Weapon with ammo regen always auto-switches when empty

[Pandut]

So this is an annoying problem with a potentially simple fix that I'm just not seeing;

I have a weapon with regenerating ammo via ACS. It regens 2 ammo every 35 ticks. This weapon consumes 20 ammo per shot. When the ammo drops below 20, the weapon autoswaps to something else no matter what. What I've tried -

- A_JumpIfNoAmmo to a NoAmmo/NoAmmoReady/Dryfire state to prevent autoswapping. This gets completely ignored by the weapon code if placed in the Ready State, Deselect State or the end of the Fire State. If placed at the start of the Fire state the weapon will *always* jump to the NoAmmo states regardless of ammo count.
- A_JumpIfInventory for the same thing. This one just doesn't work at all because it can really only be reliably set to "jump if completely empty" or "jump if completely full". IDK how to set it to "jump if below 20". Works great for weapons with reloads, but not "vanilla" styled weapons.
- Setting the weapon to use consume 0 ammo and use A_TakeInventory to subtract the ammo. This results in the weapon just having infinite ammo when it reaches 0, ignoring any calls to jump to a NoAmmo state.

---

ACTOR InquisitorStaff : Weapon Replaces RocketLauncher
{
Inventory.PickupMessage "You've found an Inquisitor's Staff."
Inventory.PickupSound "MagicWeapon/Pickup"
Weapon.AmmoType1 "ManaPool"
Weapon.AmmoType2 "ManaPool"
Weapon.AmmoUse1 20
Weapon.AmmoUse2 40
Weapon.AmmoGive1 1
Weapon.UpSound "Inq/Up"
Weapon.SlotNumber 5
Weapon.SelectionOrder 2
Weapon.KickBack 1
Weapon.BobStyle InverseSmooth
Weapon.BobRangeX 0.6
Weapon.BobRangeY 0.6
Weapon.BobSpeed 1.0
+Weapon.Ammo_CheckBoth
+BRIGHT
Tag "Inquisitor's Staff"
States
{
Spawn:
TNT1 A 1 NoDelay
TNT1 A 1 A_SpawnItemEx("InquistorPickup",25,0,20,5,0,0,0,SXF_ABSOLUTEPOSITION)
Stop
Ready:
TNT1 A 0 A_JumpIfNoAmmo(1)
Goto NoAmmoReady
INQS ABCDCB 3 A_WeaponReady
goto ready
Select:
INQS A 1 A_Raise
Loop
Deselect:
TNT1 A 0 A_PlaySound("Weapon/Foley", 7)
ActualDeselect:
INQS A 1 A_Lower
Loop
Fire:
TNT1 A 0
TNT1 A 0 A_JumpIfNoAmmo(1)
Goto NoAmmoDryFire
INQS A 1 A_GunFlash("MagicHand")
INQS AB 3
TNT1 A 0 A_PlaySound("Inq/Fire", 1)
TNT1 A 0 A_FireCustomMissile("InquisitorBall",0,1,1,1,0,0)
INQS CDCBABCDCB 3
TNT1 A 0 A_ReFire("Fire")
Goto Ready
MagicHand:
INQH ABCDEFG 1
INQH H 1 A_ZoomFactor(0.98)
TNT1 A 0 A_Light(1)
INQH H 1 A_ZoomFactor(0.96)
TNT1 A 0 A_Light(2)
INQH I 1 A_ZoomFactor(0.94)
TNT1 A 0 A_Light(3)
INQH I 1 A_ZoomFactor(0.93)
TNT1 A 0 A_Light(4)
INQH J 1 A_ZoomFactor(0.94)
TNT1 A 0 A_Light(3)
INQH J 1 A_ZoomFactor(0.96)
TNT1 A 0 A_Light(2)
INQH K 1 A_ZoomFactor(0.98)
TNT1 A 0 A_Light(1)
INQH K 1 A_ZoomFactor(1.00)
TNT1 A 0 A_Light(0)
INQH LMN 2
INQH OPQR 1
INQH S 6
Stop
NoAmmoHand:
INQH ABCDEFG 1
INQH G 3
INQH FEDCBA 1
Stop
//AltFire
AltFire:
TNT1 A 0
INQS A 1 A_GunFlash("MagicHand")
INQS AB 3
TNT1 A 0 A_PlaySound("Inq/AltFire", 1)
TNT1 A 0 A_FireCustomMissile("InqRainBall",0,1,1,1,0,0)
TNT1 A 0 A_Quake(2, 10, 0, 25, "None")
INQS CDCBABCDCB 3
TNT1 A 0 A_ReFire("AltFire")
Goto Ready
NoAmmoDryFire:
TNT1 A 0 A_PlaySound("Mana/Empty", 6)
INQS A 16 A_GunFlash("NoAmmoHand")
Goto Ready
NoAmmo:
INQS A 1
Goto NoAmmoReady
NoAmmoReady:
INQS ABCDCB 3 A_WeaponReady
goto Ready
}
}

This was my last iteration before I gave up. Right now it always jumps to the "NoAmmoDryFire" state even at full ammo.

[Virathas]

I personnally would approach it using both 2 and 3 approaches. First, i would set the ammo use to 0 indeed, use take inventory to spend the mana, but i would also add the A_JumpIfInventory function. It is important to remember, that the function jumps if it finds the preset value or more, so the fire state would be reversed:

Code: Select all

Fire:
TNT1 A 0 
TNT1 A 0 A_JumpIfInventory("ManaPool", 20, "ActualFire")
Goto NoAmmoDryFire
ActualFire:

Also, it is best to avoid using offsets in jump states, as it is very easy to make a mistake there.

[Pandut]

That worked! It did not even occur to me to do it in a reversed manner, thanks a ton .