[ZScript]Line3d - for debugging and more

[Sir Robin]

This is something I started as a debug tool but then had some fun with it and thought I'd share it here.

I was debugging some movement code, things weren't going where I thought they should. I wished I had a way to mark points in space so I could see if my vector locations were correct. Then I wished I could draw a line from one vector to another. So I wrote a class to do that, super easy:
Line3d.SpawnTo((x1, y1, z1),(x2, y2, z2));
I didn't want to have to track and deleted the lines, so I gave them a self-destruct feature, specified in tics:
Line3d.SpawnTo((x1, y1, z1), (x2, y2, z2), 175);
And sometimes I wanted an animation to show me the flow from one end to the other, animation specified in tics:
Line3d.SpawnTo((x1, y1, z1), (x2, y2, z2), 175, 20);

But then things got a little crazy. Imagine this: You're a huge Doom nerd (duh!) and you're on your way to the birthday party of your favorite Doom demon when you realize that you were supposed to bring the decorations but you totally space-marined out. What are you going to do? No problem, I got you covered:
Give yourself a LineDrawer, select it in inventory, then go use it on a wall. Then use it on another wall, or a floor, or a ceiling, or an actor. Or even in the open air. What ever, it's a party! Go nuts!

Imagine this: The party is banging and you're feeling a bit crazy. What are you going to do? I got you covered there, too.
Give yourself LinesComingOutMyButt and go frolic. It's a party! Enjoy!

download it here

Or see the code here:

---

ZSCRIPT

Code: Select all

//Code by Mike Ratzlaff, AKA Sir Robin on ZDoom forums. Use this however you want but please credit me. Thanks!

version "4.10"

// ---------- Line3d Stuff ----------

class Marker3d : actor
{
	default
	{
		height 7;
		radius 7;
		+RollSprite
		+NoGravity
		+NoBlockmap
		+NoInteraction
		+FORCEXYBILLBOARD
	}
	states
	{
		spawn:
			MARK Y -1 bright;
			stop;
	}
	override void BeginPlay()
	{
		roll=45;
	}
}

class Line3d : actor
{
	int TimeToLive,TimeToCycle;
	vector3 startVector,deltaVector;
	actor marker;
	
	default
	{
		height 1;
		radius 1;
		+NoGravity
		+NoBlockmap
		+NoInteraction
	}
	states
	{
		spawn:
			PIXL M -1 bright;
			stop;
	}
	
	override void tick()
	{
		super.tick();
		if (TimeToLive > 0)
		{
			if (TimeToLive < 15)
			{
				A_SetRenderStyle(TimeToLive/15.,STYLE_Translucent);
				if (marker) marker.A_SetRenderStyle(TimeToLive/15.,STYLE_Translucent);
			}
			TimeToLive--;
			if (TimeToLive == 0) Destroy();
		}
		if (TimeToCycle > 1 && marker)
		{
			marker.SetOrigin(startVector + deltaVector * (level.time % TimeToCycle) / (TimeToCycle - 1), false);
		}
	}
	override void OnDestroy()
	{
		if (marker) marker.Destroy();
		super.OnDestroy();
	}
	
	void SetEndPoints(vector3 StartPos, vector3 EndPos, int TimeToLive = -1, int TimeToCycle = 0)
	{
		startVector = StartPos;
		deltaVector = EndPos - StartPos;
		vector3 midOff = deltaVector / 2;
		SetOrigin(StartPos + midOff, false);
		scale.y = deltaVector.length();
		scale.x = 0.25;
		pitch = -90 - VectorAngle(deltaVector.xy.length(),deltaVector.z);
		angle = VectorAngle(deltaVector.x, deltaVector.y);
		self.TimeToLive=TimeToLive;
		self.TimeToCycle=TimeToCycle;
		if (TimeToCycle > 1)
		{
			if (marker)
				marker.SetOrigin(StartPos,false);
			else
				marker=spawn("marker3d",StartPos);
		}
		else
		{
			if (marker) marker.destroy();
		}
		A_SetSize(max(abs(deltaVector.x),abs(deltaVector.y)) / 2, abs(deltaVector.z) / 2);
	}
	
