Weapon-Specific Hud elements

[LolaHThicc]

I'm working on a custom hud and it's beeing going fairly well, but once again i'm reaching a wall to my knowledge.

I would like for when a specific weapon is selected for a hud element showing an integer value used by the weapon to appear, and I would like for it to only appear while the weapon is selected.
I have a vuage idea of what i might need to do, maybe an if statement using CPlayer.ReadyWeapon, but i'm not sure. Any input as always is greatly appriciated!

[Average Raven Fan]

Let's give this a go. I've copy-pasted the whole Doom status bar to a new class and added these two bits to it!

Code: Select all

		if(CPlayer.ReadyWeapon is "Shotgun")
		{
			DrawString(mAmountFont, FormatNumber(CPlayer.mo.CountInv("Cell")), (44, 181), DI_TEXT_ALIGN_RIGHT, Font.CR_LIGHTBLUE);
		}

This is added to DrawMainBar, right after drawing the current weapon's ammo...

Code: Select all

		if(CPlayer.ReadyWeapon is "Shotgun")
		{
			DrawString(mHUDFont, FormatNumber(CPlayer.mo.CountInv("Cell")), (-30, -40), DI_TEXT_ALIGN_RIGHT, Font.CR_LIGHTBLUE);
		}

And this one is added to DrawFullScreenStuff, also right after the ammo display code!

This shows the amount of cells you have in light blue whenever you have the single shotgun selected in Doom. Give it a spin and see if that's what you wanted!

[LolaHThicc]

Yes, it does exactly that, Thank you!

Now, i have an integer stored in the weapon; whats the procedure to passing that number along to the hud?

[Average Raven Fan]

Code: Select all

class RNGShotgun : Shotgun
{
	int num;
	
	override void Tick()
	{
		num = random(0,255);
		Super.Tick();
	}
}

This is a shotgun with a variable. Just showing this so the code afterwards makes some sense!

Code: Select all

		if(CPlayer.ReadyWeapon is "RNGShotgun")
		{
			RNGShotgun weap = RNGShotgun(CPlayer.ReadyWeapon);
			DrawString(mHUDFont, FormatNumber(weap.num), (-30, -40), DI_TEXT_ALIGN_RIGHT, Font.CR_LIGHTBLUE);
		}

This is added to DrawFullScreenStuff just like the last example but it shows the value of the "num" variable in the RNGShotgun weapon instead of your current energy cells!

[LolaHThicc]

works perfectly! thanks again for the help!