[SOLVED] Adding a spin alt-fire to a chaingun?

[Dan_The_Noob]

I think you would need to have a check of some kind in the ready state and AltFire basically be just adding or removing the "toggle" (which could be done like pistolmag with 1 bullet)

something like

Code: Select all

AltFire:
{
A_JumpIfInventory("Spinner",1,3)
A_GiveInventory("Spinner", 1)
goto Ready
A_TakeInventory("Spinner",1)
goto Ready
}

then some spin thing in ready based around A_JumpIfInventory("Spinner",1,##) I guess?
I haven't tried this type of thing, i don't like idle sounds

[Matt]

A ZScript lump is just a file called "zscript" like a Decorate lump is just a file called "decorate".

[Alexagon]

A ZScript lump is just a file called "zscript" like a Decorate lump is just a file called "decorate".

Okay, yeah I did that. I didn't seem to do anything ingame though.

[Matt]

Did you do the other stuff in that post though? (and do *not* try to combine what I'm saying with what Dan is saying, I believe we are working at cross purposes here)

---

If you make ModWeapon (or whichever of its ancestors inherits from Weapon) inherit from this ZS-defined actor instead:

Code: Select all

class JumpButtonWeapon:Weapon{
    action void A_JumpIfPressing(int button,statelabel stt,int layer=PSP_WEAPON){
        if(player.cmd.buttons&button)player.setpsprite(layer,invoker.findstate(stt));
    }
    action void A_JumpIfPressingFire(statelabel stt){
        A_JumpIfPressing(BT_ATTACK,stt);
    }
    action void A_JumpIfPressingAltfire(statelabel stt){
        A_JumpIfPressing(BT_ALTATTACK,stt);
    }
}

and then in althold replace "VLCN ABCD 1" with

Code: Select all

VLCN ABCD 1 A_JumpIfPressingFire("hold")

and then in hold, just before the A_Refire line, add

Code: Select all

TNT1 A 0 A_JumpIfPressingAltfire("althold")

I think you can approximate what you need.

[Alexagon]

Did you do the other stuff in that post though? (and do *not* try to combine what I'm saying with what Dan is saying, I believe we are working at cross purposes here)

---

If you make ModWeapon (or whichever of its ancestors inherits from Weapon) inherit from this ZS-defined actor instead:

Code: Select all

class JumpButtonWeapon:Weapon{
    action void A_JumpIfPressing(int button,statelabel stt,int layer=PSP_WEAPON){
        if(player.cmd.buttons&button)player.setpsprite(layer,invoker.findstate(stt));
    }
    action void A_JumpIfPressingFire(statelabel stt){
        A_JumpIfPressing(BT_ATTACK,stt);
    }
    action void A_JumpIfPressingAltfire(statelabel stt){
        A_JumpIfPressing(BT_ALTATTACK,stt);
    }
} 

and then in althold replace "VLCN ABCD 1" with

Code: Select all

VLCN ABCD 1 A_JumpIfPressingFire("hold")

and then in hold, just before the A_Refire line, add

Code: Select all

TNT1 A 0 A_JumpIfPressingAltfire("althold")

I think you can approximate what you need.

I did, and this is what I get:

Script error, "li-wpnitm.pk3:actors/weapons/minigun.txt" line 149:
Invalid parameter 'a_jumpifpressingfire'

[Matt]

Did you also do the "If you make ModWeapon (or whichever of its ancestors inherits from Weapon) inherit" part?

[Void Weaver]

Alexagon, maybe my english are too bad but I still don't understand what (alt-)firing effects you want to achieve? Should is Altfire mode supposed to be are sorta of toggleable (by alt-fire button) wind-up "awaited-for-Fire-button" state?

I want it so that while holding the altfire key, the barrel on the minigun spins and only spins. Then if I press fire while the barrel is spinning, I want it to fire without any delay.

Essentially I want to be able to be prepared to shoot with the minigun instead of waiting for the first few frames to pass before actually firing.

Oh, got it. Well that's easy, even without any scripts. There are 2 variants:

VAR #1 - this is the same mechanics which you looking for. While you hold Alt-fire barrels are spin, if you press Fire at the same time it will immediately shoots.

Code: Select all

Actor WindUpChecker : Inventory {Inventory.MaxAmount 1}

Actor HoldChaingun : Chaingun replaces Chaingun
{
   Weapon.AmmoUse1 1
   Weapon.AmmoUse2 1
   Weapon.AmmoType1 "Clip"
   Weapon.AmmoType2 "Clip"
   Weapon.SlotNumber 4
   States
   {
Fire:
      TNT1 A 0 A_JumpIfNoAmmo("Dryfire")
      TNT1 A 0 A_PlaySound ("weapons/minig/start")
      TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,"Hold")
      CHGG B 2 
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG CD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABCD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_Refire
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABCD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABC 2 A_WeaponReady
      CHGG DABCDAB 3 A_WeaponReady
      CHGG CD 4 A_WeaponReady
      Goto Ready
   Altfire:
      TNT1 A 0 A_TakeInventory("WindUpChecker")
	  TNT1 A 0 A_PlaySound ("weapons/minig/start")
   AltHold:
	  TNT1 A 0 A_PlaySound("weapons/minig/spin",6)
      CHGG ABCD 1 
	  {
	  A_WeaponReady(WRF_DISABLESWITCH|WRF_NOSWITCH|WRF_NOSECONDARY);
	  A_GiveInventory("WindUpChecker");
	  }
	  VLCN A 0 A_Refire
   AltWinddown:
      CHGG ABCDAABBCCDD 1
      TNT1 A 0 A_TakeInventory("WindUpChecker")
	  goto ready
    Hold:
      TNT1 A 0 A_TakeInventory("WindUpChecker")
      TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("ToggleMinigun")==0, "NoReloadHold")
      TNT1 A 0 A_JumpIfNoAmmo("EmptyWindDown")
      TNT1 A 0 A_AlertMonsters
      TNT1 A 0 A_PlaySound("weapons/minig/spin",6)
      TNT1 A 0 A_GunFlash
      CHGG A 1 Offset(0,35) A_FireBullets (5, 5, 1, 8, "BulletPuff")
      TNT1 A 0 Radius_Quake (1, 2, 0, 1, 0)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch-1.0)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG B 1 Offset(0,37) A_Firecustommissile("ChaingunCasingSpawner",0,0,-12,-18)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG C 1 Offset(0,39) A_FireBullets (5, 5, 1, 8, "BulletPuff")
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch-0.6)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_Firecustommissile("ChaingunCasingSpawner",0,0,-12,-18)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG D 1 Offset(0,37)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch+1.6)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_ReFire
	  Goto Ready
	  }
}

