Slow down player if he selects specific weapon?

Tormentor667 · Post by **Tormentor667** » Thu Apr 20, 2017 1:08 pm

Is it possible to half the player speed if he selects a specific weapon through the weapon actor itself? If yes, how?

D2JK · Post by **D2JK** » Thu Apr 20, 2017 2:28 pm

You could make the weapon modify player's speed in the select-state, by using A_SetSpeed function, or just { Speed = x; } in ZScript.

Another option is to make the weapon give the player custom speed-modifying powerups.

22alpha22 · Post by **22alpha22** » Thu Apr 20, 2017 2:28 pm

There are a couple ways you can do it that I know of. One requires some ACS, the other does not.

Method 1:
In the weapon's "Select" state, have it call a global script that will reduce the player's speed property to whatever value you want. In the "Deselect" state, have it call a script which will return the player's speed to normal.

Example taken from my Delta Force mod:

Spoiler:
Here in the "Select" state, the script "Assault_Rifle_Speed" is called.
Code: Select all
Select:
		TNT1 A 35
		"G11-" A 0 A_Overlay(2,"Crosshair",False)
		"G11-" # 0 A_GiveInventory("AlphaAutoToken",1,AAPTR_DEFAULT)
		"G11-" # 0 ACS_NamedExecuteAlways("Assault_Rifle_Speed",0,0,0,0)
		"G11-" A 1 A_Raise
		Goto Select+4
Here the script sets the player's speed and jump height to the desired values when holding the weapon.
Code: Select all
Script "Assault_Rifle_Speed" (void) {
SetActorProperty(0,APROP_SPEED,0.7);
SetActorProperty(0,APROP_JUMPZ,5.6);
}
Here in the "Deselect" state, the script "Normal_Speed" is called.
Code: Select all
Deselect:
		"G11-" A 0 A_TakeInventory("AlphaAutoToken",0,0,AAPTR_DEFAULT)
		"G11-" # 0 A_TakeInventory("AlphaBurstToken",0,0,AAPTR_DEFAULT)
		"G11-" # 0 A_TakeInventory("AlphaSemiToken",0,0,AAPTR_DEFAULT)
		"G11-" # 0 A_TakeInventory("AlphaBoltToken",0,0,AAPTR_DEFAULT)
		"G11-" # 0 ACS_NamedExecute("Normal_Speed",0,0,0,0)
		"G11-" A 1 A_Lower
		Goto Deselect+5
Here the script returns the player to the default speed and jump height.
Code: Select all
Script "Normal_Speed" (void) {
SetActorProperty(0,APROP_SPEED,1.0);
SetActorProperty(0,APROP_JUMPZ,8.0);
}

Method 2:
Create a powerup that inherits from "PowerSpeed" and have the weapon give the player the powerup in the weapon's "Select" state and take the powerup in the "Deselect" state.

Example:

Spoiler:

EDIT:
Disregard method 1, D2JK's method is simpler.

Tormentor667 · Post by **Tormentor667** » Thu Apr 20, 2017 3:23 pm

D2JK wrote:You could make the weapon modify player's speed in the select-state, by using A_SetSpeed function, or just { Speed = x; } in ZScript.

Tried it but doesn't work:

Code: Select all

		TNT1 A 0 A_SetSpeed(0.1)

or

Code: Select all

		TNT1 A 0 A_SetSpeed(2)

in the Select state of the weapon.

Blue Shadow · Post by **Blue Shadow** » Fri Apr 21, 2017 4:17 am

Does the following code work (for me, it does):

Code: Select all

actor TestShotgun : Shotgun
{
    Weapon.SlotNumber 0

    States
    {
    Select:
        SHTG A 0 A_SetSpeed(0.1)
        SHTG A 1 A_Raise
        Wait

    Deselect:
        SHTG A 0 A_SetSpeed(1.0)
        SHTG A 1 A_Lower
        Wait
    }
}

Tormentor667 · Post by **Tormentor667** » Fri Apr 21, 2017 10:32 am

