Seeking Non-Functional in Bounce State

[amv2k9]

Pretty much what the title says; A_SeekerMissile, when called from the brand spankin' new Bounce state, does not cause the missile to seek. Unless I'm grossly misunderstanding the Bounce state's capabilities, this looks like a bug to me.

Code:

---

ACTOR PlasmaRifleMK2 : PlasmaRifle replaces PlasmaRifle
{
States
{
Altfire:
PLSG A 0 A_FireCustomMissile("BouncyHomer",-3,1,-3)
PLSG A 3 A_FireCustomMissile("BouncyHomer",3,1,3)
PLSG B 20 A_ReFire
Goto Ready
}
}

ACTOR BouncyHomer : PlasmaBall
{
+USEBOUNCESTATE
+BOUNCEONWALLS
+BOUNCEONFLOORS
+BOUNCEONCEILINGS
+SEEKERMISSILE
BounceCount 2
States
{
Spawn:
PLSS AB 6 Bright
Loop
Bounce:
PLSS A 1 A_SeekerMissile(90,90,SMF_LOOK,SMF_PRECISE)
Goto Spawn
}
}

I don't have access to my modding comp right now, so I don't have an example wad. But it would take all of 30 seconds for someone to put this in Slade3, so hopefully it's not a problem.

[Graf Zahl]

Of course it won't seek. You have to call A_SeekerMissile repeatedly so you can't just jump to the spawn state. You have to define another sequence with A_SeekerMissile calls.

[Ichor]

I think he wants it to act like the big firemace spheres from Heretic, where it changes direction to seek after a target only when it bounces and not any other time.

[Xaser]

The trouble is that he's only calling A_SeekerMissile for a single tic, which isn't enough to get it to change direction completely, since "threshold" and "maxturnangle" are clamped at a certain value (90?) and don't allow for instantaneous turns (though I can't imagine why -- that'd be a useful feature as well ).

tl;dr: Make it seek for a few more tics and it'll turn as desired.

[Gez]

I think he wants it to act like the big firemace spheres from Heretic, where it changes direction to seek after a target only when it bounces and not any other time.

But the [wiki=Classes:MaceFX4]big firemace spheres[/wiki] call [wiki]A_DeathBallImpact[/wiki] which doesn't exactly behave like [wiki]A_SeekerMissile[/wiki], so it's not surprising.

[Xaser]

Is it not clear he's trying to emulate the effect?

[amv2k9]

You have to call A_SeekerMissile repeatedly so you can't just jump to the spawn state. You have to define another sequence with A_SeekerMissile calls.

I'll give this a go, thanks.

...since "threshold" and "maxturnangle"...don't allow for instantaneous turns.

Maybe that's worth a feature suggestion.

[zrrion the insect]

Would A_FaceTarget suffice?

[Enjay]

Does a missile necessarily travel in the direction that it is facing?

[Graf Zahl]

No, only the velocity vector matters.

[NeuralStunner]

You could call A_SeekerMissile twice on a tic to achieve a 180 degree turn, right?

[Ichor]

I managed to get it working.

---

Code: Select all

ACTOR IronDoom
{
    PROJECTILE
    +CANBOUNCEWATER
    +BOUNCEONWALLS
    +ALLOWBOUNCEONACTORS
    +RIPPER
    +NOBOSSRIP
    +SEEKERMISSILE
    +USEBOUNCESTATE
    +EXTREMEDEATH
    -THRUGHOST
    -NOGRAVITY
    -NOWALLBOUNCESND
    BounceType Hexen
    BounceFactor 1.0
    WallBounceFactor 1.0
    SeeSound "weapons/macestop"
    BounceSound "weapons/macestop"
    WallBounceSound "weapons/macestop"
    ReactionTime 40
    Gravity 0.6
    Radius 14
    Height 8
    Speed 9
    Damage 12
    Scale 1.5
    States
    {
    Spawn:
	IWDM AAABBBCCC 1
	TNT1 A 0 A_CountDown
	Loop
    Bounce:
	IWDM A 0 A_SeekerMissile(90,90,9,100)
	IWDM A 0 A_SeekerMissile(90,90,9,100)
	Goto Spawn
    Death:
	CFCF Q 4 Bright A_NoGravity
	CFCF Q 0 Bright A_Explode(180,128,0)
	CFCF R 3 Bright A_PlaySound("Fireball")
	CFCF S 4 Bright
	CFCF T 3 Bright
	CFCF U 4 Bright
	CFCF V 3 Bright
	CFCF W 4 Bright
	CFCF X 3 Bright
	CFCF Y 4 Bright
	CFCF Z 3 Bright
	Stop
    }
}

If you don't include it, there's a 50% chance that it will not home in on anything. I set mine to 100 so it will always home in. I briefly had SMF_PRECISE, but it turned out to not work for this, which is similar to the big firemace sphere. However, it should work for you.

[NeuralStunner]

Just to note...

If you don't include it, there's a 50% chance that it will not home in on anything. I set mine to 100 so it will always home in.

• chance
  If the SMF_LOOK flag is used, this is the chance (out of 256) that the missile will try acquiring a target if it doesn't already have one. The default value is 50.

[Ichor]

Out of 256? I thought it was a percentage. Well, I guess I'll fix that then...