Infinite ammo weapons and cooldowns

[Ac!d]

Weapons mod idea:

All your weapons have infinite ammo (which gives room for more situational weapons and more items on ammo pickups),

BUT

The more you you use them, the worse they get, until they deal the minimal damage possible, and you must wait them for recharge in the background if you want to use them full power again (although you can still use them if you ever need to, no restrictions involved). Ammo pickups could help them recharge faster, OR some weapons could recharge faster than others.

Don't know what crossed my mind so i could have this idea. Hope someone makes a good use of it.

- How can I make a "background reload" like in Beautiful Doom but whitout any ammo ? (for exemple in my code with "Int NailgunCharge")
- How could I reload faster a weapon with "fake ammo pickups" (with the utilisation of Inventory and/or Int)

---

Code: Select all

Class Nailgun : Weapon
{
	Int NailgunCharge;
	
	Default
	{
		Weapon.SlotNumber 4;

		Weapon.SelectionOrder 700;
				
		Inventory.PickupMessage "$GOTNAILGUN";
		Inventory.PickupSound "weapons/ngun_pkup";
		Tag "$TAG_NAILGUN";
	}
	States
	{
	Spawn:
		DENG A -1;
		Stop;
	Select:
		TNT1 A 0 A_Raise;
	FinishSelect:
		TNT1 A 5 { Invoker.NailgunCharge == 0; }
		DNGG A 1 A_WeaponOffset(0,90,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,80,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,70,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,60,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,55,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,49,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,44,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,39,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,35,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,33,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,32,WOF_INTERPOLATE);
		"####" A 1 A_WeaponReady(WRF_NOSWITCH|WRF_NOFIRE);
	Ready:
		DNGG A 1 A_WeaponReady();
		Loop;
	Deselect:
		"####" A 0
		{
			If(Health <= 0 && Invoker.NailgunCharge > 0)
				Return ResolveState("DeadThrow");
				// If dead, the player throw the weapon if he's still hot.
			Else 
				{ Invoker.NailgunCharge == 0; }				
				Return ResolveState(Null);
		}
		"####" A 1 A_WeaponOffset(0,33,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,35,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,39,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,44,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,49,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,55,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,60,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,70,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,80,WOF_INTERPOLATE);
		"####" A 1 A_WeaponOffset(0,90,WOF_INTERPOLATE);
		TNT1 A 0 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH);
	FinishDeselect:
		TNT1 A 0 A_Lower;
		Loop;
	DeadThrow:
		TNT1 A 1 { A_FireProjectile("FakeNailgun",0,False,0,0); { Invoker.NailgunCharge == 0; } }
		Goto FinishDeselect;
	Fire:
		TNT1 A 0 A_JumpIfNoAmmo("Ready");
		DNGF A 1 Bright { A_Light1(); A_WeaponOffset(-1,33,WOF_INTERPOLATE); }
		DNGF B 0 Bright
		{
			A_WeaponOffset(-2,34,WOF_INTERPOLATE);
			If(Invoker.NailgunCharge == 100)
			{
				A_FireProjectile("RocketSmokeTrail",0,True,-4);
				A_SetTics(1);
			}
			Else
			{
				A_FireProjectile("Nail",0,True,-4);			
				A_SetTics(2);
			}
			A_AlertMonsters();
			A_Light2();
		}
		DNGF A 1 Bright { A_Light1(); A_WeaponOffset(-1,33,WOF_INTERPOLATE); }
		DNGG A 1 { A_Light0(); A_WeaponOffset(0,32,WOF_INTERPOLATE); }
		DNGG A 1 A_JumpIfNoAmmo("Ready");
		DNGF C 1 Bright { A_Light1(); A_WeaponOffset(1,33,WOF_INTERPOLATE); }
		DNGF D 0 Bright
		{
			A_WeaponOffset(2,34,WOF_INTERPOLATE);
			If(Invoker.NailgunCharge == 100)
			{
				A_FireProjectile("RocketSmokeTrail",0,True,4);
				A_SetTics(1);
			}
			Else
			{
				A_FireProjectile("Nail",0,True,4);
				A_SetTics(2);
			}
			A_AlertMonsters();
			A_Light2();
		}
		DNGF C 1 Bright { A_Light1(); A_WeaponOffset(1,33,WOF_INTERPOLATE); }
		DNGG A 1 { A_Light0(); A_WeaponOffset(0,32,WOF_INTERPOLATE); }
		TNT1 A 0 A_ReFire; 
		Goto Ready;	
	}
}