Strange, it works on normal Doom but it doesn't work on Blade of Agony... does it have something to do with the fact that the player class has been externalized into a ZScript variant?

Code: Select all

class BoAPlayer : PlayerPawn
{
	double user_crouch;
	double user_ScaleY;
	int user_visibility;
	int suspicion;

	Default
	{
		+DONTBLAST // avoid kick's blast effect while kicking at walls
		+THRUSPECIES // Needed for swimming through SharkBlockers.
		Species "Player";
		Player.MaxHealth 100; // Needed for improved vitality serum
		Player.InvulnerabilityMode "reflective";
		Player.StartItem "KnifeSilent";
		Player.StartItem "TrenchShotgunLoaded",8;
		Player.StartItem "Browning5Loaded",4;
		Player.StartItem "MP40Loaded",32;
		Player.StartItem "G43Loaded",10;
		Player.StartItem "Walther9mmLoaded",8;
		Player.StartItem "Luger9mmLoaded",8;
		Player.StartItem "StenLoaded",32;
		Player.StartItem "Kar98kLoaded",5;
		Player.StartItem "PyrolightLoaded",25;
		Player.StartItem "PanzerschreckLoaded";
		Player.StartItem "AstroShotgunLoaded",8;
		Player.StartItem "AstroRocketLauncherLoaded",5;
		Player.StartItem "AstroChaingunLoaded",30;
		Player.StartItem "Stamina", 100;
		Player.ViewHeight 56;
		Player.AttackZOffset 24;
		Player.DisplayName "William Blazkowicz";
		Player.CrouchSprite "PLYC";
		Player.SideMove 1.0,0.5;
		Player.ForwardMove 1.0,0.5;
		Player.ViewBob 0.44;
		Player.WeaponSlot 1, "KnifeSilent", "Shovel", "Firebrand", "AstrosteinMelee";
		Player.WeaponSlot 2, "Luger9mm", "Walther9mm";
		Player.WeaponSlot 3, "TrenchShotgun", "Browning5", "AstroShotgun";
		Player.WeaponSlot 4, "MP40", "Sten", "AstroChaingun";
		Player.WeaponSlot 5, "Kar98k", "G43", "UMG43";
		Player.WeaponSlot 6, "Pyrolight", "Nebelwerfer", "AstroRocketlauncher";
		Player.WeaponSlot 7, "Panzerschreck";
		Player.WeaponSlot 8, "NullWeapon";
		Player.DamageScreenColor "ff ff ff", 1, "IceWater";
		Player.DamageScreenColor "64 00 C8", 1, "MutantPoison";
		Scale 0.65;
	}

