"How do I ZScript?"

[Kinsie]

I've been really wanting to ask this. How powerful is ZScript? Is it able to manipulate the monsters' movements instead of them going straightly towards the player while walking on left to right a little and shoot from time to time?

I don't think A_Chase has been exported to script, so you can't really use it as a base.

[ZZYZX]

You can write a replacement for A_Chase, it's fairly straightforward.
The problem is actually making decisions. From my tests naive approaches to astar (build WxHxZ grid, Z is needed because of 3D floors and cacodemons) cause epic lag both on level start and during chase, so there should be some algorithm to build a node list much like bot nodes. idk I'm too bad at things to do that.

[Matt]

Thus far I've been happy to just have monsters pursue an oblique point to flank the player and to avoid the most obvious threats that can be avoided. I don't even want to begin thinking about actual pathfinding.

+usespecial does nothing whether I enable it or not.

Code: Select all

class usetest:actor{
	default{
		+usespecial;
		+solid;
	}
	override bool used(actor user){
		A_Log("YAY");
		return false;
	}
	states{
	spawn:
		BEXP B -1;
		stop;
	}
}

[Graf Zahl]

Unfortunately the only way to draw things correctly is either through Menus or through a Powerup. If you try to draw from an actor, your text will flicker because the actor tick only runs at 35Hz.

To be more precise, you can only draw while the 2D screen is locked, otherwise you may get fatal errors with the software renderer. At the moment, the menu's Drawer function and the powerup overlay are the only pieces of code that get called in there but some more will come

[Major Cooke]

I've been really wanting to ask this. How powerful is ZScript? Is it able to manipulate the monsters' movements instead of them going straightly towards the player while walking on left to right a little and shoot from time to time?

I don't think A_Chase has been exported to script, so you can't really use it as a base.

You can certainly 'reinvent' it using functions and the likes that it uses.

This example, from D4D, make monsters always run directly at their target if they can. Otherwise it performs the old A_Chase methods so it can at least navigate around obstacles and stuff that gets in the way.

Code: Select all

//--------------------------------------------------------------------------
//
// D4Chase(melee, missile, flags, max turn)
//
// A_Chase enhanced, + new parameter: Max turn.
// Specifies how much in degrees the monster should turn towards its target.
// -1 will not turn it.
//--------------------------------------------------------------------------
void D4Chase(statelabel melee = "Melee", statelabel missile = "Missile", int flags = 0, double maxturn = 30.0)
{
    int newflags = 0;
    if (GetCvar("D4D_EnhancedChase"))
    {
        if (!target || target.bKilled)
        {    A_Chase(null,null,CHF_DONTMOVE|CHF_DONTTURN|CHF_NODIRECTIONTURN|CHF_NORANDOMTURN|CHF_NOPOSTATTACKTURN);    }
        
        if (A_JumpIfTargetInLOS("Null",360,JLOSF_DEADNOJUMP))
        {
            double ang = angle;
            
            // MUST BE DEFINED IN THE ACTOR USING THIS FUNCTION. Or just replace it with a number/dump the if entirely.
            if (maxturn >= 0.0)
                A_FaceTarget(maxturn,0);
            Vector2 nmpos = Vec2Angle(speed,angle);
            
            // Since we can move straight forward to the target, disable all movement for A_Chase itself.
            // Keep the melee and missile states active, however.
            if (TryMove(nmpos, false))
            {
                newflags = CHF_DONTMOVE|CHF_DONTTURN|CHF_NODIRECTIONTURN|CHF_NOPOSTATTACKTURN;
            }
            else
            {
                angle = ang;
                newflags = 0;
            }
        }
    }
    // Since some flags may be specified ahead of time, combine them with the ones used in here.
    A_Chase(melee, missile, flags|newflags);
}
 

[Graf Zahl]

Be careful with that! All normal movement splits up the move if the distance is too large, it may clip through walls if the distance between old and new pos is larger than the actor's radius. Of course if you know this cannot happen, there's nothing to worry.

[Ed the Bat]

I would really love to reinvent A_Chase so that movement is spaced evenly across the total distance, but my impression was that it couldn't be done, and all I could do was call A_Chase more frequently with smaller distances.

[Matt]

