Kick Stamina

[YeeTee2]

How would I add stamina to this kick? I'm not great at Zscript or Decorate.

[Jarewill]

You'd have to define a stamina actor first. Something like this:

Code: Select all

ACTOR StaminaActor : Inventory
{
    Inventory.MaxAmount 20 //Replace 20 with maximum stamina for the player
}

And then modify the Kick script to check for the stamina actor and take away an amount of it:

---

Code: Select all

    if (StrICmp(weapon, "KickWeapon") && CheckInventory("StaminaActor") >= 5) //If more than 5 stamina, continue. Replace 5 with any amount
    {
        SetPlayerProperty(0, 1, PROP_INSTANTWEAPONSWITCH);
        GiveInventory("KickWeapon", 1);
        GiveInventory("Kicking", 1);
        SetWeapon("KickWeapon");
        TakeInventory("StaminaActor",5); //Replace 5 with the amount to take
        While (CheckInventory("Kicking"))
            Delay(1);
        SetWeapon(weapon);
        TakeInventory("KickWeapon", 1);
        Delay(3);
        SetPlayerProperty(0, 0, PROP_INSTANTWEAPONSWITCH);
    }

You will also need a script to restore stamina to the player. (Unless it's supposed to be restored another way) This script does that:

---

Code: Select all

Script "StaminaRestore" ENTER
{
    While(true)
    {
        GiveInventory("StaminaActor",1);
        Delay(35); //Loop this script every second. (35 tics) Modify to will
    }
}

[YeeTee2]

That was very simple, thank you!

[YeeTee2]

So, I added it to the linked pk3, and modified it so every kick takes all stamina, and 4 seconds later stamina is completely full. It doesn't seem to work
http://www.mediafire.com/file/rel0on0la ... 2.pk3/file

[Jarewill]

Sorry for not specifying, that part in the Kick script had to be replaced, not added.
The scripts should look like this:

---

Code: Select all

Script "Kick" (void)
{
    str weapon = GetWeapon();
    if (StrICmp(weapon, "KickWeapon") && CheckInventory("StaminaActor") >= 20) //If more than 5 stamina, continue. Replace 5 with any amount
    {
        SetPlayerProperty(0, 1, PROP_INSTANTWEAPONSWITCH);
        GiveInventory("KickWeapon", 1);
        GiveInventory("Kicking", 1);
        SetWeapon("KickWeapon");
        TakeInventory("StaminaActor",20); 
        While (CheckInventory("Kicking"))
            Delay(1);
        SetWeapon(weapon);
        TakeInventory("KickWeapon", 1);
        Delay(3);
        SetPlayerProperty(0, 0, PROP_INSTANTWEAPONSWITCH);
    }
}

Script "StaminaRestore" ENTER
{
    While(true)
    {
        If(!CheckInventory("StaminaActor")){Delay(140); GiveInventory("StaminaActor",20);}
        Delay(1);
    }
}

Also this kind of stamina restore script might work better here.

Also don't forget to compile the script, you will have to press this blue arrow in upper right corner of the editor in SLADE:

You will also need to specify a path to ACC to compile it properly.

[YeeTee2]

Ah, thank you