	States
	{
	Spawn:
		PLAY A 1 NoDelay {
			if (user_ScaleY == 0) { user_ScaleY = Scale.Y; }
		}
		"####" # 0 A_JumpIfInventory("ScientistUniformToken", 1, "Spawn.Uniform");
		Loop;
	Spawn.Uniform:
		PLSC A 1;
		"####" # 0 A_Jump(256, "See");
	See:
		"####" AAAAAAABBBBBBBBCCCCCCCCDDDDDDDD 1 { //Check for change every tic, but still let each frame display for 8 tics (A is only 7 times here to account for the lead in frame set in other states)
			user_crouch = GetCrouchFactor(AAPTR_DEFAULT);

			if (CountInv("ScientistUniformToken") > 0) {
				if (user_crouch < 0.75) { 
					return ResolveState("See.Scientist.Crouch");
				} else {
					Scale.Y = user_ScaleY;
					return ResolveState("See.Scientist");
				}
			} else {
				Scale.Y = user_ScaleY;
				return ResolveState(null);
			}
		}
		PLAY A 1;
		Loop;
	See.Scientist:
		PLSC A 1;
		"####" # 0 A_Jump(256, "See.Resume");
	See.Scientist.Crouch:
		PLYS A 1;
		"####" # 0 A_Jump(256, "See.Resume");
	See.Resume:
		"####" AAAAAAABBBBBBBBCCCCCCCCDDDDDDDD 1 {
			Scale.Y = user_ScaleY / user_crouch; //Negate crouch sprite scaling
			if ((vel.x + vel.y) == 0 || GetCrouchFactor(AAPTR_DEFAULT) != user_crouch) { //Get rid of the 'running in place' effect and check if crouch state changed
				if (CountInv("ScientistUniformToken") > 0) {
					return ResolveState("See");
				} else {
					Scale.Y = user_ScaleY;
					return ResolveState("Spawn");
				}
			} else {
				return ResolveState(null);
			}
		}
		"####" # 0 A_Jump(256, "See");
	Pain:
		"####" G 0 ACS_NamedExecuteWithResult("PlayerFlinch", 0);
		"####" G 4 A_Pain;
		"####" # 0 A_Jump(256, "Spawn");
	Missile:
		PLAY E 12 BRIGHT;
		"####" # 0 A_Jump(256, "Spawn");
	Melee:
		PLAY F 6;
		"####" # 0 A_Jump(256, "Missile");
	Disintegrate: //here in order to transfer properly frames if needed - ozy81
		"####" G 0 A_Playsound("astrostein/guard_death");
		"####" G 5 A_PlayerScream;
		"####" G 0 A_NoBlocking;
		"####" G 0 A_SpawnItemEx("BaseLineSpawner", random(16, -16), random(16, -16), random(0, 8), 0, 0, random(1,3), 0, 129, 0);
		"####" GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG 1 A_FadeOut(0.02,0);
		TNT1 A -1 A_SetTranslucent(1);
		Stop;
	Death:
		"####" H 5 A_PlayerScream;
		"####" I 8;
		"####" I 1 A_PlaySound("death/bjfall");
		"####" J 5 A_NoBlocking;
		"####" K 5;
		"####" LM 2;
		"####" N -1;
		Stop;
	Death.Fire:
		TNT1 A 0 A_Jump(256,"Death.Fire.A","Death.Fire.B");
	Death.Fire.A:
		BURN A 5 BRIGHT Light("ITBURNS1");
		"####" BC 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" D 5 BRIGHT Light("ITBURNS1") A_PlaySound("death/burning");
		"####" E 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" FGHIJ 5 BRIGHT Light("ITBURNS2") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" KLMN 5 BRIGHT Light("ITBURNS3");
		"####" O 5 BRIGHT Light("ITBURNS3") A_NoBlocking;
		"####" PQR 5 BRIGHT Light("ITBURNS2") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,16), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" STU 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,8), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" V -1;
		Stop;
	Death.Fire.B:
		NRUB A 5 BRIGHT Light("ITBURNS1");
		"####" BC 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" D 5 BRIGHT Light("ITBURNS1") A_PlaySound("death/burning");
		"####" E 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" FGHIJ 5 BRIGHT Light("ITBURNS2") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,32), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" KLMN 5 BRIGHT Light("ITBURNS3");
		"####" O 5 BRIGHT Light("ITBURNS3") A_NoBlocking;
		"####" PQR 5 BRIGHT Light("ITBURNS2") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,16), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" STU 5 BRIGHT Light("ITBURNS1") A_SpawnItemEx("FloatingCinder", random(-8,8), random(-8,8), random(0,8), 1, 0, random (1, 3), random (0, 360), SXF_TRANSFERPITCH | SXF_CLIENTSIDE, 160);
		"####" V -1;
		Stop;
	}
}

Blue Shadow · Post by **Blue Shadow** » Fri Apr 21, 2017 12:13 pm

There is the possibility of conflict. What happens if you temporarily disable this script? Does it work?

Ozymandias81 · Post by **Ozymandias81** » Sat Apr 22, 2017 5:17 pm

You were right Blue Shadow, thanks.

ZDoom

Slow down player if he selects specific weapon?

Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?

Re: Slow down player if he selects specific weapon?