Death at day , resurrect at night?

[Sephiron]

I want spectres to appear only during the night (outside, of course).
The way I have it set up is this (all spectres have the TID 9)

Code: Select all

                                //NIGHT
                                Thing_Raise (9);
                                //Above resurrects all spectres at night
                                ChangeSky("SKY1NIGH","");
                                Floor_RaiseByValue(6, 10, 160);
                                fadeto(0,0,20,0.8,1300);
                                delay(500);
                                        //MORNING
                                        Thing_Destroy (9, 0);
                                        //Above kills all spectres in the day
                                        Floor_lowerByValue(6, 10, 160);
                                        changesky("Sky1dawn","");
                                        fadeto(20,10,5,0.6,1100);
                                        delay(300);
                                            restart;
}

However none die and none resurrect. Is there something I'm missing?

[InsanityBringer]

A better way of doing it would probably be just to spawn them when night comes in, rather than resurrect them.

Other than that, the code does look right. Double-check your tags, perhaps.

[Sephiron]

A better way of doing it would probably be just to spawn them when night comes in, rather than resurrect them.

Other than that, the code does look right. Double-check your tags, perhaps.

I would do that, but I can't give spawned actors tags. How would I kill them? and I just double check my tags. maybe something else is wrong?

[NeuralStunner]

I would do that, but I can't give spawned actors tags.

Uh, yes you can. Any spawn function has a TID parameter to give to the spawned thing.

[InsanityBringer]

I would do that, but I can't give spawned actors tags. How would I kill them?

Actually, you can, [wiki]Spawn[/wiki]'s tid paramater is the tid of the spawned actor (same with SpawnSpot).

Also, post the DECORATE for the spectre.

edit: ns said the first part but still post the decorate

[Sephiron]

I just stole it from here
http://www.realm667.com/index.php?optio ... Itemid=137

---

Code: Select all

ACTOR DEWraith 302
{ 
Health 160
Radius 16 
Height 32 
Mass 50 
Speed 10 
Damage 2
MeleeDamage 1
RENDERSTYLE ADD
Obituary "A wraith had it's way with %o."
HitObituary "%o got bitten by a wraith too many times."
ALPHA 0.67 
PAINCHANCE 64 
MONSTER
+DONTGIB
+NOTARGET
+NOGRAVITY 
+FLOAT
+DONTFALL
+DONTHURTSPECIES
+THRUGHOST
AttackSound "monster/sprsit"
MeleeSound "monster/spratk"
PainSound "archvile/pain" 
DeathSound "monster/sprdth"
SpawnID 176
States 
   { 
   Spawn: 
       WRAI AB 10 A_Look 
       Loop 
   See: 
       WRAI AABB 3 A_VileChase 
       Loop 
   Missile: 
       WRAI A 10 A_FaceTarget 
       WRAI B 4 A_SkullAttack 
       WRAI AB 4 
       Goto Missile+2
   Melee:
       WRAI A 5 A_FaceTarget 
       WRAI B 5 A_MeleeAttack
       Goto See
   Heal:
       WRAI AB 3
       Goto Death 
   Pain: 
       WRAI A 3  
       WRAI A 3 A_Pain 
       Goto See 
   Death: 
       WRAI E 4 A_Noblocking
       WRAI F 5 A_Scream 
       WRAI GHIJ 4  
       Stop 
   } 
}

Also guys, thanks for the spawn link. Going to see if that works any better.


EDIT:

Still no luck :\
I replaced the resurrect with this

Code: Select all

Spawn ("wraith", -5649, 784, 32 , 9 , 6);

But it still doesn't spawn...

EDIT 2:

Oops, it's DEwraith. Going to see if that works...

EDIT 3:
Nope, still won't spawn.

EDIT 4:
It's odd... I was just walking around minding my own business when a wraith tried to kill me out of nowhere. He didn't spawn anywhere NEAR where I wanted him to!

EDIT 5:
Found out they were spawning at 0,0. Wtf?

[Salad Viking]

EDIT 5:
Found out they were spawning at 0,0. Wtf?

Try [wiki]SpawnSpot[/wiki] instead of [wiki]Spawn[/wiki]. As for why Spawn isn't working, are you sure you're correctly using [wiki=Definitions]fixed point coordinates[/wiki]?

[Sephiron]

EDIT 5:
Found out they were spawning at 0,0. Wtf?

Try [wiki]SpawnSpot[/wiki] instead of [wiki]Spawn[/wiki]. As for why Spawn isn't working, are you sure you're correctly using [wiki=Definitions]fixed point coordinates[/wiki]?

Yeah, spawnspot is working now. thanks.

[ChronoSeth]

BTW, I'm quite sure that the resurrection isn't working because the wraith doesn't have a Raise state.

[Ethril]

BTW, I'm quite sure that the resurrection isn't working because the wraith doesn't have a Raise state.

And even if it did, the death state ends with a "stop" after a frame using a duration other than -1, so the actor will simply be removed at the end of its death animation. (See: Pain Elemental)

[Graf Zahl]

Code: Select all

Spawn ("wraith", -5649, 784, 32 , 9 , 6);

Spawn uses fixed point coordinates so the above has to be:

Code: Select all

Spawn ("wraith", -5649.0, 784.0, 32.0 , 9 , 6);