Glitch:Weapon Pickup Sprite Showing Up While Firing

[Xx_aogp_xX]

Well, I'm Making A Mod Named "Shells The Way Id Did" That Just Adds Casings To Doom.
And There Is A Glitch With The Chaingun That Makes The Pickup Sprite Appear On The Corner Of The Screen When You Shoot.

Here Is The Code So Someone Can Fix It.

ACTOR ShelledChaingun : DoomWeapon Replaces Chaingun
{
Weapon.SelectionOrder 700
Weapon.AmmoUse 1
Weapon.AmmoGive 20
Weapon.AmmoType "Clip"
Inventory.PickupMessage "$GOTCHAINGUN" // "You got the chaingun"
Obituary "$OB_MPCHAINGUN" // "%o was mowed down by %k's chaingun."
Tag "$TAG_CHAINGUN"
States
{
Ready:
CHGG A 1 A_WeaponReady
Loop
Deselect:
CHGG A 1 A_Lower
Loop
Select:
CHGG A 1 A_Raise
Loop
Fire:
FIRC B 0 A_SpawnItemEx("Casings",28, 0, 30, 0,5,5,0,"",0,"")
FIRC B 4 A_FireCGun
FIRC C 0 A_SpawnItemEx("Casings",28, 0, 30, 0,5,5,0,"",0,"")
FIRC C 4 A_FireCGun
FIRC C 0 A_ReFire
Goto Ready
Flash:
FIRC A 0 Bright A_Light1
Spawn:
MGUN A -1
Stop
}
}

Can Someone Please Fix This.

[Player701]

Flash:
FIRC A 0 Bright A_Light1
Spawn:
MGUN A -1
Stop

You need at least to add another Stop just before Spawn:, i.e.:

Code: Select all

Flash:
FIRC A 0 Bright A_Light1
Stop // <-- Here
Spawn:
MGUN A -1
Stop

But, also note that your flash state sequence is clearly incorrectly made. You are calling A_Light1 to raise the level of illumination, but there is nothing in your code that resets it afterwards. To fix this error, you have to add a call to A_Light0 to the end of the sequence, while also increasing the duration of the state where A_Light1 is called so that its effect lasts a non-zero amount of time. For example:

Code: Select all

Flash:
FIRC A 4 A_Light1
FIRC A 0 A_Light0
Stop

I don't know if your FIRCA sprite is supposed to be visible, or whether it is just a placeholder and the actual flash is drawn in the main attack state. In the latter case, simply replace it with TNT1.