Hell-Forged - Episode 2 (Restarting Eventually)

[jazzmaster9]

there sprites are looking amazing so far.
these would fit perfectly well to my vampire themed Abysm 2 episode though Im guessing they are still off limits until the release of HF2 ?

[Amuscaria]

though Im guessing they are still off limits until the release of HF2 ?

yup.

[broomann43]

So excited to hear about this - Hellforged Episode 1 was such a blast and that secret map was beyond anything I could have expected. If Episode 2 comes anywhere close to meeting the goals you set out here, I have no doubt that it will be just as impressive. You do fantastic work, seriously

[Amuscaria]

So excited to hear about this - Hellforged Episode 1 was such a blast and that secret map was beyond anything I could have expected. If Episode 2 comes anywhere close to meeting the goals you set out here, I have no doubt that it will be just as impressive. You do fantastic work, seriously

Thanks! Unfortunately, it will be some time before I continue work on this mod. Read the below statement for more info.
-------------------------------------------------------------

HI All. It's been some time since I've work on this mod because I've redirected most of my time towards my art and Visual Novel game for the past couple of months. I don't really have time to maintain two projects at once these days, or do I do a good job with one project distracting me from another, so I just jump between theme from time to time. So needless to say, it will be some time before I return to Hell-Forged 2.

I'd be a dick move to just sit on the resources I've done so far, so I am opening the resources I've released to the public so far for public use. You are free to use them as is, edit them, or redistribute them on you own project as you see fit. I wouldn't mind getting a shoutout here and there.

-Cheers. Will return after I burn out on drawing anime pictures for the visual novel.

[ActionAlligator]

HI All. It's been some time since I've work on this mod because I've redirected most of my time towards my art and Visual Novel game for the past couple of months. I don't really have time to maintain two projects at once these days, or do I do a good job with one project distracting me from another, so I just jump between theme from time to time. So needless to say, it will be some time before I return to Hell-Forged 2.

Damn, shame to hear as I was excited about this I really loved HF 1 and appreciate the work you put towards it and look forward to your return to HF 2!

It'd be a dick move to just sit on the resources I've done so far so I am opening the resources I've released to the public so far for public use. You are free to use them as is, edit them, or redistribute them on you own project as you see fit

I respectfully disagree that it'd be a dick move But, your resource gift is too kind sir and I'm sure others will appreciate it Again, thx for your work and offerings thus far and good luck with your other project! Those anime VN fans will surely be getting a quality project to get excited over

[Lagi]

Could anyone who use Amuscaria monsters please advertise his mod here?


I am supper happy to see this guys in motion

[Captain J]

An excellent, generous choice with allowing people to use your resources that you've released so far to the public. Always thank you for making all kinds of cool and influential resources for doom community through out the years.

[osjclatchford]

... so I am opening the resources I've released to the public so far for public use. You are free to use them as is, edit them, or redistribute them on you own project as you see fit. I wouldn't mind getting a shoutout here and there. ...

absolute gentlemen.






and one both sad and happy at-the-same-time OSJC... ;D

[Scuba Steve]

Absolute legend of you. Beyond being respectful and attributing your work, will we need to carve up the sprite sheets and decorate the monsters ourselves, or is there a decorate file already available which appropriate codes the monsters and their attacks?

[osjclatchford]

Could anyone who use Amuscaria monsters please advertise his mod here?
I am supper happy to see this guys in motion

this is a fair point tbh.

would help to get the proper credit-where-credit's-due this mod and epic-modder deserves. its easy for stuff to get diluted in the mod-soup thats out there...
Its no stretch to say that without Amuscaria's mods and subsquent resources the modding community would be a much lesser place imho...

guess I'll start us off then:
https://www.moddb.com/mods/osjcs-doom-major-crisis - get my possessed edits of the wight monster here (mc_monsata.pk3)

[Amuscaria]

Absolute legend of you. Beyond being respectful and attributing your work, will we need to carve up the sprite sheets and decorate the monsters ourselves, or is there a decorate file already available which appropriate codes the monsters and their attacks?

Sprite resource wad attached.

https://drive.google.com/file/d/1x_Ljjf ... sp=sharing

Monster decorate code:

---

Code: Select all

