Can monster melee attacks poison the player?

[Heisanevilgenius]

I'm specifically looking for a way to use A_CustomComboAttack to poison a player, but only with melee. The projectile would not poison them. Since melee monster attacks don't use puffs, I'm not sure how to implement it.

[Player701]

If you can use ZScript, it is not that difficult a task to code a function that does exactly what you want:

Code: Select all

void A_CustomPoisonComboAttack(class<Actor> projType, int meleeDamage, sound meleeSound)
{
    if (Target != null && CheckMeleeRange())
    {
        A_StartSound(meleeSound, CHAN_WEAPON);
        int newdam = Target.DamageMobj(self, self, meleeDamage, 'Melee');
        Target.TraceBleed(newdam > 0 ? newdam : damage, self);
        Target.PoisonMobj(self, self, PoisonDamage, PoisonDuration, PoisonPeriod, PoisonDamageType);
    }
    else
    {
        A_SpawnProjectile(projType);
    }
}

In melee, this attack will play the meleeSound sound, do meleeDamage damage to the target, and also poison them according to the calling actor's poison damage properites. Otherwise, if the target is not in melee range, it will fire a projectile of type projType. If you want the melee attack to only do poison damage and not regular damage, simply remove the calls to DamageMobj and TraceBleed (you may then also remove the meleeDamage argument as it won't be needed for anything anymore).

Usage example:

Code: Select all

class TestImp : DoomImp replaces DoomImp
{
    Default
    {
        PoisonDamage 2;
    }

    States
    {
        Melee:
        Missile:
            TROO EF 8 A_FaceTarget;
            TROO G 6 A_CustomPoisonComboAttack('DoomImpBall', random(1, 8) * 3, "imp/melee");
            Goto See;
    }

    void A_CustomPoisonComboAttack(class<Actor> projType, int meleeDamage, sound meleeSound)
    {
        if (Target != null && CheckMeleeRange())
        {
            A_StartSound(MeleeSound, CHAN_WEAPON);
            int newdam = Target.DamageMobj(self, self, meleeDamage, 'Melee');
            Target.TraceBleed(newdam > 0 ? newdam : damage, self);
            Target.PoisonMobj(self, self, PoisonDamage, PoisonDuration, PoisonPeriod, PoisonDamageType);
        }
        else
        {
            A_SpawnProjectile(projType);
        }
    }
}

[Heisanevilgenius]

Fantastic, thank you!

[Heisanevilgenius]

So, a weird side effect is that these monsters now infight when they hit each other with their projectiles... I'm not sure why that is. I'm not even sure they do damage to each other. They just keep attacking each other in a big endless brawl.

[Player701]

So, a weird side effect is that these monsters now infight when they hit each other with their projectiles...

I'm unable to reproduce this with my example code. It must be caused by something else in your code.

[Heisanevilgenius]

How strange. Okay, thank you.

[Heisanevilgenius]

Yeah, you're right. The problem is not the custom attack. It must be something weird with the projectile. I'll have to look into it further. Thanks again.