Weapon causes ACS problems

[DonaldDuck]

I have created a new Playerclass and a new weapon.
Whenever i start a normal map without any ACS scripting, it works (e.g.: normal doom maps).

But when I change the map to a map WITH ACS coding, errors come up like:
"ACS: I dont know what XXX is."

Playerclass:

---

Code: Select all

actor TheTerminator : Playerpawn
{ 
  Health 110
  Radius 17
  Height 58 
  Mass 900
  PainChance 255
  scale 0.9
  player.forwardmove 0.75
  player.sidemove 0.45
  Player.Maxhealth 110
  Player.DisplayName "TheTerminator"
  player.startitem "Terminatorgunner"
  player.startitem "termplasma", 100
  player.crouchsprite "TZRM"
  player.soundclass "term"
  +NOBLOOD
  States 
   { 
   Spawn: 
       TZRM A 0
	   TZRM A 3 ACS_Execute(451,0,0,0,0) //Starts the script once, it loops
   Okay:
       TZRM A 3
       Loop 
   See:
       TZRM A 8 A_Playsound("term/step1")
       TZRM B 8
       TZRM C 8 A_Playsound("term/step2")
       TZRM D 8
       Loop 
   Pain:
       TZRM L 3 	
       TZRM L 3 A_PlaySound("term/pain")
       Goto See
   Missile:  
       TZRM K 8 BRIGHT
       TZRM J 8
	   goto Okay
   Death:
       TZRM M 6 A_PlaySound("term/death")
       TZRM N 4 
       TZRM OPQ 4 Bright
       TZRM R 0 Bright A_SpawnItemEx("TerminatorHead", 15, 0, 90, 10, 0, 0, -170, 128)
       TZRM R 0 Bright A_SpawnItemEx("TerminatorShoulder", 60, 0, 75, 8, 0, 0, -70, 128)
       TZRM R 4 Bright A_SpawnItemEx("TerminatorArm", 60, 0, 0, 3, 0, 0, -90, 128)
       TZRM STUV 4 Bright
       TZRM W 4 
       TZRM X 6
       TZRM Y 6
       TZRM Z 1 A_Playsound("term/step1")
       TZRM Z 5 
       TZRM [ -1   
       Stop
   } 
}

Weaponcode:

---

Code: Select all

actor TerminatorGunner : Weapon
{
   Weapon.SlotNumber 2
   Weapon.AmmoGive 100
   Weapon.YAdjust 0
   Weapon.SelectionOrder 350
   Inventory.PickupSound ""
   Inventory.PickupMessage ""
   +WEAPON.NOAUTOAIM
   +INVENTORY.UNDROPPABLE
   states
   {
   Spawn:
      TGUN A 400
      Stop
   Ready:
      TGUN A 0
	  TGUN A 0 ACS_Execute(452,0,0,0,0)
	  TGUN A 2 A_WeaponReady
      Loop
   Deselect:
	  TGUN A 1 A_Lower
      Loop
   Select:
      TGUN A 1 A_Raise
      Goto Select
   Fire:
      TGUN I 0 A_JumpIf(ACS_ExecuteWithResult(453,0,0,0) == 1, "Ready")
      TGUN I 3 BRIGHT ACS_Terminate(452,0)
	  TGUN J 3 BRIGHT
   Hold:
      TGUN J 0 BRIGHT A_JumpIf(ACS_ExecuteWithResult(453,0,0,0) == 1, "Out")
	  TGUN K 0 BRIGHT A_TakeInventory("termplasma",1)
	  TGUN K 0 BRIGHT A_PlayWeaponSound("term/shot1")
	  TGUN K 1 BRIGHT ACS_Terminate(452,0)
	  TGUN J 0 BRIGHT A_JumpIf(ACS_ExecuteWithResult(453,0,0,0) == 1, "Out")
	  TGUN K 2 BRIGHT A_FireCustomMissile("RedPlasmaterm",random(-2,2),0,-7,-2)
	  TGUN L 3 BRIGHT
	  TGUN L 0 BRIGHT A_Refire
	  goto OUT
   Out:
	  TGUN J 3 BRIGHT
	  TGUN I 3 BRIGHT
	  goto Ready
    }
}

The weapon also causes problem with my global script, when I enter a map with ACS coding.
Instead of the hudmessage "PlasmaAmmo: XXX" some random words will be shown like "ook they have0" or the mapname or something like this.

ACS coding:

---

Code: Select all

script 451 (void)
{
  while(1)
  {
    SetFont("BIGFONT");
    HUDMessage(s:"PlasmaAmmo: ",d:CheckInventory("termplasma");HUDMSG_PLAIN,15400200,CR_BLUE,0.15,0.15,0.04);
  
    Delay(1);
  }
}

script 452 (void)
{
  while(CheckInventory("termplasma") < 100)
  {
    Delay(5);
    GiveInventory("termplasma",1);
  }
}

script 453 (void)
{
  if(CheckInventory("termplasma"))
  {
    SetResultValue(0);
  }
  else
  {
    SetResultValue(1);
  }
}

I really dont know where the problem is.

[Blue Shadow]

The weapon also causes problem with my global script, when I enter a map with ACS coding.
Instead of the hudmessage "PlasmaAmmo: XXX" some random words will be shown like "ook they have0" or the mapname or something like this.

Maybe there is script number conflict between your scripts and the map's. If that's the case, use [wiki]named scripts[/wiki] instead.

[DonaldDuck]

OK, I've made something new.
But the problem is now:

The script with TakeInventory doesnt do anything on Zdoom maps, it only works on normal Doom maps!
But the scripts with SetActorVelocity and SetActorProperty are for other classes and they work on ALL maps.
I dont know why the terminator one wont (script. no. 314), even though it is the only wad i drag on zdoom exe. (no other scripts in use)
I tried it with skulltag too, but the same problem occurs.

I dont know what went wrong

Heres the ACS:

---

Code: Select all

#include "zcommon.acs"

script 313 ENTER
{
  Thing_ChangeTID(0,1000+Playernumber());
}

script 314 (void) //THIS ONE WONT DO ANYTHING ON ZDOOM MAPS
{
  while(1)
  {
  	TakeInventory("overheatedterm",1);
    Delay(15);
  }
}

script 339 (void)
{
  SetActorVelocity(0,0.4,0.4,0.4,0,0);
  SetActorProperty(0, APROP_SPEED, 0.4);
}

script 340 (void)
{
  SetActorProperty(0, APROP_SPEED, 1.0);
}

script 341 (void)
{
  SetActorVelocity(0,0.1,0.1,0.1,0,0);
  SetActorProperty(0, APROP_SPEED, 0.1);
}

And heres the Decorate (weapon and playerclass):

---

Code: Select all

actor TheTerminator : Playerpawn
{ 
  Health 110
  Radius 16
  Height 57 
  Mass 900
  PainChance 255
  scale 0.82
  player.forwardmove 0.85
  player.sidemove 0.55
  Player.Maxhealth 110
  Player.startitem "terminatorgunner"
  player.startitem "overheatedterm" 1
  Player.DisplayName "TheTerminator"
  player.crouchsprite "TZRM"
  player.soundclass "term"
  +NOBLOOD
  States 
   { 
   Spawn: 
       TZRM A 0
       TZRM A 3 ACS_Execute(314,0,0,0,0)    
	   Loop 
   See:
       TZRM A 8 A_Playsound("term/step1")
       TZRM B 8
       TZRM C 8 A_Playsound("term/step2")
       TZRM D 8
       Loop 
   Pain:
       TZRM L 3 	
       TZRM L 3 A_PlaySound("term/pain")
       Goto See
   Missile:  
       TZRM K 8 BRIGHT
       TZRM J 8
	   goto Spawn
   Death:
       TZRM M 6 A_PlaySound("term/death")
       TZRM N 4 
       TZRM OPQ 4 Bright
       TZRM R 0 Bright A_SpawnItemEx("TerminatorHead", 15, 0, 90, 10, 0, 0, -170, 128)
       TZRM R 0 Bright A_SpawnItemEx("TerminatorShoulder", 60, 0, 75, 8, 0, 0, -70, 128)
       TZRM R 4 Bright A_SpawnItemEx("TerminatorArm", 60, 0, 0, 3, 0, 0, -90, 128)
       TZRM STUV 4 Bright
       TZRM W 4 
       TZRM X 6
       TZRM Y 6
       TZRM Z 1 A_Playsound("term/step1")
       TZRM Z 5 
       TZRM [ -1   
       Stop
   } 
}


ACTOR TerminatorArm
{
	Radius 12
	Height 15
	Speed 3
	Mass 1000
	scale 0.9
	+DOOMBOUNCE
      States
	{
	Spawn:
         TARM A 5
         TARM B 5 A_Fall 
         TARM CDE 5
         TARM F -1
         Stop
	}
}

actor TerminatorHead
{
    Radius 6
    Height 8
    Speed 10
    Mass 1000
    +DOOMBOUNCE
    +DROPOFF
    +Missile
    scale 0.9
    
    States
    {
    Spawn:
    	THAD DEFGHABC 2
        loop
    Death:
    	THAD I -1
        loop
    }
}

actor TerminatorShoulder
{
    Radius 8
    Height 8
    Speed 8
    Mass 1000
    +DOOMBOUNCE
    +DROPOFF
    +Missile
    scale 0.9
    
    States
    {
    Spawn:
    	TSHO ABCDEFGH 2
        loop
    Death:
    	TSHO I -1
        loop
    }
}

actor TerminatorGunner : Weapon
{
   Weapon.SlotNumber 6
   Weapon.AmmoGive 100
   Weapon.YAdjust 0
   Weapon.SelectionOrder 350
   Inventory.PickupSound ""
   Inventory.PickupMessage ""
   weapon.ammotype "overheatedterm"
   +WEAPON.NOAUTOAIM
   +INVENTORY.UNDROPPABLE
   states
   {
   Spawn:
      TGUN A 400
      Stop
   Ready:
     TGUN A 2 A_WeaponReady
      Loop
   Deselect:
     TGUN A 1 A_Lower
      Loop
   Select:
      TGUN A 1 A_Raise
      Goto Select
   Fire:
      TGUN I 3 BRIGHT
      TGUN J 3 BRIGHT
   Hold:
     TGUN K 0 A_JumpIfInventory("Overheatedterm",100,"Overheated")
     TGUN K 0 BRIGHT A_PlayWeaponSound("term/shot1")
	 TGUN K 0 A_GiveInventory("Overheatedterm",1)
     TGUN K 2 BRIGHT A_FireCustomMissile("RedPlasmaterm",random(-2,2),0,-7,-2)
     TGUN L 3 BRIGHT
	 TGUN L 0 BRIGHT A_Refire
	 goto Out
   Overheated:
     TGUN L 0 A_Print("Your weapon is overheated! Let it cool down!")
   Out:
     TGUN J 3 BRIGHT
     TGUN I 3 BRIGHT
     goto Ready
    }
}

actor Redplasmaterm
{
    Radius 5
    Height 10
	scale 0.5
    Speed 24
    Damage 3
    PROJECTILE
    RENDERSTYLE ADD
    ALPHA 0.8
    DeathSound "imp/shotx"
    States
    {
    Spawn:
        STAR ABCD 3 Bright
        Loop
    Death:
        STAR EFGHIJKLMNO 1 Bright
        Stop
    }
}

actor overheatedterm : ammo
{
  Inventory.Icon "FIREC0"
  Inventory.Amount 1
  Inventory.MaxAmount 50
  Ammo.BackpackAmount 1
  Ammo.BackpackMaxAmount 51
}

If someone could help me, that'd be great, I'd really like to finish this mod.
(I still dont have that much experience)

[LilWhiteMouse]

Are your scripts in a library? If so, I think you've forgotten to add

Code: Select all

#library "My Library Name"

[DonaldDuck]

Are your scripts in a library? If so, I think you've forgotten to add

Code: Select all

#library "My Library Name"

Hey it works!
Thx!