Retain velocity from a spawned... spawner.

[Grey-Wolf]

TNT1 A 0 A_print("Hello world! Yes, it's me. AGAIN")



I got a lootable closed chest up and working and now I'm writing the loot spawners for when it is opened by the player:

---

Code: Select all

ACTOR OpenCrate
{
  +FloorClip
  Scale 0.5
  States
  {
  Spawn:
  CHOP A 1
  CHOP A 1 A_SpawnItemEx("Armorloot",0,0,0,1,-2,8)
  CHOP A 1 A_SpawnItemEx("Ammoloot",0,0,0,1,2,8)
  CHOP A 1 A_SpawnItemEx("Healingloot",0,0,0,1,0,8)
 
  Rest:
  CHOP A 1
  loop
  } 

Now, here's the catch: each one of the "loot" objects is a random spawner that picks between different items of the same type (of course armor, ammo, and healing items). Since this is just a prototype (there will be more spawn states with more loot combinations of three) and I want them to be randomized, I want those items to retain the velocity of the "loot" spawner actors written above, so the loot won't clip with itself and the three categories always pop up in those 3 directions. Is it possible?

Maybe a pointer with change_velocity? But how can I get the spawner point to the lootable spawned item from the spawner?

[KeksDose]

If you're using RandomSpawner, you may override PostSpawn. There, you can transfer the velocity to the spawned thing.

Code: Select all

override void PostSpawn (Actor spawned) {
   spawned.vel = vel;
} 

That's in zs, though.

edit: You don't even need that. RandomSpawner already does it and it's available in decorate.

[Grey-Wolf]

Nope, just decorate.
These are some example of spawners:

---

Code: Select all

actor ArmorLoot : CustomInventory
{
	+Inventory.QUIET
    States
    {

	 Spawn:
		TNT1 A 0
		TNT1 A 0 A_jump(255, "Spawn1", "Spawn2", "Spawn3", "Spawn4", "Spawn5", "Spawn6")
		loop
		
	Vanilla:	
	Spawn1:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("ArmorBoots",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait
	
	 Spawn2:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("ArmorHelmet",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait
		
	Spawn3:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("ArmorUniform",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40,"Spawn")
		TNT1 A 1
		Wait	
		
	Spawn4:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("MediumArmor",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait	
	
	Spawn5:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx ("HeavyArmorBelt",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait
	
	Spawn6:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx ("Armorbonus",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(100, "Spawn")
		TNT1 A 1
		Wait	
	

}}

actor Healloot : CustomInventory
{
	+Inventory.QUIET
    States
    {

	 Spawn:
		TNT1 A 0
		TNT1 A 0 A_jump(255, "Spawn1", "Spawn2", "Spawn3", "Spawn4", "Spawn5", "Spawn6")
		loop
		
	Vanilla:	
	Spawn1:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("medikit2",0,0,0,velx,vely,velz,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait
	
	 Spawn2:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("stimpack2",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(80, "Spawn")
		TNT1 A 1
		Wait
		
	Spawn3:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("Healthbackpack",0,0,0,velx,vely,velz,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40,"Spawn")
		TNT1 A 1
		Wait	
		
	Spawn4:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx("HealthPack2",0,0,0,velx,vely,velz,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(40, "Spawn")
		TNT1 A 1
		Wait	
	
	Spawn5:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx ("Healthbonus",0,0,0,velx,vely,velz,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(100, "Spawn")
		TNT1 A 1
		Wait
	
	Spawn6:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx ("Bandages",0,0,0,velx,vely,velz,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_jump(100, "Spawn")
		TNT1 A 1
		Wait	
	

}}

I used the "velx,vely,velz" and managed to make the items inherit the spawner's velocity, but there's another problem now: if the player is not facing what the MAP "thinks" X and Y are, the items will actually spawn behind and in front of the player, rather than at its left and right. Is there some way to make the velocities point at the player?

[KeksDose]

If you can make the open crate face towards player, A_SpawnItemEx will do the rest for you. That depends on how the open crate is spawned. It might be as simple as A_FaceTarget before spawning the open crate (with A_SpawnItemEx).

[Grey-Wolf]

This is what the crate looks like right now:

---

Code: Select all

ACTOR OpenCrate
{
  +FloorClip
  Scale 0.5
  States
  {
  Spawn:
 	CHOP A 1 
	Goto see
  See:
    CHOP A 1 A_Facetarget
	CHOP A 5
	CHOP A 1 A_SpawnItemEx("Armorloot",0,0,0,2,-3,10,0)
	CHOP A 1 A_SpawnItemEx("Healloot",0,0,0,2,3,10,0)
	goto rest 
   Rest:
	CHOP A 1
	loop
  }
}

And this is one of the many spawner types: I added the absolutevelocity flag hoping that something would change.

---

actor ArmorLoot : CustomInventory
{
States
{

Spawn:
TNT1 A 0
TNT1 A 0 A_jump(255, "Spawn1", "Spawn2", "Spawn3", "Spawn4", "Spawn5", "Spawn6")
loop

Vanilla:
Spawn1:
TNT1 A 0
TNT1 A 1 A_SpawnItemEx("ArmorBoots",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION|SXF_ABSOLUTEVELOCITY)
TNT1 A 0 A_jump(40, "Spawn")
TNT1 A 1
Wait

Spawn2:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("ArmorHelmet",0,0,0,velx,vely,velz,0,SXF_NOCHECKPOSITION|SXF_ABSOLUTEVELOCITY)
TNT1 A 0 A_jump(40, "Spawn")
TNT1 A 1
Wait

But they still spawn toward a fixed direction.

EDIT: here's some screenshots of what happens: no matter the starting position of the player when he opens them (I tried approaching the crates from different directions), the items always spawns "to the left" of the map.

---

[KeksDose]

As I said, it might be as simple as A_FaceTarget before spawning the open crate. The open crate might have no target. That depends on how the closed crate spawns the open one, and how the closed crate is spawned, so a target may be transferred to begin with. Show the closed crate and how it is spawned.

The loot is not so interesting, cuz giving it velocity happens way earlier in the spawn chain. We need the player, which is information clearly used way earlier, cuz somehow, the closed crate has to spawn the open one. If it doesn't care about a specific player at all, we might have a bad problem.

For example, the approach can easily work if the closed crate is spawned by a dying monster. A_SpawnItemEx can then transfer the monster's target to the closed crate. Then A_FaceTarget before spawning the open crate will do the trick.

Don't use absolute velocity, either. It prevents using the crate's angle for velocity and then the same thing will keep happening.

[Grey-Wolf]

Ok, here's the closed crate and the key item:

---

Code: Select all

ACTOR ClosedCrate
{
  +FloorClip
  Scale 0.5
  States
  {
  Spawn:
    CHCL AA 10 A_look
	loop
	
  See:
	CHCL A 1
	CHCL A 1 A_JumpifCloser(40,"Needkey")
	CHCL A 1 A_JumpifCloser(100,"KeyCheck")
	loop
	
  Needkey:
	CHCL A 1 A_print("you need a key to open it",1)
	Goto See
  
  KeyCheck:
	CHCL A 0 
	CHCL A 1 A_JumpifintargetInventory("openpass",1,"Open")
	Goto See

  Open:
    CHOP A 1 
	CHOP A 1 A_print("you opened the chest!")
	CHOP A 1 A_takefromtarget("openpass",1)
	TNT1 A 0 A_SpawnItem("opencrate",0)
	Stop
  }
}



ACTOR Cratekey : CustomInventory
{
  Inventory.PickupSound "weapons/casing2"
  Inventory.PickupMessage "Picked up a small key"
  Inventory.Icon KEYCB0
  +Inventory.Invbar
  +FloorClip
  Inventory.Amount 1
  Inventory.MaxAmount 5
  Inventory.Interhubamount 1
  Scale 0.2
  States
  {
  Spawn:
    KEYC A -1
  Use:
	TNT1 A 0
	TNT1 A 0 A_CheckProximity("Openpass","closedcrate",100,1,CPXF_CHECKSIGHT)
	TNT1 A 0 A_print("See anything with a lock on it somewhere?")
	Goto giveitback
  Giveitback:
	TNT1 A 0
	TNT1 A 0 A_GiveInventory("cratekey",1)
	Stop
  Openpass:
	TNT1 A 0
	TNT1 A 0 A_GiveInventory("openpass",1)
	Stop
  }
}

[KeksDose]

Fantastic! You're even using the target already. This here should already do the trick:

Code: Select all

// Spawn the open crate like this:
TNT1 A 0 A_FaceTarget
TNT1 A 0 A_SpawnItem("OpenCrate", 0) 

A_SpawnItem will transfer the closed crate's direction, and A_SpawnItemEx will use this for the velocity if you didn't set SXF_ABSOLUTEVELOCITY.

edit: had a ; where it doesn't belong huhu

[Grey-Wolf]

You... you life-saving bastard...

https://i.imgur.com/njobuYV.gif

Well, thanks A LOT. I don't think there's anything else to say.