[Solved] Changing SpriteOffset of projectile at spawn

[peewee_RotA]

How do you change a sprite offset in decorate default properties?

You probably can't. GZDoom source code doesn't have a decorate property exposed from the source. But A_SpriteOffset IS available. So you can call this in your frames.

The problem is that it is difficult to run this action before State frame #1 renders. But it is really easy to run this action in one of the provided virtual functions that happen before the first frame ever renders.

In this case, I'm reusing an actor sprite from Hexen that I don't want to copy and manually redo all of the offsets. The actual change happens in PostBeginPlay(). I'm using a pretty extreme 50, but you could work this however you want.

Code: Select all

class MageWandSunMissile : Actor
{
    Default
    {
        Speed 10;
        Radius 12;
        Height 8;
        Damage 10;
        Projectile;
        +CANNOTPUSH +NODAMAGETHRUST
        +SPAWNSOUNDSOURCE
        Obituary "$OB_MPMWEAPWAND";
        Scale 2.0;
        DamageType "Fire";
        SeeSound "TreeExplode";
    }
    States
    {
    Spawn:
        FDMB B 4 Bright Light("YellowSunSmall");
        Loop;
    Death:
        FDMB B 6 Bright Light("YellowSunBig") A_SunExplode;
        FDMB C 3 Bright Light("YellowSunBigFade1");
        FDMB C 3 Bright Light("YellowSunBigFade2");
        FDMB D 3 Bright Light("YellowSunBigFade3");
        FDMB D 3 Bright Light("YellowSunBigFade4");
        FDMB E 3 Bright Light("YellowSunBigFade5");
        Stop;
    }
    
    override void PostBeginPlay()
    {
        A_SpriteOffset(0, 50);
    }

    action void A_SunExplode()
    {
        A_Explode(65, 150);
        A_StartSound("Fireball", CHAN_BODY);
    }
}

[Jekyll Grim Payne]

Why not modify the offset in the actor's PostBeginPlay?

Edit: sorry, you're already doing it. No, there isn't a property for this, but you can make one. But ultimately it'll still have to be run in PostBeginPlay.

You could also try BeginPlay, I believe it should work.

[peewee_RotA]

Thanks for the reply. I added a utility class for it so I could use it easier in other places. Now these projectiles just inherit from here.

Code: Select all

class OffsetSpriteActor : Actor
{
	double offsetSpriteX;
	double offsetSpriteY;
	property OffsetSpriteX : offsetSpriteX;
	property OffsetSpriteY : offsetSpriteY;
    
    override void PostBeginPlay()
    {
		if (offsetSpriteX != 0 || offsetSpriteY != 0)
			A_SpriteOffset(offsetSpriteX, offsetSpriteY);
    }
}