//================================||MONSTERS||==================================
//==================================WIGHT=======================================
ACTOR Wight1 32100
{  
  Health 30
  Radius 20
  Height 56
  Mass 75
  Speed 8
  PainChance 200
  PainChance "wepkick", 250
  Monster  
  BloodColor "72 4b 3f"
  Tag "Wight"
  SeeSound "wight/sight"
  PainSound "wight/pain"
  DeathSound "wight/death"
  ActiveSound "wight/active"  
  HitObituary "%o was beaten to death by a Wight."  
  +FLOORCLIP
  States
  {
  Spawn:
    WGHT AB 10 A_Look
    Loop
  See:
    WGHT AABBCCDD 3 A_Chase
    Loop
  Melee:
  Melee1:
    WGHT E 6 {A_FaceTarget; A_PlaySound("wight/attack",4);}
	WGHT F 6 A_FaceTarget
    WGHT G 6 A_CustomMeleeAttack(random(1,10) * 2, "wight/hit")
	WGHT G 0 A_JumpIfCloser(64, "Melee2")
	Goto See
  Melee2:
	WGHT B 2 A_FaceTarget
	WGHT H 6 {A_FaceTarget; A_PlaySound("wight/attack",4);}
	WGHT I 6 A_FaceTarget
    WGHT J 6 A_CustomMeleeAttack(random(1,10) * 2, "wight/hit")
    Goto See
  Pain:
    WGHT K 2
    WGHT K 2 A_Pain
    Goto See
  Pain.wepkick:
    WGHT K 2 
    WGHT K 50 A_Pain
    Goto See
  Death:
    WGHT L 8 A_Scream
    WGHT M 8 A_NoBlocking    
    WGHT NOP 6
    WGHT Q random(245, 700)
	WGHT Q 1 CanRaise Thing_Raise(0)
    wait
  XDeath:
    WGHT R 5
    WGHT S 5 A_XScream
    WGHT T 5 A_NoBlocking
    WGHT UVWXYZ 5
    WGHT [ -1
    Stop
  Raise:
    WGHT PONML 7
    Goto See
  }
}
//================================PUTREFIER=====================================
ACTOR Putrefier 32101
{
  Health 400
  Radius 31
  Height 56
  Mass 400
  Speed 8
  PainChance 128
  Monster
  BloodColor "72 4b 3f" 
  Tag "Putrefier"
  SeeSound "putrefier/sight"
  PainSound "putrefier/pain"
  DeathSound "putrefier/death"
  ActiveSound "putrefier/active"
  Obituary "%o was splattered by a Putrefier."
  +FLOAT
  +NOGRAVITY
  +FLOORCLIP
  States
  {
  Spawn:
    MIKE ABC 10 A_Look
    Loop
  See:
    MIKE AABBCCDDEEFF 3 A_Chase
    Loop
  Missile:
    MIKE GHI 5 A_FaceTarget
    MIKE I 0 A_CustomMissile("PukeMissile",32)
    Goto See
  Pain:
    MIKE J 6
    MIKE J 6 A_Pain
    Goto See
  Pain.wepkick:
    MIKE J 6
	MIKE J 24 A_Pain
  Death:
    MIKE K 5 {A_NoBlocking; A_Scream; A_Die;}
    MIKE K 5
	goto Death+1  
  Crash:
    MIKE L 8 {A_NoBlocking; A_PlaySound("putrefier/crash");}
	MIKE MNO 8
	MIKE PPPPP random(70,350) A_SpawnItemEX("PukeFlesh2",random(-10,10),random(-10,10),0,0,0,0)
	MIKE P -1	
  Raise:
    MIKE PONML 8
    Goto See
  }
}

ACTOR PukeMissile
{
  Radius 20
  Height 26
  Speed 15
  FastSpeed 25
  Damage 5
  Projectile
  +RANDOMIZE  
  RenderStyle Normal  
  SeeSound "putrefier/attack"
  DeathSound "putrefier/hit"
  States
  {
  Spawn:
    PUKE AB 4 Bright
    Loop
  Death:
    PUKE C 6 Bright A_SpawnItemEx("PukeFlesh",0,0,0,0,0,0,0)
	PUKE DE 6 Bright
	Stop	
  XDeath:	
  Crash:    
    PUKE CDE 6 Bright
    Stop
  }
}

Actor PukeFlesh
{
   Projectile
   RenderStyle Normal
   ReactionTime 4
   DeathSound "misc/gibbed"   
   +RANDOMIZE 
   +DONTSPLASH
   +NODAMAGETHRUST
   +FORCEXYBILLBOARD
   +THRUACTORS
   +FLOORHUGGER   
   -NOGRAVITY
   States
   {
   Spawn:      
	  PUKE F 2 A_CheckFloor("See") 	       
      loop
   See:
      PUKE GH 5
	  PUKE I 5 { A_PlaySound("misc/slime");}
	  PUKE HIH 5
	  PUKE I 5 { A_CountDown; A_PlaySound("misc/slime");}
	  goto See+1
   Death:
	  PUKE JKL 5
	  WGHT B 5
	  WGHT B 0 A_SpawnItemEX("Wight1",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
      stop
   }
}

Actor PukeFlesh2
{
   Projectile
   RenderStyle Normal
   ReactionTime 4
   DeathSound "misc/gibbed"   
   +RANDOMIZE 
   +DONTSPLASH
   +NODAMAGETHRUST
   +FORCEXYBILLBOARD
   +THRUACTORS
   +FLOORHUGGER   
   -NOGRAVITY
   States
   {
   Spawn:
      PUKE H 5
	  PUKE I 5 { A_PlaySound("misc/slime");}
	  PUKE HIH 5
	  PUKE I 5 { A_CountDown; A_PlaySound("misc/slime");}
	  loop
   Death:
	  PUKE JKL 5
	  WGHT B 5
	  WGHT B 0 A_SpawnItemEX("Wight1",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
      stop
   }
}

//================================ABYSS MITE====================================
ACTOR Mite 32102
{
  Health 20
  Radius 16
  Height 30
  Mass 50
  Speed 10
  PainChance 200
  PainChance "wepkick", 256  
  Monster
  MaxTargetRange 200
  Damagetype weppoison
  BloodColor "95 91 16"
  Tag "Abyss Mite"
  SeeSound "mite/sight"
  PainSound "mite/pain"
  DeathSound "mite/death"
  ActiveSound "mite/active"   
  HitObituary "%o was bitten to death by a mite."
  Obituary "%o was liquified by a mite."
  +DONTHARMSPECIES
  +DONTHARMCLASS
  +FLOORCLIP
  +THRUSPECIES
  States
  {
  Spawn:
    MITE M 10 A_Look
    Loop
  See:
    MITE AABBCCDDEEFF 2 Fast A_Chase
    Loop
  Rest:
    MITE AABBCCDDEEFF 2 Fast A_Chase("Melee","")
	goto See
  Missile:    
    MITE G 12  {A_PlaySoundEX("mite/attack", "Auto"); A_FaceTarget;}
	MITE H 0 {A_SetGravity(0.5); A_Recoil(-20); ThrustThingZ(0,28,0,0);}
	MITE H 1 A_JumpIfTargetInsideMeleeRange("Kaboom")
	MITE H 1 A_CheckFloor("Land")
	goto Missile+2
  Melee:
    MITE GH 5 A_FaceTarget	
	MITE I 5 A_CustomMeleeAttack(1 * random(1,4),"mite/melee","","weppoison")
	Goto See
  Kaboom:
    MITE K 1 Bright A_Die("kaboom")
	stop
  Land:
    MITE I 3 A_SetGravity(1.0)
	goto Rest
  Pain:
    MITE J 2 Fast A_SetGravity(1.0)
    MITE J 2 Fast A_Pain
    Goto See
  Pain.wepkick:
    MITE J 2 Fast A_SetGravity(1.0)
    MITE J 50 A_Pain
    Goto See
  Death:
    MITE N 0 A_SetGravity(1.0)
    MITE N 5 A_Scream
    MITE O 5 { A_NoBlocking; A_SpawnItemEX("SOBGas2",0,0,0,0,0,1,0,SXF_CLIENTSIDE);}     
    MITE PQR 5
	MITE S -1
  Death.kaboom:
    MITE K 3 Bright {A_Stop; A_NoGravity; A_NoBlocking; A_PlaySound("weapons/splat4");}
	MFX1 K 0 Bright {A_Explode(12 * random(1,4),64,XF_NOTMISSILE,0,36); A_SpawnItemEx("MiteFX",0,0,15,0,0,0,0);}	
	stop
  Raise:
    MITE RQPON 5
    Goto See
  }
}

ACTOR MiteFX
{  
  RenderStyle ADD   
  Mass 5  
  +NOBLOCKMAP
  +NOGRAVITY
  +ALLOWPARTICLES
  +RANDOMIZE  
  States
  {
  Spawn:    
	MFX1 QRSTU 3 Bright    
    stop
  }
}
//=================================STRIGA=======================================
ACTOR Striga 32103
{  
  Health 50
  Radius 20
  Height 32
  Mass 75
  Speed 12
  PainChance 180
  PainChance "wepkick", 220
  Monster    
  Tag "Striga"
  SeeSound "striga/sight"
  PainSound "striga/pain"
  DeathSound "striga/death"
  ActiveSound "striga/active"  
  HitObituary "A striga drained %o dry."  
  +FLOORCLIP
  States
  {
  Spawn:
    STRI AB 10 A_Look
    Loop
  See:    
    STRI AA 3 {A_Chase; A_SpawnItemEx("StrigaFX",-32,0,0,0,0,0,0,SXF_CLIENTSIDE);}
	STRI B 3 {A_Chase; A_PlaySound("striga/move",4); A_SpawnItemEx("StrigaFX",-32,0,0,0,0,0,0,SXF_CLIENTSIDE);}
	STRI BCCDD 3 {A_Chase; A_SpawnItemEx("StrigaFX",-32,0,0,0,0,0,0,SXF_CLIENTSIDE);}
	STRI E 3 {A_Chase; A_PlaySound("striga/move",4); A_SpawnItemEx("StrigaFX",-32,0,0,0,0,0,0,SXF_CLIENTSIDE);}
	STRI EFF 3 {A_Chase; A_SpawnItemEx("StrigaFX",-32,0,0,0,0,0,0,SXF_CLIENTSIDE);}
    Loop
  Melee:
    STRI G 6 {A_FaceTarget; A_PlaySound("striga/attack",4);}
    STRI H 6 A_FaceTarget
	STRI I 6 A_CustomMeleeAttack(random(1,10) * 2, "striga/hit")
	Goto See
  Pain:
    STRI J 2
    STRI J 2 A_Pain
    Goto See
  Pain.wepkick:
    STRI J 2 
    STRI J 50 A_Pain
    Goto See
  Death:
    STRI K 5 A_Scream
    STRI L 5 A_NoBlocking    
	STRI MNOPQR 5  
    STRI S -1
    stop
  Raise:
    WGHT RQPONMLK 7
    Goto See
  }
}

Actor StrigaFX
{
   Radius 5
   Height 1   
   +NOGRAVITY
   +DONTSPLASH
   +THRUACTORS
   +FLOORHUGGER
   +FLATSPRITE    
   States
   {
   Spawn:      
      STFX ABCD 18	  
   Death:       
	  stop
   }
}
//================================HEMODEMON=====================================
ACTOR Hemodemon 32104
{
  Health 400
  Radius 31
  Height 56
  Mass 400
  Speed 12
  PainChance 128
  Monster   
  Tag "Hemodemon"
  SeeSound "hemodemon/sight"
  PainSound "hemodemon/pain"
  DeathSound "hemodemon/death"
  ActiveSound "hemodemon/active"
  Obituary "%o was toasted by a Hemodemon."
  +FLOAT
  +NOGRAVITY
  +FLOORCLIP
  States
  {
  Spawn:
    HEMO A 10 A_Look
    Loop
  See:
    HEMO AA 3 A_Chase
    Loop
  Melee:	
  Missile:
    HEMO A 0 A_JumpIfInventory("BloodLustToken",1, "Missile2")
    HEMO BC 5 Bright A_FaceTarget
	HEMO D 5 Bright A_CustomComboAttack("HemodemonBall1",24, 10*random(1,6),"caco/melee","wepnormal",false)    
    Goto See
  Missile2:
    HEMO BC 5 Bright A_FaceTarget
    HEMO D 5 Bright {A_CustomComboAttack("HemodemonBall2",24, 15*random(1,6),"caco/melee","wepnormal",false); A_TakeInventory("BloodLustToken",1);}
    Goto See 	
  Pain:
    HEMO E 6
    HEMO E 6 A_Pain
    Goto See
  Pain.wepkick:
    HEMO E 6
	HEMO E 24 A_Pain
  Death:
    HEMO F 5 {A_NoBlocking; A_Scream; A_Die;}
    HEMO F 5
	goto Death+1  
  Crash:
    HEMO G 8 {A_NoBlocking; A_PlaySound("putrefier/crash");}
	HEMO HIJ 8
	HEMO K -1	
  Raise:
    HEMO KJIHGF 8
    Goto See
  }
}

ACTOR HemodemonBall1
{
  Radius 6
  Height 12
  Speed 20
  FastSpeed 25
  Damage 5
  Projectile   
  RenderStyle ADD  
  SeeSound "hemodemon/launch"
  DeathSound "hemodemon/explode"
  +RANDOMIZE 
  States
  {
  Spawn:
    BAL6 AB 4 Bright
    Loop 
  Crash:	
  Death:    
    BAL6 CDEFG 4 Bright	
	Stop	
  XDeath:
    BAL6 C 4 Bright A_GiveToTarget("BloodLustToken",1)
    BAL6 DEFG 4 Bright	
    Stop
  }
}

ACTOR HemodemonBall2 : HemodemonBall1
{
  Radius 10
  Height 20  
  Damage 10  
  States
  {
  Spawn:
    BAL5 AB 4 Bright
    Loop 
  Crash:	
  Death:    
    BAL5 CDEFG 4 Bright	
	Stop	
  XDeath:
    BAL5 C 4 Bright A_GiveToTarget("BloodLustToken",2)
    BAL5 DEFG 4 Bright	
    Stop
  }
}

ACTOR BloodLustToken: Inventory //used to give the vampiric enemies Bloodlust
{
     Inventory.Amount 1
     Inventory.MaxAmount 10
}
//=================================VAMPIRE======================================
ACTOR Vampyr 32105
{  
  Health 120
  Radius 20
  Height 60
  Mass 75
  Speed 8
  PainChance 144
  PainChance "wepkick", 225
  Monster    
  Tag "Vampyr"
  SeeSound "vampyr/sight"
  PainSound "vampyr/pain"
  DeathSound "vampyr/death"
  ActiveSound "vampyr/active"  
  HitObituary "%o was slashed up by a Vampyr."  
  +FLOORCLIP
  States
  {
  Spawn:
    VAMP AB 10 A_Look
    Loop
  See:
    VAMP AABBCCDD 3 A_Chase
    Loop
  Melee:  
  Missile:    
    VAMP E 6 {A_FaceTarget; A_PlaySound("vampyr/attack",4);}
	VAMP F 6 A_FaceTarget
    VAMP G 6 A_CustomComboAttack("VampyrBall",34,random(1,10) * 4, "imp/melee")
	VAMP E 0 A_JumpIfInventory("BloodLustToken",1, "Missile2")
	Goto See
  Missile2:    
	VAMP D 1 A_FaceTarget
	VAMP H 6 {A_FaceTarget; A_PlaySound("vampyr/attack",4);}
	VAMP I 6 A_FaceTarget
    VAMP J 6 {A_CustomComboAttack("VampyrBall",34,random(1,10) * 4, "imp/melee"); A_TakeInventory("BloodLustToken",1);}
	Goto See 
  Pain:
    VAMP K 2
    VAMP K 2 A_Pain
    Goto See
  Pain.wepkick:
    VAMP K 2 
    VAMP K 50 A_Pain
    Goto See
  Death:
    VAMP L 8 A_Scream
    VAMP M 8 A_NoBlocking    
    VAMP NOP 6
    VAMP Q -1
    wait
  XDeath:
    VAMP R 5
    VAMP S 5 A_XScream
    VAMP T 5 A_NoBlocking
    VAMP UVWXYZ 5
    VAMP [ -1
    Stop
  Raise:
    VAMP PONML 7
    Goto See
  }
}

ACTOR VampyrBall
{
  Radius 6
  Height 12
  Speed 12
  FastSpeed 20
  Damage 4
  Projectile  
  RenderStyle ADD  
  SeeSound "vampyr/missile"
  DeathSound "vampyr/explode"
  Obituary "%o was smited by a Vampyr."
  +RANDOMIZE
  +SEEKERMISSILE
  States
  {
  Spawn:
    BAL8 ABCD 2 Bright A_SeekerMissile(1,2)
    Loop 
  Crash:	
  Death:    
    BAL8 EFGHIJ 3 Bright	
	Stop	
  XDeath:
    BAL8 E 3 Bright A_GiveToTarget("BloodLustToken",1)
    BAL8 FGHIJ 3 Bright	
    Stop
  }
}
//=============================END OF MONSTERS==================================

[Scuba Steve]

Awesome... I'm contemplating getting back into mapping and these interesting creatures would be a good fit for an idea of mine. I hate sounding entitled, but did you also have sfx picked out for the creatures or was that still a work in progress?

[Amuscaria]

Awesome... I'm contemplating getting back into mapping and these interesting creatures would be a good fit for an idea of mine. I hate sounding entitled, but did you also have sfx picked out for the creatures or was that still a work in progress?

I have sounds, but they were just ripped from other games from the 90s, like Half-Life and Shadow Warrior.

[Gez]

Captain J made a sound addon for Hell-Forged, so maybe he'd be willing to help with the SFX?

[Captain J]

If Amu says yes, then yes!