	static Line3d SpawnTo(vector3 StartPos, vector3 EndPos, int TimeToLive = -1, int TimeToCycle = 0)
	{
		Line3d l3d = Line3d(actor.spawn("Line3d",StartPos));
		if (l3d) l3d.SetEndPoints(StartPos,EndPos,TimeToLive, TimeToCycle);
		return l3d;
	}
}

// ---------- Happy Fun Party Stuff ----------

//A place to park some math functions
//Developed by Mike Ratzlaff (AKA Sir Robin on Zdoom forums) with a tremendous amount of help From Player701
Struct LineTraceCalc
{
	static double, double, double GetHitAnglePitchRoll(FLineTraceData t){
		double ang, pt, roll;

		switch (t.HitType)
		{		
			case TRACE_HitFloor:
			case TRACE_HitCeiling:
				[ang, pt, roll] = GetHitAnglePitchRollFromPlane(t);
				break;
			case TRACE_HitWall:
				[ang, pt, roll] = GetHitAnglePitchRollFromLine(t);
				break;
			default:
				return 180+VectorAngle(t.HitDir.x,t.HitDir.y), 270+VectorAngle(t.HitDir.xy.length(),t.HitDir.z), 0;
		}

		return ang, pt, roll;
	}

	static double, double, double GetHitAnglePitchRollFromPlane(FLineTraceData t){
		bool is3dfloor = t.Hit3DFloor != null;
		SecPlane p;

		if (is3dfloor)
		{
			p = t.HitType == TRACE_HitFloor ? t.Hit3DFloor.top : t.Hit3DFloor.bottom;
		}
		else if (t.HitType == TRACE_HitFloor)
		{
			p = t.HitSector.floorplane;
		}
		else // if (t.HitType == TRACE_HitCeiling)
		{
			p = t.HitSector.ceilingplane;
		}

		let n = p.Normal;
		if (is3dfloor){n=-1*n;}
		
		double ang = 0, pt = -asin(n.Z);

		if (n.XY.Length() > 0)
		{
			ang = atan2(n.Y, n.X);
		}

		double roll = VectorAngle(t.HitDir.x,t.HitDir.y) + 180 - ang;
		return ang, pt - 90, pt > 0 ? roll : -roll;
	}

	static double, double, double GetHitAnglePitchRollFromLine(FLineTraceData t)
	{
		let delta = t.HitLine.delta;
		double ang = atan2(delta.Y, delta.X);
		return ang + (t.LineSide == Line.front ? -90 : 90), -90, 0;
	}
}

class Marker3d_M : Marker3d //Marker Magenta
{
	states
	{
		spawn:
			MARK M -1 bright;
			stop;
	}
}

//Put this in inventory and then use it on floors, walls, ceilings, actors, or even open space
//To stop the flow, drop it and pick it up again
class LineDrawer : Inventory
{
	vector3 lastPos, nextPos;
	line3d ActiveLine;
	FLineTraceData curFltd;
	
	default
	{
		+Inventory.InvBar;
	}
	states
	{
		spawn:
			UNKN A -1;
			stop;
	}
	override void tick()
	{
		super.tick();
		if(!owner || !owner.player || !owner.player.mo)
		{
			if (ActiveLine) ActiveLine.destroy();
			return;
		}

		Owner.LineTrace(
			owner.angle,
			owner.player.mo.userange,
			owner.pitch,
			TRF_SolidActors,
			owner.player.viewheight,
			data: curFltd
		);
		nextPos = curFltd.HitLocation;

		if (ActiveLine) ActiveLine.SetEndPoints(lastPos,nextPos,-1,20);
	}
	override bool use(bool pickup)
	{
		if(!owner || !owner.player || !owner.player.mo) return false;
		
		lastPos=nextPos;
		ActiveLine=line3d.SpawnTo(lastPos,NextPos);
		
		if (curFltd.HitType == TRACE_HitFloor || curFltd.HitType == TRACE_HitWall || curFltd.HitType == TRACE_HitCeiling)
		{
			actor marker = spawn("Marker3d_M",curFltd.HitLocation);
			double y,p,r;
			[y,p,r] = LineTraceCalc.GetHitAnglePitchRoll(curFltd);
			marker.bFlatSprite = true;
			marker.angle = y;
			marker.pitch = p;
			marker.roll = random(0,359);
		}
		
		return false;
	}
	override bool PreTeleport( Vector3 destpos, double destangle, int flags )
	{
		if (ActiveLine) ActiveLine.Destroy();
		return super.PreTeleport(destpos, destangle, flags);
	}
	override void PreTravelled()
	{
		if (ActiveLine) ActiveLine.Destroy();
		super.PreTravelled();
	}
	override void OnDestroy()
	{
		if (ActiveLine) ActiveLine.Destroy();
		super.OnDestroy();
	}
}

