Halve state durations of some monsters

[Kzer-Za]

I want to have some monsters, but not all of them, have all their state durations halved. Is there a way of achieving it without creating replacements for these monsters with all their states and specifying new state durations? I have tried giving them an item when they are spawned that would halve their tics variable, but it seems to be read-only:

Code: Select all

class Hastener : Inventory
{
	Default
	{
		Inventory.Amount 1;
		Inventory.MaxAmount 1;
	}
	override void Tick()
	{
		let myowner = owner;
		State PrevState = myowner.curState;
		if (myowner.curState != PrevState);
		{
			myowner.curState.tics = (myowner.curState.tics + 1)/2;
			Console.Printf("dur: "..myowner.curState.tics);
		}
		super.Tick();
	}
}

I get "Expression must be a modifiable value". Is there another way of achieving it?

[Player701]

Try myowner.tics. curState probably refers directly to state table data which is not supposed to be modified, since it's used by every instance of each actor class.

[Kzer-Za]

Thanks a lot! That's it!

In case anyone needs something similar, here's the code I eventually came up with. The changes to the initial version, apart from the key change advised by Player701, are: assignment of the current state to "PrevState" of course had to be moved to after the condition; and typecasting was unnecessary, it works without it. Also I added a condition to exclude Death and Pain states, so that their animation has the unchanged speed.

Code: Select all

class Hastener : Inventory
{
	Default
	{
		Inventory.Amount 1;
		Inventory.MaxAmount 1;
	}
	
	State PrevState;
	
	override void Tick()
	{
		if (owner.CurState != PrevState)
		{
			if (owner.InStateSequence(owner.CurState, owner.ResolveState("Death")) == false && owner.InStateSequence(owner.CurState, owner.ResolveState("Pain")) == false)
				owner.tics = (owner.tics + 1)/2;
		}
		PrevState = owner.CurState;
		super.Tick();
	}
}