[SOLVED - ZS] Menus - Getting the Currently Selected Option

[Sarah]

So I modified m8f's Tips for Menus mod to work with Option Menus. Currently it works exactly the same, it picks from a random string and prints it at the bottom right of the screen when the menu is opened.

What I'd like it to do is show a different string depending on what option in the parent menu is highlighted. Is there a way to get an index number of the currently highlighted option, or something along those lines?

---

Code: Select all

OptionMenu "PAOptions"
{
	Title		"Project Absolam Options"
	StaticText	"Camera Pitch", "White"
	Option		"Auto Pitch",		"pavar_AutoPitch", "OnOff"
	Slider		"Camera Pitch",		"pavar_CamPitch", -90, 90, 0.25, 2
	Slider		"Pitch Speed",		"pavar_CamPitchSpeed", 0.05, 1.0, 0.05, 2
	Slider		"Camera Origin Radius X/Y",	"pavar_CamOriginX", 64.0, 128.0, 8.0, 0
	Slider		"Camera Origin Raidus Z",	"pavar_CamOriginZ", 64.0, 128.0, 8.0, 0
	StaticText	""
	StaticText	"Camera Controls", "White"
	Slider		"Current Pitch Interval",	"pavar_CamPitchLocation", 1, 20, 1, 0
	Control		"Move Pitch Up",		"t_ptchup"
	Control		"Move Pitch Down",		"t_ptchdwn"
	StaticText  ""
	StaticText	"Misc. Settings", "White"
	Option		"Camera Connection",	"pavar_CamConnect", "OnOff"
	Control		"Camera Connection Bind", "t_camcon"
	StaticText	"Camera Connection - if turned off the camera position system will be disabled.", "DarkGray"
	Option		"First-Person Toggle",	"pavar_FrstCam", "OnOff"
	Control		"First-Person Bind", "t_frstcam"
	StaticText	"First-Person Toggle - if turned on the system switches back to the player's view.", "DarkGray"
	Option		"Debug Output",	"pavar_CamDebug", "OnOff"
}

AddOptionMenu "OptionsMenu"
{
	StaticText	""
	Submenu		"Project Absolam Options", "PAOptions"
}

OptionMenu PA_MenuInjector
{
	PA_MenuInjector
}

---

Code: Select all

class PA_OptionMenuNote : OptionMenuItem
{
	const MARGIN = 10;

	/// Must contain at least 1 string.
	private ui Array<String> _strings;
	private ui uint          _iString;
	
	PA_OptionMenuNote init()
	{
		add("Toggling the Auto Pitch control will enable the camera\nto automatically look where the player looks.");
		Super.Init("PA Camera Tips:", "none");
		return self;
	}
	
	override bool, string GetString(int i)
	{
		return true, "OptionMenuNote";
	}
	
	override void OnMenuCreated()
	{
		_iString = random(0, _strings.size() - 1);
	}
	
        // Had to switch to Draw instead of Drawer
	override int Draw(OptionMenuDescriptor desc, int y, int indent, bool selected)
	{
		if (!pavar_show_notes)
			return Super.Draw(desc, y, indent, selected);
		
		int width = (Screen.GetWidth() / CleanXFac_1) * 3 / 4;
		let lines = NewSmallFont.BreakLines(_strings[_iString], width);
		int nLines = lines.Count();
		double height = NewSmallFont.GetHeight();
		double y = Screen.GetHeight() - MARGIN - height * nLines * CleanYFac_1;

		for (int i = 0; i < nLines; ++i)
		{
			double x = Screen.GetWidth() - MARGIN - lines.StringWidth(i) * CleanXFac_1;
			Screen.DrawText( NewSmallFont, Font.CR_WHITE, x, y, lines.StringAt(i), DTA_CleanNoMove_1, true);
			y += height * CleanYFac_1;
		}
		return Super.Draw(desc, y, indent, selected);
	}
	
	private ui void add(String s)
	{
		_strings.push(s);
	}
}

class OptionMenuItemPA_MenuInjector : OptionMenuItem
{
	void Init()
	{
		injectNote("PAOptions");
	}
	
	void injectNote(String menuName)
	{
		let descriptor = OptionMenuDescriptor(OptionMenuDescriptor.GetDescriptor(menuName));
		if (descriptor)
		{
			bool hasString;
			string whatString;
			[hasString, whatString] = descriptor.mItems[descriptor.mItems.size() - 1].GetString(0);
			
			if (hasString && whatString == "OptionMenuNote")
				return;
			else
				descriptor.mItems.Push(new("PA_OptionMenuNote").init());
		}
		else
			Console.Printf("MENU TIPS - PA MENU TIP FAILURE TO FIND DESCRIPTOR -");
	}
}

Lastly @m8f, I will clean up the current ZScript and incorporate it back into your mod and send it to you if you want - might be able to set up some other options too - let me know what you want me to do.

Update
Very much solved. Thank you AFADoomer for the quick response, that was exactly what I needed.

Also I'd like to make the fruits of my labor available. They, yes they for they are two, come in two flavors, Tips with Options, and Tooltips. What's the difference? Tips with Options is m8f's Tips for Menus mod with the addition of a class for Option Menus. Works exactly the same as m8f's original code, for a demo just open up the Options Menu.

Tooltips is what I was trying to accomplish here. I want text to appear in the lower right hand corner of the screen with information on the current thing I have selected in a menu. Tooltips is about 95% m8f's code, 1% mine, and 4% further head trauma as I banged my head on the keyboard getting it to work. So it's my gift to m8f and the community and you can find more info about both of these mods to the mod over at the mod thread, which I will be making a post at shortly to give info and links.

Please let me know if you have any problems downloading the files from my Google Drive - I probably borked the share settings.

[AFADoomer]

OptionMenuDescriptor has a mSelectedItem variable that you should be able to use.