Radius thrust limit to specific cone in front of player

[williamhernandez]

Hello all,

I'm a new member. I have a question.

How can I achieve the use of Radius thrust, but limit it to a specific cone in front of the player? Should I implement a different function altogether for this purpose?uno online

Thanks in advance.

[Jarewill]

Welcome!

To my knowledge there isn't any function like that, however you can use a custom one.
This is a modified A_Blast function that also checks if the player is looking at the monsters:

---

Code: Select all

	Action void A_DirectionalBlast(double fov = 90, int blastflags = 0, double strength = 255, double range = 255, double speed = 20, sound blastsound = "BlastRadius"){
		//This is copied directly from gzdoom.pk3:zscript/actors/hexen/blastradius.zs
		if (player && (blastflags & BF_USEAMMO) && invoker == player.ReadyWeapon && stateinfo != null && stateinfo.mStateType == STATE_Psprite)
		{
			Weapon weapon = player.ReadyWeapon;
			if (weapon != null && !weapon.DepleteAmmo(weapon.bAltFire))
			{
				return;
			}
		}

		A_StartSound (blastsound, CHAN_AUTO);

		if (!(blastflags & BF_DONTWARN))
		{
			SoundAlert (self);
		}
		ThinkerIterator it = ThinkerIterator.Create("Actor");
		Actor mo;
		while ( (mo = Actor(it.Next ())) )
		{
			if (mo == self || (mo.bBoss && !(blastflags & BF_AFFECTBOSSES)) || mo.bDormant || mo.bDontBlast)
			{ // Not a valid monster: originator, boss, dormant, or otherwise protected
				continue;
			}
			if (mo.bIceCorpse || mo.bCanBlast)
			{
				// Let these special cases go
			}
			else if (mo.bIsMonster && mo.health <= 0)
			{
				continue;
			}
			else if (!mo.player && !mo.bMissile && !mo.bIsMonster && !mo.bCanBlast && !mo.bTouchy && !mo.bVulnerable)
			{	// Must be monster, player, missile, touchy or vulnerable
				continue;
			}
			if (Distance2D(mo) > range)
			{ // Out of range
				continue;
			}
			if (mo.CurSector.PortalGroup != CurSector.PortalGroup && !CheckSight(mo))
			{
				// in another region and cannot be seen.
				continue;
			}
			if ((blastflags & BF_ONLYVISIBLETHINGS) && !isVisible(mo, true)) 
			{
				//only blast if target can bee seen by calling actor
				continue;
			}
			//This code is added for directional detection
			Actor oldtarg = mo.target;
			mo.target=self;
			If(mo.CheckIfInTargetLOS(fov)){
				//BlastActor is private so we couldn't use it here
				If(!mo.SpecialBlastHandling(self,strength)){Return;}
				mo.vel.xy = AngleToVector(AngleTo(mo),speed);
				If(mo.bMISSILE){
					If(!mo.bFLOORHUGGER&&!mo.bCEILINGHUGGER){mo.vel.z=8;}
				}Else{
					mo.vel.z=1000./mo.mass;
				}
				If(mo.player){}
				Else If(!(blastflags&BF_NOIMPACTDAMAGE)){mo.bBLASTED=true;}
				If(mo.bTOUCHY){
					mo.bARMED=false;
					mo.DamageMobj(self,self,mo.health,"Melee",DMG_FORCED|DMG_EXPLOSION);
				}
			}
			mo.target=oldtarg;
		}
	}

You can also use this function in DECORATE.
Create a new class in ZScript depending on how you want to use it, for example a Weapon:

Code: Select all

Class NewWeapon : Weapon{
	Action void A_DirectionalBlast(....)
}

Then in DECORATE you can inherit your weapons from NewWeapon and freely use this function.