How to make a "switch weapon if you have item" function

[Clown_Number_42]

I was wondering about how i could make a "When you have a certain inventory item, lower weapon and switch to a specific weapon immediately, switching back to the previous weapon when you lose the inventory item." function? Another question i had is if i could have a run-down on how to animate two-handed/dual wielding sprites with overlays?

[yum13241]

Sister weapons?

[Clown_Number_42]

Sister weapons?

I was thinking something similar to Sister weapons, but it doesn't change any of the default weapons and the player can only equip it by pressing custom keybind.

[Jarewill]

You should specify what exactly do you want.
From what I understand, you want a powerup of sorts?
Here's a ZScript example I quickly whipped together:

---

Code: Select all

Class SuperWeaponPowerup : Powerup{
	//Store the previous weapon
	Weapon prevweap;
	
	Default{
		Powerup.Duration -5;
	}
	
	//When the effect starts
	Override void InitEffect(){
		If(owner.player){
			//Save the current player weapon before changing
			prevweap = owner.player.readyweapon;
			//Give the super weapon to the player
			owner.A_GiveInventory("SuperWeapon",1);
			//Select the super weapon
			owner.A_SelectWeapon("SuperWeapon");
		}
		Super.InitEffect();
	}
	
	//When the effect ends
	Override void EndEffect(){
		If(owner.player){
			//Select the previous player weapon
			owner.A_SelectWeapon(prevweap.GetClassName());
			//Take away the super weapon
			owner.A_TakeInventory("SuperWeapon",1);
		}
		Super.EndEffect();
	}
}

You should set the WRF_NOSWITCH for your weapon's A_WeaponReady function to make sure the player won't just switch back manually.

[Clown_Number_42]

You should specify what exactly do you want.
From what I understand, you want a powerup of sorts?
Here's a ZScript example I quickly whipped together:

---

Code: Select all

Class SuperWeaponPowerup : Powerup{
	//Store the previous weapon
	Weapon prevweap;
	
	Default{
		Powerup.Duration -5;
	}
	
	//When the effect starts
	Override void InitEffect(){
		If(owner.player){
			//Save the current player weapon before changing
			prevweap = owner.player.readyweapon;
			//Give the super weapon to the player
			owner.A_GiveInventory("SuperWeapon",1);
			//Select the super weapon
			owner.A_SelectWeapon("SuperWeapon");
		}
		Super.InitEffect();
	}
	
	//When the effect ends
	Override void EndEffect(){
		If(owner.player){
			//Select the previous player weapon
			owner.A_SelectWeapon(prevweap.GetClassName());
			//Take away the super weapon
			owner.A_TakeInventory("SuperWeapon",1);
		}
		Super.EndEffect();
	}
}

You should set the WRF_NOSWITCH for your weapon's A_WeaponReady function to make sure the player won't just switch back manually.

What i had in mind was something like "press a custom keybind (like f) to give yourself a custom weapon and switch to it, press the button again to switch away from it and delete it from your inventory." like the M_Gizmos "Holster" function, but i think i can make-do with this.

[Dan_The_Noob]

seems like you just want to give a player a weapon but have it auto-equip regardless of "switch on pickup"?

[Jarewill]

What i had in mind was something like "press a custom keybind (like f) to give yourself a custom weapon and switch to it, press the button again to switch away from it and delete it from your inventory." like the M_Gizmos "Holster" function, but i think i can make-do with this.

In this case the previously provided code can be adapted into what you want by combining both Init- and EndEffect overrides into a single Use override.
Use gets triggered whenever an inventory item is used, so with that it's possible to check for special logic inside the inventory item and do specific things, kind of like using CustomInventory items in DECORATE.
For example:

---

Code: Select all

Class SuperWeaponItem : Inventory{
	Weapon prevweap;
	//Combining both previous overrides into a single one
	Override bool Use(bool pickup){
		If(owner.player){
			//Checking if the current weapon is the SuperWeapon to see if we should switch to it or from it
			If(owner.player.readyweapon.GetClassName() == "SuperWeapon"){
				owner.A_SelectWeapon(prevweap.GetClassName());
				owner.A_TakeInventory("SuperWeapon",1);
			}Else{
				prevweap = owner.player.readyweapon;
				owner.A_GiveInventory("SuperWeapon",1);
				owner.A_SelectWeapon("SuperWeapon");
			}
		}
		Return Super.Use(pickup);
	}
}

Then this item can be triggered by making a keybind like this:
use SuperWeaponItem

Also if you want it to be for a mod that doesn't alter the player class, you should set up an event handler, like this:

Code: Select all

//ZScript code
Class SuperWeaponHandler : EventHandler{
	Override void WorldThingSpawned(WorldEvent e){
		If(e.Thing.player){
			e.Thing.A_GiveInventory("SuperWeaponItem",1);
		}
	}
}

//MapInfo code
GameInfo{
	AddEventHandlers = "SuperWeaponHandler"
}