Help! Changing ammo type using altfire

[A.Gamma]

Basically, is it possible to change the ammo type a weapon is using by pressing the altfire button?

[Ryan Cordell]

Technically, no. But you could fake what ammo the HUD displays.

[A.Gamma]

But that won´t make the actual ammo the weapon uses change, would it?

[Blitzky]

Theoretically, you could use altfire to give the player a dummy item and cause a jump to a different fire state based on whether or not they have that item.

[A.Gamma]

Hmmm thanks for the suggestion, I will try it later.

[Gez]

[wiki=Final_Heretic:_The_Docks]Here[/wiki]'s an example of a mod featuring a weapon where you use altfire to change firing mode and ammo used.

[A.Gamma]

Woah, thanks that's exactly what I was going for!

[A.Gamma]

Necro Bump!
Since I'm having issues with this, I decided to post them here instead of making a new thread.
Anyway, I got a weapon that's supposed to change the ammo type, needles to say, it's not

---

Code: Select all

Actor Dualguns : HereticWeapon
{
 //$Category weapons
  Game Heretic
  Weapon.SelectionOrder 200
  Weapon.Slotnumber 2
  Weapon.AmmoGive 100
  Weapon.AmmoUse 1
  Weapon.AmmoType "RedBloodAmmo"
  Obituary "%k sent %o to meet the creator"
  +NOEXTREMEDEATH
   States
   {
    Spawn:
	  TNT1 A -1
	  Stop
    Ready:
      BGUN A 1 A_WeaponReady
      Loop
   Deselect:
      BGUN A 1 A_Lower
      Loop
   Select:
      BGUN A 1 A_Raise
	  BGUN A 0 A_PlayWeaponSound("Weapons/Ready")
	  Goto Ready
   Fire:
      BGUN A 0 A_GunFlash
	  BGUN A 0 A_AlertMonsters
	  BGUN A 0 A_Jumpifinventory ("BonnieClydeCheck",1,"Fire2")
	  BGUN A 0 A_Jumpifinventory ("ChangeGreen",1,"FireGreen")
   FireGreen:
      BGUN A 0 A_GunFlash
	  BGUN A 0 A_AlertMonsters
	  BGUN A 0 A_Jumpifinventory ("BonnieClydeCheck", 1,"Fire2Green")
   Fire1:
      BGUN B 0 A_Light1
      BGUN B 0 A_PlayWeaponSound("Guns/Fire") 
	  BGUN B 0 A_GiveInventory("BonnieClydeCheck",1)
      BGUN B 2 Bright
	  BGUN C 2 Bright A_FireBullets(6,1,1,2,"BulletPuff",1)
	  BGUN B 1 A_Light1
	  BGUN A 1 A_WeaponReady
	  Goto Ready
   Fire1Green:
      BGUN A 0 A_Jumpifinventory("GreenBloodAmmo",1,1)
      BGUN B 0 A_Light1
	  BGUN B 0 A_PlayWeaponSound("Guns/Fire")
	  BGUN B 0 A_GiveInventory("BonnieClydeCheck",1)
	  BGUN B 2 Bright
	  BGUN C 2 Bright A_FireCustomMissile("GreenProjectile1",0,1)
	  BGUN B 1 A_Light1
	  BGUN A 1 A_WeaponReady
	  Goto Ready
   Fire2:
      BGUN D 0 A_Light1
      BGUN D 0 A_PlayWeaponSound("Guns/Fire") 
      BGUN D 2 Bright
	  BGUN E 2 Bright A_FireBullets(6,1,1,2,"BulletPuff",1)
	  BGUN D 1 A_Light1
	  BGUN D 0 A_TakeInventory("BonnieClydeCheck",1)
	  BGUN A 1 A_WeaponReady
	  Goto Ready
   Fire2Green:
      BGUN D 0 A_Light1
      BGUN D 0 A_PlayWeaponSound("Guns/Fire") 
      BGUN D 2 Bright
	  BGUN C 2 Bright A_FireCustomMissile("GreenProjectile1",0,1)
	  BGUN D 1 A_Light1
	  BGUN D 0 A_TakeInventory("BonnieClydeCheck",1)
	  BGUN A 1 A_WeaponReady
	  Goto Ready
	  Flash:   
      TNT1 A 1 BRIGHT A_Light2
      TNT1 A 1 BRIGHT A_Light1
      TNT1 A 1 BRIGHT A_Light0
      Stop
   Flash:   
      TNT1 A 1 BRIGHT A_Light2
      TNT1 A 1 BRIGHT A_Light1
      TNT1 A 1 BRIGHT A_Light0
      Stop  
   AltFire:
      BGUN A 0 A_Jumpifinventory("RedBloodAmmo",1,1)
	  Goto Ready
	  BGUN A 0 A_Jumpifinventory("GreenBloodAmmo",1,"GreenChange")
	  Goto Ready
   RedChange:
      BGUN A 0 A_Jumpifinventory("RedBloodAmmo",1,1)
	  Goto Altfire
	  BGUN A 0 A_PlayWeaponSound("Weapons/Ready")
	  BGUN A 0 A_Takeinventory("ChangeGreen",1)
   GreenChange:
      BGUN A 0 A_Jumpifinventory("GreenBloodAmmo",1,1)
	  Goto "Dualguns::RedChange"
	  BGUN A 0 A_PlayWeaponSound("Weapons/Ready")
	  BGUN A 0 A_GiveInventory("ChangeGreen",1)
	  Goto Ready

   }
}