[spoiler="background reload" code of Beautiful Doom. All Credits to Agent_Ash aka Jekyll Grim Payne]

Code: Select all

// I removed some parts of the original code for keeping the important parts of my request. - Ac!d

Class BDoomWeapon : Weapon abstract
{
	protected int NonselTimer; //counts how long the weapon was deselected, used for automatic background reload
	protected int AutoReloadTime; //the value that NonselTimer is compared to
	property AutoReloadTime : AutoReloadTime;
	
	Default
	{
		BDoomWeapon.AutoReloadTime 60;
		BDoomWeapon.maxOffsetTics 1; //required default values for A_CameraSway. Otherwise it'll crash due to division by zero
		BDoomWeapon.offsetTics -1;
	}
	
	override void DoEffect()
	{
		if (!owner || !owner.player)
			return;
		let plr = owner.player;
		
		Super.DoEffect();
	
		if (!ammo1 || !ammo2 || (ammo1 == ammo2))
			return;
		if (plr.readyweapon == self || ammo1.amount == ammo1.maxamount || ammo2.amount < 1) {
			NonselTimer = 0;
			return;
		}
		if (NonselTimer < AutoReloadTime)
			NonselTimer++;
		else
		{
			while (ammo2.amount > 0 && ammo1.amount < ammo1.maxamount)
			{
				owner.TakeInventory(ammo2.GetClass(),1);
				owner.GiveInventory(ammo1.GetClass(),1);
			}
			if (plr == players[consoleplayer])
				Console.Printf("%s reloaded",GetTag());
			owner.A_StartSound(reloadsound,slot:CHAN_AUTO,flags:CHAN_NOPAUSE,volume:0.5,attenuation:20);
		}			
	}
}

[/spoiler]

[Jarewill]

- For a background reload you would have to override DoEffect and check if the weapon isn't the player's readyweapon:

---

Code: Select all

    int weaponCharge;
    int chargeTimer;
    Override void DoEffect()
    {
        Super.DoEffect();
        If(owner&&owner.player&&!(owner.player.readyweapon is self.GetClassName())&&weaponCharge<100)
        { //If there is an owner, if they are a player, if the selected weapon isn't this one and if the charge is less than 100, continue
            If(chargeTimer>=35){weaponCharge++; chargeTimer=0;} //Increase the charge and reset the timer
            Else{chargeTimer++;} //Add to the timer, 35 is a second
        }
    } 

- You can override TryPickup to make inventory items increase the weapon's variables directly:

---

Code: Select all

    Override bool TryPickup(in out Actor toucher)
    {
        If(toucher&&toucher.FindInventory("WeaponName"))
        { //If the toucher has the weapon
            let gunn = WeaponName(toucher.FindInventory("WeaponName")); //Cast the weapon to a pointer
            If(gunn.weaponCharge<100)
            { //If the charge is below 100, continue
                gunn.weaponCharge+=50; //Increase the charge by an amount
                If(gunn.weaponCharge>100){gunn.weaponCharge=100;} //If the amount is higher than 100, set to 100
                Destroy(); //Remove the pickup
                Return 1; //Pick it up
            }
        }
        Return 0;
    } 

[Ac!d]

The background reload doesn't seems to work and I would like to decrease the weapon's variable to 0.
I made an exemple with a weapon (replaces chainsaw) and an item (replaces zombieman)

test.wad

(11.92 KiB) Downloaded 35 times

[Virathas]

Background Reload doesn't work simply because you have put wrong comparison operator:
You had

Code: Select all

 If(owner&&owner.player&&!(owner.player.readyweapon is self.GetClassName())&&weaponCharge>=100)

instead of

Code: Select all

 If(owner&&owner.player&&!(owner.player.readyweapon is self.GetClassName())&&weaponCharge<=100)

So it only worked if the charge was 100 or more instead of 100 or less