Zscript Event Handler help?

[XASSASSINX]

Hello! I've been trying to introduce myself to Zscript for universal compability in a mod i'm making. I've read Jekyllgrim Zscript guide on GitHub and read some other things on the wiki and here. I got somewhat an idea of how it works, but, is there any other places or mods to reverse-engineer to help? The thing i want to do is every-time a monster dies, it summons (or not, decided by a customizable variable and the chance of it) a Exp Orb, after a X amount of this Exp you get some craftable items.

I also wanted to make it so that the higher the monster health that died, the more Exp he dropped.

I've got a bit of a clue on how to do this, but i'm still a bit confused on the formatting and some functions (A.K.A Event Handler usage and some other Flow Control things).

Any help or suggestions ?

[Jarewill]

For the event handler, you can do something like this:

---

Code: Select all

Version "4.3"

Class ItemDropEventHandler : EventHandler
{
    Override void WorldThingDied(WorldEvent e)
    {
        If(e.Thing.bISMONSTER) //If it's a monster that just died
        {
            int itemdrops = e.Thing.SpawnHealth(); //Set an integer based on how much health the monster had on spawn
            While(itemdrops>0)
            {
                If(itemdrops>=2000){e.Thing.A_DropItem("CellPack"); itemdrops-=2000;} //If above 2000, drop a CellPack and lower it by 2000
                Else If(itemdrops>=1000){e.Thing.A_DropItem("Cell"); itemdrops-=1000;} //If above 1000, drop a Cell and lower it by 1000
                Else If(itemdrops>=500){e.Thing.A_DropItem("RocketBox"); itemdrops-=500;} //If above 500, drop a RocketBox and lower it by 500
                Else If(itemdrops>=200){e.Thing.A_DropItem("RocketAmmo"); itemdrops-=200;} //If above 200, drop a Rocket and lower it by 200
                Else If(itemdrops>=100){e.Thing.A_DropItem("ShellBox"); itemdrops-=100;} //If above 100, drop a ShellBox and lower it by 100
                Else If(itemdrops>=50){e.Thing.A_DropItem("Shell"); itemdrops-=50;} //If above 50, drop a Shell and lower it by 50
                Else If(itemdrops>=20){e.Thing.A_DropItem("ClipBox"); itemdrops-=20;} //If above 20, drop a ClipBox and lower it by 20
                Else If(itemdrops>=10){e.Thing.A_DropItem("Clip"); itemdrops-=10;} //If above 10, drop a Clip and lower it by 10
                Else{itemdrops=0;} //If none of those work, stop it by reducing itemdrops to 0
            }
        }
    }
}

And in MAPINFO:

Code: Select all

GameInfo
{
    AddEventHandlers = "ItemDropEventHandler"
}

As for the Exp Orbs giving craftable items after X amount of them have been picked up, you could make them CustomInventory items that simply check how much of them the player has and give an item based on that.

Edit: And here's an example of the Exp Orbs:

---

Code: Select all

Class ExpOrb : Inventory
{
    Default
    {
        Inventory.Amount 1;
        Inventory.MaxAmount 99999;
        Inventory.PickupMessage "Got some Exp";
        +INVENTORY.KEEPDEPLETED;
        Scale 0.2;
    }
    States
    {
    Spawn:
        BON1 ABCDCB 6;
        Loop;
    }
    Override void DoEffect()
    {
        Super.DoEffect();
        While(owner.CountInv("ExpOrb")>=50) //If above 50, do stuff
        {
            owner.A_GiveInventory("UpgradeStamina",10);
            owner.A_Print("Level up!");
            owner.A_TakeInventory("ExpOrb",50); //Take it away too
        }
    }
}
Class ExpOrbBig : Inventory
{
    Default
    {
        Inventory.PickupMessage "Got a bit of Exp";
        Scale 0.5;
    }
    States
    {
    Spawn:
        BON1 ABCDCB 6;
        Loop;
    }
    Override void AttachToOwner(Actor other)
    {
        Super.AttachToOwner(other);
        other.A_GiveInventory("ExpOrb",10); //Bigger pickup, give 10
        Destroy();
    }
}
Class ExpOrbHuge : Inventory
{
    Default
    {
        Inventory.PickupMessage "Got a lot of Exp";
        Scale 1.0;
    }
    States
    {
    Spawn:
        BON1 ABCDCB 6;
        Loop;
    }
    Override void AttachToOwner(Actor other)
    {
        Super.AttachToOwner(other);
        other.A_GiveInventory("ExpOrb",50); //Biggest pickup, give 50
        Destroy();
    }
}

[XASSASSINX]

Oh! This is definetly fancier and simpler then ACS (And DECORATE obviously). Just one more thing, how do you integrate Cvar's with Zscript?

[Jarewill]

