Valid Custom Monster Definition

[Exosphere]

Hello again ZDoom Forums,

I'm going to be adding a few custom monsters to my mod. I would like to create them from the ground up in DECORATE (and might have a good idea on how to do that), but I want to make sure that this is a valid definition of a monster. I would also like any tips that might be necessary in creating monsters.

Code: Select all

ACTOR Synth 29999
{
        //Important values and numbers here
	Monster
	States:
	{
		//input stuff here
	}
}

[Nevander]

Looks good to me. I'm not actually sure what properties are 100% required since I don't actually write a lot of new actors from scratch unless they are just decorative objects or other small things. Some that I would absolutely include are stuff like MONSTER (which you have), health, radius and height, speed, and sounds; and of course the states. Here's an example of a simple monster coded completely from nothing (no inheritance) to give you an idea of the kind of properties I used.

---

Code: Select all

ACTOR 64NightmareImp 3007
{
	//$Color 12
	//$Category Doom64Things
	SpawnID 155
	Health 60
	RenderStyle Translucent
	Alpha 0.60
	Speed 13
	PainChance 200
	Radius 24
	Height 84
	Mass 100
	MeleeDamage 3
	Species "64NightmareImp"
	BloodColor "7B 5A 84"
	SeeSound "imp/sight"
	PainSound "imp/pain"
	DeathSound "imp/death"
	ActiveSound "imp/active"
	MeleeSound "imp/melee"
	MissileType "64NightmareImpBall"
	Obituary "$OB_NIGHTIMP"
	HitObituary "$OB_NIGHTIMPHIT"
	MONSTER
	+FLOORCLIP
	+MISSILEMORE
	+MISSILEEVENMORE
	
	States
	{
		Spawn:
			TRO2 AB 10 A_Look
			Loop
		See:
			TRO2 AABBCCDD 3 A_Chase
			Loop
		Melee:
			TRO2 EF 8 A_FaceTarget
			TRO2 G 6 A_MeleeAttack
			Goto See
		Missile:
			TRO2 IJ 8 A_FaceTarget
			TRO2 K 6 A_CustomMissile("64NightmareImpBall", 64)
			Goto See
		Pain:
			TRO2 H 2
			TRO2 H 2 A_Pain
			Goto See
		Pain.Vertigo:
			TRO2 H 0 ThrustThingZ(0, 55, 0, 0)
			TRO2 H 2
			TRO2 H 2 A_Pain
			Goto See
		Death:
			TRO2 L 8
			TRO2 M 8 A_Scream
			TRO2 N 6
			TRO2 O 6 A_NoBlocking
			TRO2 P -1
			Stop
		XDeath:
			TRO2 Q 5
			TRO2 R 5 A_XScream
			TRO2 S 5
			TRO2 T 5 A_NoBlocking
			TRO2 UVW 5
			TRO2 X -1
			Stop
		Raise:
			TRO2 PO 8
			TRO2 NML 6
			Goto See
		Crush: // Uses a violet version of the gib to match sprite color
			A055 A 0
			A055 A 0 A_PlaySound("misc/gibbed")
			A055 A -1
			Stop
	}
}

[Mikk-]

One thing I already noticed is that there's a ':' after States - that shouldn't be there, colons should only come after State Labels.