Throwing a Knife

[Galaxy_Stranger]

I've made a knife that's designed to be used on monsters as a knife, but its altfire allows the player to throw it:

---

Code: Select all

actor DaggerProjectile
{
	PROJECTILE
	-NOGRAVITY
	Radius 12
	Height 8
	Speed 50
	Damage 5
	Gravity 1.0
	//DeathSound ""
	States
	{
	Spawn:
		KNFT A 4 Bright
		Loop
	Death:
		KNFT A 1 A_SpawnItemEx("Dagger", 0, 0, 0, 0, 0, 0, 0, SXF_TRANSFERPOINTERS)
		Stop
	}
}

actor DaggerAmmo : Ammo
{
  Game Doom
  SpawnID 140
  Inventory.PickupMessage "Got a Dagger!"
  Inventory.Amount 1
  //Inventory.MaxAmount 1
  //Ammo.BackpackAmount 1
  //Ammo.BackpackMaxAmount 5
  Inventory.Icon "KNIFA0"
  States
  {
  Spawn:
    ROCK A -1
    Stop
  }
}

actor Dagger : RocketLauncher 10359
{
	Weapon.Kickback 100
	Obituary ""
	Weapon.SlotNumber 1
	//Weapon.AmmoUse 1
	Weapon.AmmoGive 1
	Weapon.AmmoType "DaggerAmmo"
	+WEAPON.NOAUTOFIRE
	+WEAPON.WIMPY_WEAPON
	+WEAPON.MELEEWEAPON
	+WEAPON.AMMO_OPTIONAL
	Inventory.PickupMessage "Got a Dagger!"
	Tag "Dagger"

	States
	{
		Ready:
			KNIF A 1 A_WeaponReady
			Loop
		Deselect:
			KNIF A 1 A_Lower
			Loop
		Select:
			KNIF A 1 A_Raise
			Loop
		Fire:
			KNIF B 4 
			KNIF C 4 A_CustomPunch(10)
			KNIF D 5 
			KNIF C 4 
			KNIF B 5 A_ReFire
			Goto Ready
		AltFire:
			KNIF C 1 A_JumpIfInventory("DaggerAmmo", 1, "ThrowDagger")
			KNIF C 1 A_TakeInventory("Dagger",1)
			Stop
			KNIF C 1 A_TakeInventory("DaggerAmmo",1)		//	Use up a Dagger.
			Goto Ready
		ThrowDagger:
			KNIF C 1 A_TakeInventory("DaggerAmmo",1)		//	Use up a Dagger.
			KNIF C 1 A_FireCustomMissile("DaggerProjectile", 0, 0, 0, 0, 0, 0)
			Goto Ready
		Spawn:
			KNIF E -1
			Stop
	}
}

With this configuration, when you altfire, it takes away the ammo - but apparently not the Dagger inventory item, unless TakeInventory() is placed above the JumpIfInventory.

Can anybody see what's wrong with this?

[edward850]

Don't you want to jump 2 frames, not 1?

Code: Select all

A_JumpIfInventory("DaggerAmmo", 1, "ThrowDagger")

Will land on A_TakeInventory("Dagger",1), not A_TakeInventory("DaggerAmmo",1).
Also, the current configuration will mean you will always have at least one "DaggerAmmo" left after taking "Dagger".

[Galaxy_Stranger]

Thanks for the reply.

Don't you want to jump 2 frames, not 1?

Ok, originally, I had a dagger. You picked it up and you could use it - without using ammo, and you could altfire it. The altfire spawned a dagger projectile and removed the dagger from the player's inventory. When the projectile died, it spawned a new dagger weapon. This works perfectly if all you want the player to have is ONE dagger.

So, to fix this, I created a weapon that doesn't use ammo per se. I remove the ammo only when it is altfired. Man, I'm going in circles. Maybe I should step away from this for a while... The idea was to check the amount of ammunition the player has and remove the weapon based on that.

Code: Select all

A_JumpIfInventory("DaggerAmmo", 1, "ThrowDagger")

Will land on A_TakeInventory("Dagger",1), not A_TakeInventory("DaggerAmmo",1).
Also, the current configuration will mean you will always have at least one "DaggerAmmo" left after taking "Dagger".

I figured this was how it was acting - because if you altfire or fire, it acts like it cycles through and it removes the weapon from the inventory. Could you point how out it is doing this? I don't see it.


Ok, after going over this post a couple times, the wheels started turning and I found another approach. I was working on another computer and tried to send myself the new versions of the decorate definitions, but that didn't work out. So, tomorrow, I'll post my solution here. It was deceptively simple...

Edward, I would still like you to point out how it was keeping the item if you would.

[edward850]

Actually I'm misreading what you were doing there. I'm not entirely sure why you have a random stop statement there for and it's throwing me off.

[Galaxy_Stranger]

Actually I'm misreading what you were doing there. I'm not entirely sure why you have a random stop statement there for and it's throwing me off.

Yeah - that stop was in there just because I was trying anything to get things to work.

Here's the solution:

Code: Select all

		AltFire:
			KNIF C 1 A_FireCustomMissile("DaggerProjectile", 0, 0, 0, 0, 0, 0)
			KNIF C 1 A_TakeInventory("DaggerAmmo",1)
			KNIF C 1 A_JumpIfInventory("DaggerAmmo", 1, "Ready")
			KNIF C 1 A_TakeInventory("Dagger",1)
			Stop

And that's it. Here are the properties:

Code: Select all

	Obituary ""
	Weapon.SlotNumber 1
	//Weapon.AmmoUse 1
	Weapon.AmmoGive 1
	Weapon.AmmoType "DaggerAmmo"
	+WEAPON.NOAUTOFIRE
	+WEAPON.WIMPY_WEAPON
	+WEAPON.MELEEWEAPON
	+WEAPON.AMMO_OPTIONAL
	Inventory.PickupMessage "Got a Dagger!"
	Tag "Dagger"

I'm also working on a WWII grenade that will work very similar to this.