I can post what I've been trying to do so far. It's very hacky and you may need to set +nodropoff elsewhere for faster monsters. The idea is to call the standard movement, then on success reposition the actor back at its previous spot and add velocity moving it in that direction. Note that there aren't any calls to attack or heal states other than melee - those are in a separate function.

---

Code: Select all

	//the simple aimless version of A_MChase
	void A_MWander(){
		if(A_CheckBlock("null")){ //if stuck, call a normal A_Chase to get unstuck
			A_Wander();
			return;
		}
		vector3 oldpos=pos; //set starting position
		target=self; //just to get rid of that warning
		if(!TryWalk()) NewChaseDir(); //basic trywalk

		if(random(1,mass/40)+4==1) NewChaseDir();

		vector3 moveto=pos; //set destination
		setxyz(oldpos); //revert to starting position

		//move and start facing
		HDLib.FaceVector(self,moveto-pos,40);
		if(HDLib.CubeDist(self,vel)<=speed){
			moveto-=pos;
			if(moveto!=(0,0,0)) moveto/=moveto.length();
			vel+=moveto*speed/10;
		}
		//revert target
		target=null;
	}
	//a chase function kludged into giving actual velocity
	void A_MChase(){
		//abort if target dead
		if(!target || target.health<1){
			target=null;
			setstatelabel("spawn");
			return;
		}
		targetdistance=HDLib.CubeDist(self,target.pos-pos,true);

		//if within melee range, forget it just beat them
		if(targetdistance-target.radius<meleerange){
			setstatelabel("melee");
			return;
		}

		if(A_CheckBlock("null")){ //if stuck, call a normal A_Chase to get unstuck
			A_Chase(null,null);
			return;
		}

		vector3 oldpos=pos; //set starting position

		//"Chase" using the movetarget
		if(!movetarget) movetarget=spawn("idledummy",target.pos); //failsafe
		targbak=target; target=movetarget;
		if(!TryWalk()) NewChaseDir(); //basic trywalk

		target=targbak; //reset this for the A_JumpIfTargetInLOS calls
		//randomly change direction
		if(
			(random(1,mass/40)+1==1) //random direction change
			||(
				(!A_JumpIfTargetInLOS("null")) //more change if in LOS
				&&(random(1,mass/10)==1)
			)
			||(
				(!A_JumpIfTargetInLOS("null",180)) //if back to target and out of range
				&&(targetdistance<(radius+target.radius)*2)
			)
		){
			targbak=target; target=movetarget;
			NewChaseDir();
			target=targbak;
		}

		vector3 moveto=pos; //set destination
		setxyz(oldpos); //revert to starting position

		//move and start facing
		HDLib.FaceVector(self,moveto-pos,40);
		pitch=0; //apparently the forced vec3 above screws up subsequent projectile aiming, lol
		if(HDLib.CubeDist(self,vel,true)<=speed){
			moveto-=pos;
			double movetolength=moveto.length();
			if(movetolength!=0) moveto/=movetolength;
			vel+=moveto*speed*0.1;
		}
	}

("HDLib.CubeDist" is just a crude way of getting an approximate length of a vector without calling a square root. It returns the longest axis, but if needed also multiplies that number by a pre-defined square root of two if two axes are similar enough.)

[Major Cooke]

Be careful with that! All normal movement splits up the move if the distance is too large, it may clip through walls if the distance between old and new pos is larger than the actor's radius. Of course if you know this cannot happen, there's nothing to worry.

It's also missing float height adjustment, I just realized. Two things for me to work on then!

[Gutawer]

Is it possible to overload an operator inside a struct?

[Graf Zahl]

No.
What do you want to do?

[Gutawer]

Creating a struct for complex numbers. I've got all the maths down and working, but you cannot use +-*/, instead member functions must be used which are a bit unwieldy.
EDIT: Also, is there a function/operator for raising a number to a power?

[4thcharacter]

Alright, thanks. How about the other question? What are the other notable things ZScript can do?

[Kinsie]

Alright, thanks. How about the other question? What are the other notable things ZScript can do?

Try making the Heresiarch from Hexen in DECORATE. Stupid block tricks and all. (You can't, because a massive chunk of the Heresiarch's behavior pre-ZScript was hardcoded).

Here it is in ZScript. Ta-da.

[ZZYZX]

Mmm, 1138 line tada... I wouldn't use that to persuade people into using ZScript really.