Micromod: Quake-like Wall Friction 1.1

[Ivory Duke]

I AM NO LONGER INVOLVED IN DOOM MODDING, YOU ARE FREE TO USE THIS A YOU PLEASE (JUST MENTION MY NAME SOMEWHERE IN THE CREDITS OUT OF CURTESY).

NOTE: THE PK3 ONLY WORKS WITH VANILLA DOOM. TO WORK WITH MODS YOU WILL NEED TO EDIT THE PLAYER'S CODE.
REQUIRES GZDOOM 3.8.0 OR HIGHER. FEEL FREE TO USE TO YOUR LIKING, JUST WRITE SOMEWHERE I WAS THE ORIGINAL CREATOR

An only mildly hacky way to force Quake-like wall friction onto player movement.
What is Quake-like wall friction?
When you touch a wall your velocity is not decimated but is perfectly redirected along the impact surface.

This works on the same concept of the wallslide I coded for ZMovement, which is: GZDoom's P_SlideMove correctly changes the direction player is moving to slide along the wall, but during the process it more or less significantly decreases the player speed.
So all we need to do is keep the velocity vector direction but apply a different length to it.

The mod works around two editable values:
IMPACT_ANGLE_TOLERANCE, if the dot product of the velocity before and after impact is higher than this value the new velocity will not be demultiplied, otherwise it will be proportionally scaled. Edit the const value keeping in mind that: if VelDot is 1 (impossible) the direction of the old and new velocity is the same, 0.5 it means the impacting angle was 45, 0 the angle is 90.
FORCED_VELOCITY_TICS, how many tics velocity length is forced onto the player. 2 works best, but 1 is totally fine if you have a player that moves at regular DoomGuy's (or slower) speed.

Code: Select all

Changelog 1.1:
Slightly changed meaning of const IMPACT_ANGLE_TOLERANCE and added scaling multiplier if the impacting angle is too steep.

A couple of basic demonstration videos
Warning: they are extremely lame. Only watch if you cannot live without doing so



This will eventually be added to ZMovement 3.2, but since the release of this one is not imminent in the meantime I am putting it here in case it is interests anybody.
DOWNLOAD HERE

Code for people who don't want to download the pk3.

---

Code: Select all

Class QWallPlayer : DoomPlayer
{
	//if lowered to 0 the only situation where player's movement will be scaled is when it collides
	//against a wall with an angle of 90 degrees
	const IMPACT_ANGLE_TOLERANCE = 0.5f;
	//More than 2 is not recommended, 1 is fine but may not always work
	const FORCED_VELOCITY_TICS = 2;
	
	int ForceVelocity;
	vector2 OldVelXY;
	
	Override void HandleMovement()
	{
		QWallFriction();
		Super.HandleMovement();
		
		OldVelXY = Vel.XY;
	}
	
	void QWallFriction()
	{
		Let Player = Self.Player;
		UserCmd cmd = Player.cmd;
		
		//The function works based on the fact that the player is re-directed in the correct direction
		//when colliding against a wall, but does not do it in a way that it mantains the previous
		//tic's speed, so we force it for a couple tics to help code properly slide player against the
		//wall surface, but only as long as: the previous and current speed is not 0 (otherwise player
		//is slingshot in a bottomless black void) and player is pressing directional inputs.
		
		if(ForceVelocity)
		{
			if(OldVelXY.Length() && Vel.XY.Length() && (cmd.forwardmove || cmd.sidemove))
			{
				Vector2 VelUnit = Vel.XY.Unit();
				Float VelDot = OldVelXY.Unit() dot VelUnit;
				if(VelDot > 0)
				{
					if(VelDot > IMPACT_ANGLE_TOLERANCE)
						VelDot = 1.f;
					else
						VelDot /= IMPACT_ANGLE_TOLERANCE;
					
					Vel.XY = VelDot * OldVelXY.Length() * VelUnit;
				}
				ForceVelocity--;
			}
			else
			{
				ForceVelocity = 0;
			}
		}
		
		//If CheckMove() is false it means player will collide with a solid surface next tic
		if(!CheckMove(Pos.XY + Vel.XY)) { ForceVelocity = FORCED_VELOCITY_TICS; }
	}
}

/*
//Alternative OldVelXY multiplier, replace line 44
VelDot = 1 - (IMPACT_ANGLE_TOLERANCE - VelDot);
*/

[Ivory Duke]

1.1, I think this is it

[RikohZX]

I guess this technically means you've created the capability for Surf in Doom, huh? Interesting work, I forgot that wall collisions cripple your speed.

[StroggVorbis]

What about Quake 1/Half-Life style slope physics/friction, like sliding them down and slowly climbing upwards when directly running into them? Would it be possible to recreate this with ZScript?

[Ivory Duke]

I made "Trimping" which is slope jumping and will be available as an option in the next ZMovement.
Source-Q1 slope sliding is only possible going down slopes, when you try to go up a slope the engine immediately makes your velocity 1 in the downward slope direction.
Furthermore GZDoom has inconsistent behavior between non 3D slopes and 3D slopes with an angle higher than 45.
It is doable by making a custom GZDoom version which removes its hardcoded slope behavior (which I have identified), but of course mantaining a custom GZDoom build for just one thing is out of question

[Captain J]

Oh yeah... I tend to have some serious problem with the walls of Vanilla Doom. No matter how far away from it, short or thin, you get stuck and lose all the momentum nonetheless. It's not Wolf 3D, but still.

But i'm glad you managed to fix this particular problem! So i guess you also could bounce off walls and boost up the speed like a super ball?

[Ivory Duke]

So i guess you also could bounce off walls and boost up the speed like a super ball?

Yes. Tested, works.

Code: Select all

Class BouncyPlayer : DoomPlayer
{
	const P_BOUNCE_FACTOR = 1;
	
	bool BounceForMe;
	vector2 OldVelXY;
	
	Override void HandleMovement()
	{
		Boing();
		Super.HandleMovement();
		OldVelXY = Vel.XY;
	}
	
	void Boing()
	{
		if(BounceForMe)
		{
			if(OldVelXY.Length() && Vel.XY.Length())
			{
				Vector2 WallNormal = (Vel.Y, Vel.X).Unit();
				Float ImpactDot = OldVelXY dot WallNormal;
				Vel.XY = OldVelXY - 2 * ImpactDot * WallNormal;
				Vel.XY *= P_BOUNCE_FACTOR;
			}
			BounceForMe = False;
		}
		
		if(!CheckMove(Pos.XY + Vel.XY)) { BounceForMe = True; }
	}
}