VAR #2 - this a bit different mechanics. Alt-fire itself consist from 2 toggleable modes: spin on\spin off. While in spin mode it also will immediately shoots while Fire is pressed.

Code: Select all

Actor ToggleChaingun : Chaingun replaces Chaingun
{
   Weapon.AmmoUse1 1
   Weapon.AmmoUse2 1
   Weapon.AmmoType1 "Clip"
   Weapon.AmmoType2 "Clip"
   Weapon.SlotNumber 4
   States
   {
	Fire:
      TNT1 A 0 A_JumpIfNoAmmo("Dryfire")
      TNT1 A 0 A_PlaySound ("weapons/minig/start")
      TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,"Hold")
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG B 2 
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG CD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABCD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_Refire
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABCD 1 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG ABC 2 A_WeaponReady
      CHGG DABCDAB 3 A_WeaponReady
      CHGG CD 4 A_WeaponReady
      Goto Ready
   
	Altfire:
   	  CHGG ABCD 1
	  TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,3)
	  TNT1 A 0 A_GiveInventory("WindUpChecker")
	  TNT1 A 0 A_PlaySound ("weapons/minig/start")
	  Goto AltHoldd
      TNT1 A 0 A_TakeInventory("WindUpChecker")
	  Goto AltWinddown
	AltHoldd:
	  TNT1 A 0 A_PlaySound("weapons/minig/spin",6)
      CHGG ABCD 1 
	  {
	  A_WeaponReady(WRF_DISABLESWITCH|WRF_NOSWITCH);
	  If(CountInv("WindUpChecker")==0){Return state("AltWinddown");}
      Else{Return state("");}
	  }
	  Loop
    AltWinddown:
      CHGG ABCDAABBCCDD 1
      CHGG AABBCCDD 2
	  Goto Ready
    Hold:
      TNT1 A 0 A_JumpIf(ACS_NamedExecuteWithResult("ToggleMinigun")==0, "NoReloadHold")
      TNT1 A 0 A_JumpIfNoAmmo("EmptyWindDown")
      TNT1 A 0 A_AlertMonsters
      TNT1 A 0 A_PlaySound("weapons/minig/spin",6)
      TNT1 A 0 A_GunFlash
      CHGG A 1 Offset(0,35) A_FireBullets (5, 5, 1, 8, "BulletPuff")
      TNT1 A 0 Radius_Quake (1, 2, 0, 1, 0)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch-1.0)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG B 1 Offset(0,37) A_Firecustommissile("ChaingunCasingSpawner",0,0,-12,-18)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG C 1 Offset(0,39) A_FireBullets (5, 5, 1, 8, "BulletPuff")
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch-0.6)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_Firecustommissile("ChaingunCasingSpawner",0,0,-12,-18)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      CHGG D 1 Offset(0,37)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_SetPitch(pitch+1.6)
      TNT1 A 0 A_WeaponReady(WRF_NoFire|WRF_NoSwitch)
      TNT1 A 0 A_ReFire
	  TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,"AltHoldd")
	  Goto Ready
	  }
}