There was some way to detect CVars, but I can't remember it.
However, I am using the GetCVar function and it works fine for me.

Edit: I made a mistake with the ExpOrb item.
You should add the +INVENTORY.KEEPDEPLETED flag to it to prevent a VM abort.

[XASSASSINX]

Hm, interesting use of the Zscript. however, is there any technical problem making it on decorate? An item that (somehow, that's the only problem right now i'm thinking off) checks the amount you have of EXP, and wouldn't remove the total quantity. The reason to this is because i wanted to make the items you get with this EXP randomized on certain tiers. (I would use Token Items to see if you have them, as some of them would be one time craftable only).

Any comments?

[Jarewill]

It could be possible to make an item like that in DECORATE, however is there any reason why ZScript can't be used here?
I don't think I quite understand how you want it to work though.
Something like this?

---

Code: Select all

ACTOR ExpOrb2 : CustomInventory
{
    Inventory.Amount 1
    Inventory.MaxAmount 99999
    Inventory.PickupMessage "Got some Exp"
    +INVENTORY.KEEPDEPLETED
    +INVENTORY.AUTOACTIVATE
    Scale 0.2
    States
    {
    Spawn:
        BON1 ABCDCB 6 Bright
        Loop
    Pickup:
        TNT1 A 0 A_RailWait
        Stop
    Use:
        TNT1 A 0 A_Overlay(-100,"ExpOrb")
        Fail
    ExpOrb:
        TNT1 A 0 A_JumpIf(CountInv("ExpOrb2")>=1000&&!CountInv("BFG9000"),"GiveBFG")
        TNT1 A 0 A_JumpIf(CountInv("ExpOrb2")>=500&&!CountInv("SuperShotgun"),"GiveSSG")
        TNT1 A 0 A_JumpIf(CountInv("ExpOrb2")>=100&&!CountInv("Chaingun"),"GiveChaingun")
        TNT1 A 0 A_JumpIf(CountInv("ExpOrb2")>=10&&!CountInv("Shotgun"),"GiveShotgun")
        TNT1 A 1
        Loop
    GiveBFG:
        TNT1 A 0 A_Print("Got the BFG9000!")
        TNT1 A 0 A_GiveInventory("BFG9000",1)
        Goto ExpOrb
    GiveSSG:
        TNT1 A 0 A_Print("Got the Super Shotgun!")
        TNT1 A 0 A_GiveInventory("SuperShotgun",1)
        Goto ExpOrb
    GiveChaingun:
        TNT1 A 0 A_Print("Got the Chaingun!")
        TNT1 A 0 A_GiveInventory("Chaingun",1)
        Goto ExpOrb
    GiveShotgun:
        TNT1 A 0 A_Print("Got the Shotgun!")
        TNT1 A 0 A_GiveInventory("Shotgun",1)
        Goto ExpOrb
    }
}

[XASSASSINX]

Kinda of. The reason as to why is of the Token Items, so the game can remember which items you gave. It's because i want to try to make a basic Tier System, so the in the first tier is that the first 3 items you will get when you level up will be randomized between them. Then Tier 2, 3 random items between them, and so on. I'm not sure who complicated this would be on Zscript (Albeit Zscript is a more fancier version of Decorate per say)

[Jarewill]

So something like this?

---

Code: Select all

