My custom monster can't be killed after resurrecting

[splattenburgers]

I attempted to create a zombieman variant with a 50% chance of reviving after death, but it returns non-solid and unkillable for some reason.

Here is the actor code:

Code: Select all

class ZombieManRevenge : Actor replaces ZombieMan
{
	Default
	{
		Health 20;
		Radius 20;
		Height 56;
		Speed 8;
		PainChance 200;
		Monster;
		+FLOORCLIP
		SeeSound "grunt/sight";
		AttackSound "grunt/attack";
		PainSound "grunt/pain";
		DeathSound "grunt/death";
		ActiveSound "grunt/active";
		Obituary "$OB_ZOMBIE";
		Tag "$FN_ZOMBIE";
		DropItem "Clip";
	}
 	States
	{
	Spawn:
		POSS AB 10 A_Look;
		Loop;
	See:
		POSS AABBCCDD 4 A_Chase;
		Loop;
	Missile:
		POSS E 10 A_FaceTarget;
		POSS F 8 A_PosAttack;
		POSS E 8;
		Goto See;
	Pain:
		POSS G 3;
		POSS G 3 A_Pain;
		Goto See;
	Death:
		POSS H 5 A_Jump(128, "FakeDeath");
		POSS I 5 A_Scream;
		POSS J 5 A_NoBlocking;
		POSS K 5;
		POSS L -1;
		Stop;
	FakeDeath:
		POSS H 5;
		POSS I 5 A_Scream;
		POSS J 5 A_ChangeFlag("A_NoBlocking", FALSE);
		POSS K 5;
		POSS L 150;
		POSS L 1 A_Jump(256, "Raise");
		POSS L -1;
		Stop;
	XDeath:
		POSS M 5;
		POSS N 5 A_XScream;
		POSS O 5 A_NoBlocking;
		POSS PQRST 5;
		POSS U -1;
		Stop;
	Raise:
		POSS K 5;
		POSS JIH 5;
		Goto See;
	}
}

[Jarewill]

That happens because you jump to the Raise state directly instead of resurrecting the monster, which creates a ghost.
You will have to use a function like A_RaiseSelf to resurrect the monster first.

Also your A_ChangeFlag won't work because "A_NoBlocking" is not a valid flag.
Since you use ZScript, you can directly change the flag, like so: POSS J 5 { bNOBLOCKING = false; }