I did use your basic code, so I have replace your sprites with vanilla CHgun ones.

EDIT:
Code bugs fixed.

[Alexagon]

Thanks, Void Weaver, that variation 1 worked perfectly.

Thanks so much! To all of you, I really appreciate the help.

[Void Weaver]

Glad to help. ^_^

But I forget to place else one "TNT1 A 0 A_TakeInventory("WindUpChecker")" line right after entering into "Hold" state of the 1st variant - without it a some glitch are possible.
Also "TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,"Hold")" lines in both variants should be logically moved down and placed after "TNT1 A 0 A_PlaySound ("weapons/minig/start")".

[Alexagon]

Glad to help. ^_^

But I forget to place else one "TNT1 A 0 A_TakeInventory("WindUpChecker")" line right after entering into "Hold" state of the 1st variant - without it a some glitch are possible.
Also "TNT1 A 0 A_JumpIfInventory("WindUpChecker",1,"Hold")" lines in both variants should be logically moved down and placed after "TNT1 A 0 A_PlaySound ("weapons/minig/start")".

I added that first line.

I'm having an issue now: Chaingun drops from chaingunners can't be picked up anymore. I added the spawn function to the HoldChaingun actor to get them to even appear but now they don't do anything. I added a pickup line after the spawn one but that didn't do anything.

[Void Weaver]

What is HoldChaingun actor?
If it CustomInventory item then seems that you made a some mistake in its states.

[Dan_The_Noob]

I added that first line.

I'm having an issue now: Chaingun drops from chaingunners can't be picked up anymore. I added the spawn function to the HoldChaingun actor to get them to even appear but now they don't do anything. I added a pickup line after the spawn one but that didn't do anything.

try add an "+ALWAYSPICKUP" flag to the chaingun?

[Alexagon]

I added that first line.