//Put this inventory and go frolic, drop it to stop the madness
class LinesComingOutMyButt : Inventory
{
	vector3 lastPos, nextPos;
	line3d ActiveLine;
	const TimeToCycle = 5;
	const TimeToLive = 350;
	
	default
	{
		+Inventory.InvBar;
	}
	states
	{
		spawn:
			UNKN A -1;
			stop;
	}
	override void tick()
	{
		super.tick();
		if(!owner || !owner.player || !owner.player.mo)
		{
			if (ActiveLine) ActiveLine.destroy();
			return;
		}
		
		nextPos = owner.pos + (RotateVector((16,0),owner.angle+180),owner.player.viewheight / 2);

		if (ActiveLine)
		{
			ActiveLine.SetEndPoints(lastPos,nextPos,TimeToLive);
		}
		else
		{
			lastPos=nextPos;
			ActiveLine=line3d.SpawnTo(lastPos,nextPos,TimeToLive);
		}
		if (level.time % TimeToCycle == 0 && lastPos != nextPos)
		{
			ActiveLine.SetEndPoints(lastPos,nextPos,TimeToLive,TimeToCycle);
			lastPos=nextPos;
			ActiveLine=line3d.SpawnTo(lastPos,nextPos,TimeToLive);
		}
	}
	override bool PreTeleport( Vector3 destpos, double destangle, int flags )
	{
		console.printf(level.time..": "..GetCharacterName()..": PreTeleport");
		if (ActiveLine) ActiveLine=null;
		return super.PreTeleport(destpos, destangle, flags);
	}
	override void OnDestroy()
	{
		if (ActiveLine) ActiveLine.Destroy();
		super.OnDestroy();
	}
}

TEXTURES

Code: Select all

//Code by Mike Ratzlaff, AKA Sir Robin on ZDoom forums. Use this however you want but please credit me. Thanks!

// ---------- Line3d Stuff ----------

sprite MARKY0, 14, 14 //Marker Yellow (baseline)
{
	offset 7,7
	patch selectbo, 7, 7
	patch selectbo, -23, -23
}
sprite PIXLM0, 1, 1 //pixel: magenta
{
	offset 1,1
	patch selectbo, 0, 0 {translation "0:255=251:251"} //patch can be anything, just using it to draw a pixel
}

// ---------- Happy Fun Party Stuff ----------

sprite MARKM0, 14, 14 //Marker Magenta
{
	offset 7,7
	patch MARKY0, 0, 0 {translation "160:167=251:254"}
}

MODELDEF

Code: Select all

Model Line3d
{
	Model 0 "unitcube.obj"
	Scale 1.0 1.0 1.2 // for Doom ratio
	UseActorPitch
	Skin 0 "PIXLM0"
	FrameIndex PIXL M 0 0
}

UnitCube.obj

Code: Select all

o UnitCube
v 0.500000 0.500000 -0.500000
v 0.500000 -0.500000 -0.500000
v 0.500000 0.500000 0.500000
v 0.500000 -0.500000 0.500000
v -0.500000 0.500000 -0.500000
v -0.500000 -0.500000 -0.500000
v -0.500000 0.500000 0.500000
v -0.500000 -0.500000 0.500000
vn -0.0000 1.0000 -0.0000
vn -0.0000 -0.0000 1.0000
vn -1.0000 -0.0000 -0.0000
vn -0.0000 -1.0000 -0.0000
vn 1.0000 -0.0000 -0.0000
vn -0.0000 -0.0000 -1.0000
vt 1.000000 0.000000
vt 1.000000 1.000000
vt 0.000000 1.000000
vt 0.000000 0.000000
s 0
usemtl UNKNA0
f 1/1/1 5/2/1 7/3/1 3/4/1
f 4/1/2 3/2/2 7/3/2 8/4/2
f 8/1/3 7/2/3 5/3/3 6/4/3
f 6/1/4 2/2/4 4/3/4 8/4/4
f 2/1/5 1/2/5 3/3/5 4/4/5
f 6/1/6 5/2/6 1/3/6 2/4/6

