Help with referencing weapon in Event Handler

[JMaszk]

I've been trying to reference the player's weapon through event handler with no success. What I'm trying to do is a weapon overlay via event handler for a key bind. I think I'm doing everything else right besides the reference to the weapon because it still prints out my test message but A_Overlay does nothing. I'm not sure what I'm doing wrong.

Attached file has a testable example, thanks.

[Jarewill]

Replace A_Overlay in your event handler with the following:

Code: Select all

player.player.SetPSprite(500,weap.FindState("VisorLayer"));

player.player is required as the player actor needs to be interpreted as a player instead of just as an actor.

For instance, players[e.Player] returns a player, while players[e.Player].mo returns a player actor.
Both have different uses.

[JMaszk]

Ahh yes! That was it, thank you. I'll also keep those differences in mind in the future.

Is it possible to keep the Visor state from deselecting after weapon switch??

[Jarewill]

As the weapon gets deselected, all of its overlays get cleared, so you will need to work around that.
You could try using CustomInventory items as they can have overlays, even if it might be a little hacky:

---

Code: Select all

Class Inventory_LayerTest : CustomInventory
{
	States
	{
	Pickup:
		TNT1 A 0 A_RailWait(); //Required function to give the item to the inventory
		Stop;
	Use:
		TNT1 A 0 A_Overlay(500, "VisorLayer", FALSE);
		Fail; //Required to use Fail instead of Stop to prevent the item from being removed
	VisorLayer:
		VISR A 1 Bright;
		Loop;
	}
}

Then in your event handler use this instead:

Code: Select all

    override void NetworkProcess (ConsoleEvent e)
    {
		let player = players [e.Player].mo;
		let item = player.FindInventory('Inventory_LayerTest');

        if (e.Name ~== "Test_Activate")
        {
				Console.Printf("Test");
				player.UseInventory(item);
				//player.player.SetPSprite(500,weap.FindState("VisorLayer"));
		}
    }

Though at this point you could also replace the keybind netevent Test_Activate with use Inventory_LayerTest and it would also work.
Also this will require you to shift the offset of the overlay a bit down.

[JMaszk]

CustomInventory should be ok. I just read on the Wiki:
"This class is unnecessary in ZScript outside of very specific use cases, like overlays."

Neat, I didn't know you could have overlays outside of weapons. The only issue now is I had weapons in mind because I wanted to be able to select and deselect the overlay. I'm not sure if that's possible through the CustomInventory method?

[Jarewill]

What exactly do you mean by "select and deselect the overlay"?
If you want it to be toggle-able, you could modify the item to this:

---

Code: Select all

Class Inventory_LayerTest : CustomInventory
{
	bool toggled; //Variable to keep the current state
	States
	{
	Pickup:
		TNT1 A 0 A_RailWait();
		Stop;
	Use:
		TNT1 A 0
		{
			If(Invoker.toggled)
			{ //Check if it's currently on
				A_Overlay(500, null, FALSE); //If it's on, turn off the overlay
				Invoker.toggled = false; //And the variable
			}
			Else
			{
				A_Overlay(500, "VisorLayer", FALSE); //Otherwise turn on the overlay
				Invoker.toggled = true; //And the variable
			}
		}
		Fail;
	VisorLayer:
		VISR A 1 Bright;
		Loop;
	}
}

[JMaszk]

Yeah, that's even better than what I was thinking initially! I realize how obvious the toggle was... I don't know why I didn't think of that!

Thank you so much for all your help on this, I appreciate it!