I'm having an issue now: Chaingun drops from chaingunners can't be picked up anymore. I added the spawn function to the HoldChaingun actor to get them to even appear but now they don't do anything. I added a pickup line after the spawn one but that didn't do anything.

try add an "+ALWAYSPICKUP" flag to the chaingun?

I tried that, it makes so it says "You got a pickup" and does nothing else. i know how to get it to give me ammo but how do i make it so that it gives me the actual weapon?

Also, do either of you know how to make a custom ammo drop? I'm trying to make a box of bolts for my cryobow, but when I do a randomspawner for the rocket box and box of bolts, it doesn't spawn the bolts. I made a custom ammo for single bolts with a randomspawner for single rockets and that works just fine. It's the box that doesn't work. Here's the code for that:

---

Code: Select all

ACTOR RocketAmmo2 : RocketAmmo replaces RocketAmmo
{
	Inventory.PickupSound "items/rocket"
}

ACTOR Bolt : Ammo //Cryobow Ammo
{
	Inventory.Amount 2
	Inventory.MaxAmount 50
	Inventory.Icon "ABOWC0"
	Ammo.BackpackAmount 2
	Ammo.BackpackMaxAmount 100
	Inventory.PickupSound "misc/crateopen"
	Inventory.PickupMessage "Picked up some cryo bolts."
	States
	{
	Spawn:
		ABOW C -1
		Stop
	Pickup:
		TNT1 A 0 A_GiveInventory ("Bolt", 2)
	}
}

ACTOR BoxOfBolts : Ammo //Cryobow Ammo
{
	Inventory.Amount 10
	Inventory.MaxAmount 50
	Inventory.Icon "BLTBA0"
	Ammo.BackpackAmount 10
	Ammo.BackpackMaxAmount 100
	Inventory.PickupSound "misc/crateopen"
	Inventory.PickupMessage "Picked up a box of cryo bolts."
	States
	{
	Spawn:
		BLTB A -1
		Stop
	Pickup:
		TNT1 A 0 A_GiveInventory ("Bolt", 10)
	}
}
ACTOR Bolt/Rocket : RandomSpawner replaces RocketAmmo
{
	DropItem RocketAmmo2
	DropItem Bolt
}

ACTOR Bolts/Rockets : RandomSpawner replaces RocketBox
{
	DropItem RocketBox2
	DropItem BoxOfBolts
}
ACTOR RocketBox2 : RocketBox replaces RocketBox
{
	Inventory.PickupSound "items/rocketb"
}

[Void Weaver]

Oh, no... The Pickup state Curse strikes again. :\

The "Pickup:" state works ONLY FOR CustomInventory items. And it was already mentioned in your previous thread.
Btw, looks that you have the same trouble as TS of this thread, check it.

[Dan_The_Noob]

I tried that, it makes so it says "You got a pickup" and does nothing else. i know how to get it to give me ammo but how do i make it so that it gives me the actual weapon?

Also, do either of you know how to make a custom ammo drop? I'm trying to make a box of bolts for my cryobow, but when I do a randomspawner for the rocket box and box of bolts, it doesn't spawn the bolts. I made a custom ammo for single bolts with a randomspawner for single rockets and that works just fine. It's the box that doesn't work. Here's the code for that:

if you have 1 working example of an ammo pickup you can pretty much just copy it with different values to make another.
I did this to fix some wonky ammo types.

Here's one for a box of nails

---

Code: Select all

// Actor Nails : Ammo
// {
//   Radius 16
//   Height 8
//   Inventory.PickupMessage "Picked up a Box of Nails" 
//   Inventory.Icon "NLPJI0" //Icon shown on status bar
//   Inventory.Amount 35 //amount given from pickup
//   Inventory.MaxAmount 125 // amount held without backpack
//   Ammo.BackpackAmount 25 // amount given from "backpack" (i usually delete this)
//   Ammo.BackpackMaxAmount 250 //amount held with backpack
//   States
//   {
//   Spawn:
//     NBOX A -1
//     Stop
//   }
// }