Non bounce projectile disappear in water

[peewee_RotA]

In zscript I have a projectile based on VolcanoBlast. It has gravity 0.125 and almost all of the same properties. This is a standard projectile with gravity, not a bouncey projectile.

I want it to disappear if it hits water.

My understanding is that removing the related water flag (-EXPLODEONWATER) only works if it is considered a bounce projectile.

So my question is: how do I get this projectile to explode on floors but disappear in water?

Thanks!

[peewee_RotA]

As an update, I am using a workaround. It is now a bouncey projectile, but I have it emulate a normal projectile impact

---

Code: Select all

class VolcanoMonsterBlast : Actor
{
	Default
	{
		Radius 8;
		Height 8;
		Speed 10;
		Damage 4;
		DamageType "Fire";
		Gravity 0.125;
		+NOBLOCKMAP +MISSILE +DROPOFF
		+NOTELEPORT
		+STRIFEDAMAGE
		-EXPLODEONWATER // Don't do a missile impact on water, just disappear and never go to death frames.
		BounceType "Heretic"; // Missile impact on walls, but not planes... but DOES go to death frames on planes
	}

	States
	{
	Spawn:
		VFBL AB 4 BRIGHT A_SpawnItemEx("Puffy", random2[BeastPuff]()*0.015625, random2[BeastPuff]()*0.015625, random2[BeastPuff]()*0.015625, 
									0,0,0,0,SXF_ABSOLUTEPOSITION, 64);
		Loop;

	Death:
		XPL1 A 4 BRIGHT A_VolcBallImpact; // Call impact code on death
		XPL1 BCDEF 4 BRIGHT;
		Stop; // Die
	}
	
	//----------------------------------------------------------------------------
	//
	// PROC A_VolcBallImpact
	//
	//----------------------------------------------------------------------------

	void A_VolcBallImpact ()
	{
		A_Stop(); // Stop all movement, which would otherwise continue moving since it is a bounce projectile
		
		// Raise from ground and remove gravity (if necessary)
		A_StartSound("world/volcano/blast");
		if (pos.Z <= floorz)
		{
			bNoGravity = true;
			Gravity = 1;
			AddZ(28);
		}
		A_Explode(25, 25, XF_NOSPLASH|XF_HURTSOURCE, false, 0, 0, 0, "BulletPuff", 'Fire');
		for (int i = 0; i < 4; i++)
		{
			Actor tiny = Spawn("VolcanoTBlast", Pos, ALLOW_REPLACE);
			if (tiny)
			{
				tiny.target = self;
				tiny.Angle = 90.*i;
				tiny.VelFromAngle(0.7);
				tiny.Vel.Z = 1. + random[VolcBallImpact]() / 128.;
				tiny.CheckMissileSpawn (radius);
			}
		}
	}
}

[Heisanevilgenius]

There is a variable "waterlevel" that you can use to check if the projectile is underwater, and if true, you can have it make your projectile disappear.

Code: Select all

VFBL A 0
{
if (waterlevel > 0)
  {
    return ResolveState("Disappear");
  }
  return ResolveState(null);
}

[Enjay]

I usually go for a slightly simply syntax:

Code: Select all

FLRE A 0 A_JumpIf(waterlevel > 0, "Spent"); //jump straight to spent if under water

For what it's worth, this page explains the values for waterlevel:
https://zdoom.org/wiki/Swimming#Waterlevel



However, I note that the original query says "I want it to disappear if it hits water", although the title says "in water". So, if peewee_RotA wants the projectile to disappear when it hits regular non-deep water (like the liquids in vanilla Doom maps) I don't think waterlevel will help.

[peewee_RotA]

That's for the info.

I'm targeting vanilla heretic maps. I'll give it a try.