ACTOR ExpOrb2 : CustomInventory
{
    Inventory.Amount 1
    Inventory.MaxAmount 99999
    Inventory.PickupMessage "Got some Exp"
    +INVENTORY.KEEPDEPLETED
    +INVENTORY.AUTOACTIVATE
    Scale 0.2
    States
    {
    Spawn:
        BON1 ABCDCB 6 Bright
        Loop
    Pickup:
        TNT1 A 0 A_RailWait
        Stop
    Use:
        TNT1 A 0 A_Overlay(-100,"ExpOrb")
        Fail
    ExpOrb:
        TNT1 A 1
        TNT1 A 0 A_JumpIfInventory("ExpOrb2",50,"LevelUp")
        Loop
    LevelUp:
        TNT1 A 0 A_TakeInventory("ExpOrb2",50)
        TNT1 A 0 A_JumpIfInventory("ExpTier",2,"Tier2")
        TNT1 A 0 A_JumpIfInventory("ExpTier",1,"Tier1")
        Goto Tier0
    Tier0:
        TNT1 A 0 A_GiveInventory("ExpT0",1)
        TNT1 A 0 {If(CountInv("ExpT0")>=3){A_GiveInventory("ExpTier",1);}}
        TNT1 A 0 A_Jump(256,1,2,3)
        TNT1 A 0 {A_Print("Got the Shotgun!"); A_GiveInventory("Shotgun",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the Chaingun!"); A_GiveInventory("Chaingun",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the Armor!"); A_GiveInventory("GreenArmor",1);}
        Goto ExpOrb
    Tier1:
        TNT1 A 0 A_GiveInventory("ExpT1",1)
        TNT1 A 0 {If(CountInv("ExpT1")>=3){A_GiveInventory("ExpTier",1);}}
        TNT1 A 0 A_Jump(256,1,2,3)
        TNT1 A 0 {A_Print("Got the Super Shotgun!"); A_GiveInventory("SuperShotgun",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the Rocket Launcher!"); A_GiveInventory("RocketLauncher",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the MegaArmor!"); A_GiveInventory("BlueArmor",1);}
        Goto ExpOrb
    Tier2:
        TNT1 A 0 A_Jump(256,1,2,3)
        TNT1 A 0 {A_Print("Got the Plasma Gun!"); A_GiveInventory("PlasmaRifle",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the BFG9000!"); A_GiveInventory("BFG9000",1);}
        Goto ExpOrb
        TNT1 A 0 {A_Print("Got the Megasphere!"); A_GiveInventory("Megasphere",1);}
        Goto ExpOrb
    }
}
ACTOR ExpTier : Inventory {Inventory.MaxAmount 2}
ACTOR ExpT0 : Inventory {Inventory.MaxAmount 3}
ACTOR ExpT1 : Inventory {Inventory.MaxAmount 3}

[XASSASSINX]

Yeah, kinda like that. The only thing i will add (or rather, you can if you want to) is whenever a item is given such as the plasma rifle, give a Token Item so the game does a quick check to see if you have that. I think you can make that in two lines or so in Zscript.

Oh, sidenote, i'm not sure if you made this intetionally, but on the Item Drop Handler code, if a monster has a health value which is not the same as the Int, it will split the item drops in smaller pickups. I'm pretty sure if you alter it so it doesn't subtract the Intenger, but rather change it to zero, it should "fix" this.

Just putting this little note in case anyone need this thread in a possible future

Code: Select all

 Else If(itemdrops>=1000){e.Thing.A_DropItem("Cell"); itemdrops-=1000;}

VVVVV Goes To VVVVVV

Code: Select all

 Else If(itemdrops>=1000){e.Thing.A_DropItem("Cell"); itemdrops=1000;}

[Jarewill]

Detecting items like this?

---

Code: Select all

ACTOR ExpOrb2 : CustomInventory
{
    Inventory.Amount 1
    Inventory.MaxAmount 99999
    Inventory.PickupMessage "Got some Exp"
    +INVENTORY.KEEPDEPLETED
    +INVENTORY.AUTOACTIVATE
    Scale 0.2
    States
    {
    Spawn:
        BON1 ABCDCB 6 Bright
        Loop
    Pickup:
        TNT1 A 0 A_RailWait
        Stop
    Use:
        TNT1 A 0 A_Overlay(-100,"ExpOrb")
        Fail
    ExpOrb:
        TNT1 A 1
        TNT1 A 0 A_JumpIfInventory("ExpOrb2",50,"LevelUp")
        Loop
    LevelUp:
        TNT1 A 0 A_TakeInventory("ExpOrb2",50)
        TNT1 A 0 A_JumpIfInventory("ExpTier",3,"ExpOrb")
        TNT1 A 0 A_JumpIfInventory("ExpTier",2,"Tier2")
        TNT1 A 0 A_JumpIfInventory("ExpTier",1,"Tier1")
        Goto Tier0
    Tier0:
        TNT1 A 0 A_GiveInventory("ExpT0",1)
        TNT1 A 0 {If(CountInv("ExpT0")>=3){A_GiveInventory("ExpTier",1);}}
    Tier0t:
        TNT1 A 0 A_Jump(256,1,3,5)
        TNT1 A 0 A_JumpIfInventory("Shotgun",1,"Tier0t")
        TNT1 A 0 {A_Print("Got the Shotgun!"); A_GiveInventory("Shotgun",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("Chaingun",1,"Tier0t")
        TNT1 A 0 {A_Print("Got the Chaingun!"); A_GiveInventory("Chaingun",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("Chainsaw",1,"Tier0t")
        TNT1 A 0 {A_Print("Got the Chainsaw!"); A_GiveInventory("Chainsaw",1);}
        Goto ExpOrb
    Tier1:
        TNT1 A 0 A_GiveInventory("ExpT1",1)
        TNT1 A 0 {If(CountInv("ExpT1")>=3){A_GiveInventory("ExpTier",1);}}
    Tier1t:
        TNT1 A 0 A_Jump(256,1,3,5)
        TNT1 A 0 A_JumpIfInventory("SuperShotgun",1,"Tier1t")
        TNT1 A 0 {A_Print("Got the Super Shotgun!"); A_GiveInventory("SuperShotgun",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("RocketLauncher",1,"Tier1t")
        TNT1 A 0 {A_Print("Got the Rocket Launcher!"); A_GiveInventory("RocketLauncher",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("Backpack",1,"Tier1t")
        TNT1 A 0 {A_Print("Got the Backpack!"); A_GiveInventory("Backpack",1);}
        Goto ExpOrb
    Tier2:
        TNT1 A 0 A_GiveInventory("ExpT2",1)
        TNT1 A 0 {If(CountInv("ExpT2")>=3){A_GiveInventory("ExpTier",1);}}
    Tier2t:
        TNT1 A 0 A_Jump(256,1,3,5)
        TNT1 A 0 A_JumpIfInventory("PlasmaRifle",1,"Tier2t")
        TNT1 A 0 {A_Print("Got the Plasma Gun!"); A_GiveInventory("PlasmaRifle",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("BFG9000",1,"Tier2t")
        TNT1 A 0 {A_Print("Got the BFG9000!"); A_GiveInventory("BFG9000",1);}
        Goto ExpOrb
        TNT1 A 0 A_JumpIfInventory("PowerStrength",1,"Tier2t")
        TNT1 A 0 {A_Print("Got the Berserk!"); A_GiveInventory("PowerStrength",1);}
        Goto ExpOrb
    }
}
ACTOR ExpTier : Inventory {Inventory.MaxAmount 3}
ACTOR ExpT0 : Inventory {Inventory.MaxAmount 3}
ACTOR ExpT1 : Inventory {Inventory.MaxAmount 3}
ACTOR ExpT2 : Inventory {Inventory.MaxAmount 3}

Also please don't do that with the handler.
It will result in an infinite zero-duration loop and will freeze the game.

[XASSASSINX]

Code: Select all

It will result in an infinite zero-duration loop and will freeze the game.

Huh. Interesting, From what i've tested it seems to work fine. Care to explain?

[Jarewill]

I have just tested it and changing:

Code: Select all

itemdrops-=1000;

Into:

Code: Select all

itemdrops=1000;

Will freeze the game if you kill an enemy that has 1000 health or more.

The reason behind that is that it sets the itemdrops integer to the value of a monster's spawn health.
Then it subtracts the value from that integer and spawns an item.
That way it spawns various items based on the health of the enemy.

However if you change -= into just = in any of the lines, it will cause it to set the value to the number instead of subtracting it.
What happens then is an infinite zero-duration loop that will keep spawning the same item without ever stopping, freezing the game in the process.

[XASSASSINX]

Interesting. Anyhow, Like last time, i will credit you if this mod ever gets public. I've made some final adjusments like implemeting a Cvar with my custom EXP orb.

Code: Select all

Class SmallExpOrbSpawner : Actor
{
 Default
 {
  +NOINTERACTION
 }
  States
 {
  Spawn:
   TNT1 AAAA 0 NoDelay A_SpawnItemEx("ExpOrb1", 0, 0, 0, frandom(-0.6, 0.6), frandom(-0.6, 0.8), frandom(-0.9, 0.9), 0, 0, (256 * (GetCVar("cl_XPSpawnAmount"))));
   Stop;
 }
}

Along some other minor stuff, like Gldefs and what not.

Also, mind i ask, why did you override this part of the custom inventory?

Code: Select all

    }
    Override void AttachToOwner(Actor other)
    {
        Super.AttachToOwner(other);
        other.A_GiveInventory("ExpOrb1", 1); //Bigger pickup, give 10
        Destroy();
    }
 }

From what i understand of little Zscript, you override the generic PickUp State and changed it to the same thing...?

[Jarewill]

That override is only on the ExpOrbBig and ExpOrbHuge items, which aren't ExbOrb.
It's there so they can give the ExpOrb item in larger quantities.

[XASSASSINX]

I have just tested it and changing:

Code: Select all

itemdrops-=1000; 

Into:

Code: Select all

itemdrops=1000; 

Will freeze the game if you kill an enemy that has 1000 health or more.

The reason behind that is that it sets the itemdrops integer to the value of a monster's spawn health.
Then it subtracts the value from that integer and spawns an item.
That way it spawns various items based on the health of the enemy.

However if you change -= into just = in any of the lines, it will cause it to set the value to the number instead of subtracting it.
What happens then is an infinite zero-duration loop that will keep spawning the same item without ever stopping, freezing the game in the process.

Sorry for the response time, but just this wrap one final thing up, what i meant to say here (or rather, do) was to change the integer to 0 whenever a monster died, as to not spawn multiple "exp spawners". Like this:

Code: Select all

Else If (itemdrops>=3000){e.Thing.A_DropItem("SupremeEXPOrbSpawner"); itemdrops=0;}

It changes to zero, not change it to itself lol, i knew that would crash it

Anyway, final thanks for the script!! credits are on the files if i ever publish this.