My babies wont cry.

[Hidden Hands]

I have babies as NPCs in my game. Originally, they were mute but then I deceided to give them a crying "active" sound but the sound doesn't play. I have scripted it the same way I script my monsters sounds, what am I doing wrong here please? Here is the code.

Code: Select all

ACTOR PinkBaby 19998
{
//$Category NPCs
  Radius 25
  Height 9
  Speed 3
  SeeSound "baby/active"
  ActiveSound "baby/active"
  States
  {
  Spawn:
    PBAB AABBCCBB 4 A_Wander
    Loop
 }
}

ACTOR BlueBaby 19997
{
//$Category NPCs
  Radius 25
  Height 9
  Speed 3
  SeeSound "baby/active"
  ActiveSound "baby/active"
  States
  {
  Spawn:
    BBAB AABBCCBB 4 A_Wander
    Loop
 }
}

and here is the SNDINFO.

Code: Select all

baby/active CRYBABY

Any and all help is greatly appreciated!
Thanks in advance.

[Matt]

Does A_Wander even call the active sound?

[Endie]

Try this~

Code: Select all

   BBAB AABB 4 A_Wander
    BBAB CCDD 4 A_Look
    Loop

I guess with "A_Look" calls the active sound

[AFADoomer]

Or you could just use [wiki=A_ActiveSound]the function that plays the active sound[/wiki] directly?

[Arctangent]

I'm pretty sure A_ActiveSound doesn't have the chance part of it, though. Might just need to replicate the A_Chase sound logic through an anonymous or ZScript function.

[Matt]

Might I suggest:

Code: Select all

ACTOR PinkBaby 19998
{
//$Category NPCs
  Radius 25
  Height 9
  Speed 3
  SeeSound "baby/active"
  ActiveSound "baby/active"
  States
  {
  Spawn:
    PBAB A 0 nodelay A_Jump(256,"Spawn2")
  Spawn2:
    "####" AABBCCBB 4 A_Wander
    "####" A 0 A_Jump(220,"Spawn2")  //adjust this number as needed
    "####" A 0 A_ActiveSound
    Loop
  }
}

ACTOR BlueBaby : PinkBaby 19997
{
//$Category NPCs
  States
  {
  Spawn:
    BBAB A 0 nodelay A_Jump(256,"Spawn2")
  }
}

[Hidden Hands]

Might I suggest:

Code: Select all

ACTOR PinkBaby 19998
{
//$Category NPCs
  Radius 25
  Height 9
  Speed 3
  SeeSound "baby/active"
  ActiveSound "baby/active"
  States
  {
  Spawn:
    PBAB A 0 nodelay A_Jump(256,"Spawn2")
  Spawn2:
    "####" AABBCCBB 4 A_Wander
    "####" A 0 A_Jump(220,"Spawn2")  //adjust this number as needed
    "####" A 0 A_ActiveSound
    Loop
  }
}

ACTOR BlueBaby : PinkBaby 19997
{
//$Category NPCs
  States
  {
  Spawn:
    BBAB A 0 nodelay A_Jump(256,"Spawn2")
  }
}

This is exactly what I wanted, thank you so much. You are a gem!

Also, thank you to everyone else that looked at this thread in an attempt to help. Much appreciated!