Any ideas on what I'm doing wrong?
Edit:
I think I should mention that what I'm aiming at, is changing the ammo type with altfire AND fire it using the main "Fire" button, (like in the wad Gez linked) while the ammo appears to change (the ready sound playing) I fire normal ammo when pressing the "Fire" button.

[Jekyll Grim Payne]

Necro Bump!
Since I'm having issues with this, I decided to post them here instead of making a new thread.
Anyway, I got a weapon that's supposed to change the ammo type, needles to say, it's not

Wrapping it in

Code: Select all

 is better than in [spoiler] :)

Well, from the code I can't really see how you could actually switch back from green to red ammo. Also, why do you need to have red ammo in order to be able to switch to green? Are you sure it's necessary?
Apart from that, switching to green ammo should work as it is. But check if that ChangeGreen item is Inventory, not CustomInventory (as have experienced it, JumpIfInventory doesn't work with CustomInventory). Same goes for your BonnieClydeCheck.

[Gez]

Or wrap it in [spoiler][code] [/code][/spoiler] for the best practice! Which is exactly what he has done.

[A.Gamma]

Apart from that, switching to green ammo should work as it is. But check if that ChangeGreen item is Inventory, not CustomInventory (as have experienced it, JumpIfInventory doesn't work with CustomInventory). Same goes for your BonnieClydeCheck

Both of them have a parent class which is an Inventory Item, not Custom Inventory

Well, from the code I can't really see how you could actually switch back from green to red ammo.

That's my problem, I've seen a thing like that done before, but I can't manage to replicate the effect.

Also, why do you need to have red ammo in order to be able to switch to green? Are you sure it's necessary?

My mistake

[A.Gamma]

I hate to bump but, I do need help here.

[Blue Shadow]

Would this simplistic example of a weapon help?

Code: Select all

ACTOR DualAmmoShotgun : Shotgun replaces Shotgun
{
  Weapon.SlotNumber 8
  Weapon.AmmoGive1 40
  Weapon.AmmoGive2 10
  Weapon.AmmoType1 "Cell"
  Weapon.AmmoType2 "RocketAmmo"
  States
  {
  Fire:
    TNT1 A 0 A_JumpIfInventory("UseAmmo2", 0, "FireAmmo2")
    TNT1 A 0 A_JumpIfInventory("Cell", 1, 1)
    Goto Ready
    SHTG A 3
    TNT1 A 0 A_TakeInventory("Cell", 1)
    TNT1 A 0 A_GunFlash
    SHTG A 7 A_FireCustomMissile("PlasmaBall", 0, 0)
    SHTG BC 5
    SHTG D 4
    SHTG CB 5
    SHTG A 3
    SHTG A 7 A_ReFire
    Goto Ready
  FireAmmo2:
    TNT1 A 0 A_JumpIfInventory("RocketAmmo", 1, 1)
    Goto Ready
    SHTG A 3
    TNT1 A 0 A_TakeInventory("RocketAmmo", 1)
    TNT1 A 0 A_GunFlash
    SHTG A 7 A_FireCustomMissile("Rocket", 0, 0)
    SHTG BC 5
    SHTG D 4
    SHTG CB 5
    SHTG A 3
    SHTG A 7 A_ReFire
    Goto Ready
  AltFire:
    TNT1 A 0 A_JumpIfInventory("UseAmmo2", 0, "SetAmmo1")
    TNT1 A 0 A_Log("Ammo 2 is set (Rockets)") // Just a debug message
    SHTG A 3 A_GiveInventory("UseAmmo2", 1)
    Goto Ready
  SetAmmo1:
    TNT1 A 0 A_Log("Ammo 1 is set (Energy Cells)") // Just a debug message
    SHTG A 3 A_TakeInventory("UseAmmo2", 1)
    Goto Ready
  }
}	

ACTOR UseAmmo2 : Inventory {}