GetDefaultByType with custom properties?

[Matt]

Let's say I want to make an inventory class from which several other classes inherit that has a custom string and property, "NiceName" that will show up in place of the real actor name when certain scripts are executed, e.g., it'll say "Fresh Baked Chocolate Chip Cookies" instead of "CookieCChipSpawnD0" or at best "FreshBakedChocolateChipCookies" with no spaces.

I've got one script that needs to get the default NiceNames of these classes, without referring to any particular instance of any of them.

Here is what I have tried:

Code: Select all

// Expected output: type "summon nna" in console, get "nice name" when it appears
// Actual: fail to compile: "Unknown identifier 'nicename'"
class nicenameactor:inventory
{
    string nicename;
    property nicename:nicename;
    default
    {
        nicenameactor.nicename "nice name";
    }
}
class nna:actor
{
    states
    {
    spawn:
        TNT1 A 1 nodelay
        {
            for(int i=0;i<allactorclasses.size();i++)
            {
                if(allactorclasses[i] is "nicenameactor")
                {
                    string nn=getdefaultbytype(allactorclasses[i]).nicename;
                    A_Log(nn);
                }
            }
        }
        stop;
    }
}
 

If I specifically write in "nicenameactor" in the getdefaultbytype, it works fine, but obviously that means I won't be able to check for any descendants which is the whole point of this script.

Is there any other way to get the default class properties where the class is reference by a variable?

[gramps]

It looks like strings are automatically converted to class type references for functions that want class type references, but not the other way around. I think AllActorClasses[n] is getting you a type reference, but GetDefaultByType actually wants a class name in the form of a string.

Might be missing something, but it looks like GetDefaultByType really ought to take a type reference instead, if a string would get converted anyway. As it is, it's not really clear to me how to do what you want, but I'm not too familiar with the API yet.

[Graf Zahl]

The problem here is actually very simple:

GetDefaultByType("nicemnameactor") can do an implicit type conversion and give you the proper type, but when you pass in a class type variable you get a basic class<Object> as return because the compiler does not know about the queried object's type at compile time. And this base type simply does not know about the extended properties of subclasses.

You have to cast the returned default into the proper type yourself.

[Matt]

Thanks, good to know I was at least in the right direction and it was just a matter of which syntax to use.

"nicenameactor(getdefaultbytype(allactorclasses))" gave me "Cannot cast a readonly pointer" while "getdefaultbytype(nicenameactor(allactorclasses))" gave me "Cannot convert ClassPointer<Actor> to Pointer<Class<Object>>".

Turns out the correct version is

Code: Select all

string nn=getdefaultbytype((class<nicenameactor>)(allactorclasses[i])).nicename; 

(not sure if the outermost parentheses are necessary though) (they are)