[Nash]

Line trace debugging has always been annoying without any visual aid. Thank you for this.

[Sir Robin]

Line trace debugging has always been annoying without any visual aid. Thank you for this.

You're welcome! I hope it's useful.

Yes I was absolutely using it to debug my use3d line tracing:

The purple line is the linetrace, the red marks are the hitbox hits, and I made the switch box transparent so I could see better whats happening from all sides.

I designed and tested these lines with pretty small lengths in mind. If you're doing full linetraces (like 2048 length) you'll need to bump up the render radius so that they get drawn.
I've never mesed with that before, looks like renderradius is readonly and there's no setter function for it so it's hardcoded after the defaults.
But according to the wiki, if radius is bigger than renderradius then that's used instead.
So add this to line3d.setEndPoints:
A_SetSize(max(abs(deltaVector.x),abs(deltaVector.y)) / 2, abs(deltaVector.z) / 2);
obvioulsy, after deltaVector has been set.
I'll edit the code in the first post. I'm also adding a fader to the animation when the line self-destructs.

[Sir Robin]

Line trace debugging has always been annoying without any visual aid. Thank you for this.

I just dropped a new package with the function line3d.LineTraceVisual(), it wraps actor.linetrace() and adds the visualization. Doesn't work through portals though.
And here's a sample object to test it with:

Code: Select all

class LineTraceDebug : inventory //linetrace debugger
{
	default
	{
		+Inventory.InvBar;
	}
	states
	{
		spawn:
			UNKN A -1;
			stop;
	}
	override bool use(bool pickup)
	{
		if (!owner || !owner.player || !owner.player.mo) return false;
		FLineTraceData fltd;
		line3d.LineTraceVisual
		(
			owner, //source actor
			 //----------the usual line trace data here ...
			owner.angle,
			2048,
			owner.pitch,
			0,
			owner.height * 0.5 - owner.floorclip + owner.player.mo.AttackZOffset*owner.player.crouchFactor,
			0,
			0,
			fltd,
			//----------end of the usual line trace data
			"line3d",//which line3d subclass to use for the visual
			175, //time to live in tics
			0, //animation cycle in tics
			"Marker3d" //marker to use at the far end
		);
		switch (fltd.HitType)
		{
			case TRACE_HitNone: console.printf("Hit nothing"); break;
			case TRACE_HitFloor: console.printf("Hit floor "..fltd.HitTexture); break;
			case TRACE_HitWall: console.printf("Hit wall "..fltd.HitTexture); break;
			case TRACE_HitCeiling: console.printf("Hit ceiling "..fltd.HitTexture); break;
			case TRACE_HitActor: console.printf("Hit actor "..fltd.HitActor.GetCharacterName()); break;
		}
		return false;
	}
}

[Sir Robin]

Update:
Previously I had line3d.LineTraceVisual() that you could call in place of actor.linetrace(). It was a wrapper that would call the linetrace and then do the visualization. But what if you want to do the linetrace and then conditionally decide if you want it visualized? There is now line3d.VisualizeLinetrace() that takes an FLineTrace data structure and visualizes it. So for example your weapon or tool code could look like this:

Code: Select all

FLineTraceData fltd;
bool HitSomething = owner.LineTrace(owner.angle,range,owner.pitch,flags,offz,offx,offy,fltd);
//am I interested in visualizing this line? If so, for example:
if (debugmode) line3d.VisualizeLineTrace(fltd, TimeToLive: 35);

And line3d.LineTraceVisual() still functions as before, this method just gives you more control

And meanwhile I'm just over here bouncing line visualizers all over the place: