Something wrong with these sounds? [SOLVED]

[Zemakat]

So I'm working on a zombie modification and decide to give a bandit some sounds. All these sounds are OGG format as well. As well as his Bandit/Hit sounds being WAV, and not playing either.

Whensoever I decide to go into the game, his sounds don't seem to play, it's only the default grunt/attack sounds. I can't tell whether I did something wrong in the SNDINFO or his DECORATE code. Nothing seems to be misspelled...

Here's both of his codes in DECORATE and SNDINFO.

---

Actor Bandit
{
Radius 20
Height 56
Health 75
GibHealth -30
Painchance 170
Speed 10
MONSTER
+NOINFIGHTING
+FLOORCLIP
+QUICKTORETALIATE
+AVOIDMELEE
SeeSound "Bandit/See"
ActiveSound "Bandit/Active"
PainSound "*pain100"
DeathSound "*death"
Obituary "%o has been shot!"
Translation "112:123=104:111","124:127=0:0"
States
{
Spawn:
VAR7 A 0 Thing_ChangeTID(0,150)
VAR7 A 7 A_Wander
VAR7 A 0 A_LookEx(0,0,1280)
VAR7 B 7 A_Wander
VAR7 B 0 A_LookEx(0,0,1280)
VAR7 C 7 A_Wander
VAR7 C 0 A_LookEx(0,0,1280)
VAR7 D 7 A_Wander
VAR7 D 0 A_LookEx(0,0,1280)
VAR7 A 0 Thing_Hate(0,160,3)
See:
VAR7 A 0 A_JumpIfHealthLower(40,"SpeedMode")
VAR7 AABBCCDD 4 A_Chase
loop
Missile:
VAR7 E 4 A_FaceTarget
VAR7 E 0 A_PlaySound("grunt/attack")
VAR7 F 3 Bright A_CustomBulletAttack(10, 10, 1, 8, "BulletPuff")
VAR7 E 4 A_FaceTarget
VAR7 E 0 A_PlaySound("grunt/attack")
VAR7 F 3 Bright A_CustomBulletAttack(10, 10, 1, 8, "BulletPuff")
VAR7 E 4 A_FaceTarget
VAR7 E 0 A_PlaySound("grunt/attack")
VAR7 F 3 Bright A_CustomBulletAttack(10, 10, 1, 8, "BulletPuff")
VAR7 E 0 A_SentinelRefire
loop
Melee:
VAR7 A 3 A_FaceTarget
VAR7 E 5 A_CustomMeleeAttack(5,"Bandit/Hit","","Melee")
VAR7 A 3
goto See
SpeedMode:
VAR7 A 0 A_JumpIfHealthLower(15,"ImOuttaHere")
VAR7 ABCD 4 A_Chase
VAR7 ABCD 4 A_FastChase
loop
ImOuttaHere:
VAR7 A 0 A_ChangeFlag("FRIGHTENED",1)
VAR7 A 0 A_PlaySound("Bandit/Flee")
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
VAR7 ABCD 2 A_Chase
VAR7 ABCD 2 A_FastChase
loop
Pain:
VAR7 G 3
VAR7 G 3 A_Pain
goto See
Death:
VAR7 H 10
VAR7 I 10 A_Scream
VAR7 JKLM 10
VAR7 N 1800
VAR7 MLKJIH 10
TNT1 A 0 A_NoBlocking
TNT1 A 0 A_SpawnItemEx("BanditFleshEater",0,0,0,0,0,0,0)
stop
XDeath:
VAR7 O 5
VAR7 P 5 A_XScream
VAR7 Q 5 A_NoBlocking
VAR7 RSTUV 5
VAR7 W -1
stop
}
}

---

//Bandit

Bandit/Hit DSBANDITL

Bandit/See1 DSBANDITE1
Bandit/See2 DSBANDITE2
Bandit/See3 DSBANDITE3

Bandit/Active1 DSBANDITT1
Bandit/Active2 DSBANDITT2
Bandit/Active3 DSBANDITT3

Bandit/Flee1 DSBANDITEE1
Bandit/Flee2 DSBANDITEE2
Bandit/Flee3 DSBANDITEE3

//Weapons

AssaultRifle/Fire1 M16F1
AssaultRifle/Fire2 M16F2
AssaultRifle/Fire3 M16F3

$random Zombie/See { Zombie/See1 Zombie/See2 Zombie/See3 }
$random Zombie/Active { Zombie/See1 Zombie/See2 Zombie/See3 }
$random Zombie/Die { Zombie/Die1 Zombie/Die2 Zombie/Die3 }
$random Bandit/See { Bandit/See1 Bandit/See2 Bandit/See3 }
$random Bandit/Active { Bandit/Active1 Bandit/Active2 Bandit/Active3 }
$random Bandit/Flee { Bandit/Flee1 Bandit/Flee2 Bandit/Flee3 }
$random AssaultRifle/Fire { AssaultRifle/Fire1 AssaultRifle/Fire2 AssaultRifle/Fire3 }

EDIT: Forgot to give the file. http://www.mediafire.com/file/nngh2p62x ... Brains.pk3

[Voros]

Put the sounds in the "sounds" folder. I haven't looked inside the PK3 though.
Make sure to its something like this in SNDINFO:

This is an example.

Code: Select all

Bandit/Flee1 "sounds/DSBANDITEE1.ogg"

If the sounds don't have a file extension, then don't add one in SNDINFO.

[Zemakat]

Put the sounds in the "sounds" folder. I haven't looked inside the PK3 though.
Make sure to its something like this in SNDINFO:

This is an example.

Code: Select all

Bandit/Flee1 "sounds/DSBANDITEE1.ogg"

If the sounds don't have a file extension, then don't add one in SNDINFO.

Hey...it works! That was surprisingly simple. Thanks!

[Graf Zahl]

The reason here is actually quite simple: A default lump name is only 8 characters. And all your sound names are longer so you got to use their full path.

[Enjay]

Yes, I tend to try to keep my file names at 8 characters and under and I can use the simpler format originally posted.

There's nothing wrong with using full path names, of course. Using 8 characters is probably just a habit I picked up from making WAD files for so many years where the longest name possible is 8 characters.

[Voros]

I prefer writing out the whole thing. It's more concise that way if you ask me.