Weapons of Saturn

[Patriot1776]

I've been toying around with the tics-per-frame amounts at various points of the shotgun and pistol to make them a bit more faster firing in the November 22nd release. I'll post my changes tomorrow, as its 2 AM here. But mainly, they are meant to more allow one to use the pistol as a sort of backup to the assault rifle, you can fire the pistol, with rapid clicks, nearly as fast as the the assault rifle can fire full-auto, but may need to increase the bullet spread when shooting rapidly to give an incentive of accuracy to the assault rifle.

For the shotgun, with some of the tics-per-frame I've been dropping parts of the primary fire state down to, primary fire is starting to feel like a 'slam-fire' mode, and so if I post the code alterations that did that, it may also be worth trying to then increase how much your screen is jolted/tilted when firing in this possible 'slam-fire' mode. The merits of a slam-fire mode is that if you don't have the mini-gun or another rapid-fire weapon that packs a good punch and there's quite a few imps/zombies/lost souls blocking your path, you can go to the 'riot shotgun' and start slamfiring and drop them in a hurry when you can't afford to use the plasmagun/BFG and rockets/grenades are too dangerous or you don't have the rocket launcher, and the minigun/assault rifle can't get the job done fast enough. This would likely also require the double-barrel be beefed up a little in damage.

Now, as for some alt-fires, I think something that could be done for the minigun, without totally ripping off the idea of Brutal Doom's minigun, is that alt-fire could serve as a 'pre-windup' button, but with a twist: you hit altfire, you first hook a second belt of ammo to your current belt, up to 320 rounds. If you had a full belt of 160 rounds when you hit alt-fire, you attach a second belt of 160 rounds, if you have them in your inventory, to a maximum of 320 rounds. Minigun then spins up for you to lay carnage with the primary fire button. Next time you hit alt-fire, the minigun spins down. If you have less than 160 rounds of 'clip ammo' in the minigun, only an additional belt of 160 rounds are added to the minigun's 'clip' amount. I'm trying here to describe a minigun windup secondary that you still have to reload for occasionally, that you can't just keep shooting and shooting and shooting until all your ammo is depleted like you had an ammo belt that long for it. I do believe the minigun's ammo amounts need playing with. 600 rounds without backpack is too many, while 800 with backpack is too little. 400 rounds without backpack, 800 with, or 600 round without backpack, 1200 rounds with, would make more sense.

[Captain J]

For the minigun, why not have the secondary function continually spin the miniguns? For the BFG, perhaps you can have it function like the beta BFG where it shoots multiple plasma shots everywhere. For the Chainsaw, I'd always love to have a vertical slice attack. It would be slow but powerful.

now that's the idea.

[Lippeth]

I really like the chainsaw slice idea, I'll see what I can do.

Patriot1776, I'm excited to see your changes to the shotgun and pistol, and as for the minigun, I got so excited that I've already started to bring your idea to life, and will hopefully have that finished soon.

[Patriot1776]

As should happen when using this wind-up altfire on the minigun, the accuracy takes a hit, so the slower-firing primary mode will still have some merit. Also, if you hit alt-fire while your ammo belt still has more than 160 rounds, the minigun could probably spin up right away, no waiting to attach another 160 round belt. The idea is that if you have less than a full ammo belt ready, you're attaching the second belt to keep from running out and having to reload just seconds after spinning the thing up.

[Average]

Personally, I've enjoyed WOS recently. If I had to suggest secondary attacks I would suggest the chainsaw just had a 'swing' attack so that you can smack the baddies with the butt end of it - it would be a nice finishing move after hacking at them for a bit. I like the idea of plasma grenades from the plasma gun or even the BFG. There are no plasma grenades in any Doom mod that I know of. They could work a little like incendiary grenades. As for the minigun, I've never really been that happy with anyone's attempts at a secondary attack on that thing. Maybe instead of firing a number of bullets per round it could fire all 5 or 6 bullets in one 'blast' - no rotation just BOOM! then the barrell does one whole rotation to reload... I dunno.

[Captain J]

As for the minigun, I've never really been that happy with anyone's attempts at a secondary attack on that thing. Maybe instead of firing a number of bullets per round it could fire all 5 or 6 bullets in one 'blast' - no rotation just BOOM! then the barrell does one whole rotation to reload... I dunno.

unrealistic about fires whole 5~6 bullets in a one barrel like a shotgun, but i like that idea; make it rotate much faster than normal fire, and spit the hell outta the bullets like a GAU-8 avenger vulcan. also it could be a few shots or automatic. and i'm pretty sure it's the best way to controlling the whole crowd with wasting a ammo a lot.

oh, also did i mentioned about my opinion about BFG altfire?; spread plasma balls that bit stronger than slot 6 one like a super shotgun.

[LostSkull]

I like this

[Patriot1776]

Tweaked fire state for the Beretta pistol:

---

Code: Select all

Fire:
    TNT1 A 0 A_JumpIfInventory("9mm",1,1)
  Goto Reload
    TNT1 A 0 A_TakeInventory("9mm",1,TIF_NOTAKEINFINITE) 
	TNT1 A 0 A_SetPitch (pitch+0.2)
	TNT1 A 0 A_PlaySound("weapons/beretta/fire",CHAN_AUTO)
	BRTT B 0 A_GunFlash
	BRTT B 1 Bright A_FireBullets(5, 6, -1, 6, "BulletPuff2", 0)
	TNT1 A 0 A_SetPitch (pitch-0.2)
	BRTT C 1 A_AlertMonsters
	TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,8,0)
	TNT1 A 0 A_FireCustomMissile("9mmCasingSpawner",0,0,8,0)
	BRTT ED 1 
	BRTT B 1 A_WeaponReady
    Goto Ready

Key thing of note is that the tic duration of calling 'A_GunFlash' was reduced from 1 to 0. Doing this did a lot to make it more able to fire as fast as you can click, whereas having having a tic duration of 1 for the 'A_GunFlash' calling was basically wasting a whole tic. On the ZDoom wiki, the example given of A_GunFlash used in code has a tic duration of 0 as a full tic is not needed for A_GunFlash to do its job.

Widened the spread of the pistol to reflect how it is more inaccurate now with you being able to shoot it so fast, and so making it even more of a close-range only weapon. Also, it is now a semi-auto weapon, you have to click fast to shoot it because keeping A_Refire in combined with these changes turned it into a machine pistol! Not that I think a machine pistol is bad, Lippeth may just add one that can possibly be spawned next to backpacks, its just for this mod, too much of the challenge of pistol starting levels is taken out by the player having one to start with.

Now, tweaked Assault Rifle Fire and AimedFire code:

---

Code: Select all

Fire:
      TNT1 A 0 A_JumpIfInventory("Magazine",1,1)
      Goto Reload
	  TNT1 AAAA 0
	  TNT1 A 0 A_JumpIfInventory("ZoomIn",1,"AimedFire")
      TNT1 A 0 A_TakeInventory("Magazine",1,TIF_NOTAKEINFINITE)
      ASLT A 0 A_AlertMonsters
      ASLT A 0 A_PlaySound("weapons/rifle/fire", 7)
      ASLT A 0 A_GunFlash
      ASLT A 1 A_FireBullets(2,2,-1,6,"BulletPuff2",0)
	  ASLT A 0 A_SetPitch(pitch+0.1)
	  TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,8,0)
	  TNT1 A 0 A_FireCustomMissile("9mmCasingSpawner",0,0,6,-13)
      ASLT D 0 A_SetPitch(pitch-0.1)
	  ASLT D 1
	  ASLT B 1
	  ASLT A 1
      ASLT A 1 A_ReFire
      ASLT A 1 A_WeaponReady (1)
      Goto Ready
	AimedFire:
      TNT1 A 0 A_JumpIfInventory("Magazine",1,1)
      Goto Reload
      TNT1 A 0 A_TakeInventory("Magazine",1,TIF_NOTAKEINFINITE)
      IRON A 0 A_AlertMonsters
      IRFI A 0 A_PlaySound("weapons/rifle/fire", 7)
      IRFI A 1 bright A_FireBullets(1,1,-1,6,"BulletPuff2",0)
	  TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,8,0)
	  TNT1 A 0 A_FireCustomMissile("9mmCasingSpawner",0,0,6,0)
	  IRFI B 1
	  IRFI C 1
	  TNT1 AA 0 A_FireBullets(0,0,1,0,"LaserDot",FBF_NOFLASH|FBF_NORANDOMPUFFZ)
	  IRON AA 1
	  IRON A 1 A_Refire
	  IRON A 1 A_WeaponReady (1)
	  Goto Ready2

Again, eliminated a wasted tic by reducing the duration of the A_GunFlash frame from 1 tic to 0, as all A_GunFlash does is makes sure the player sprite is BRIGHT at the time the weapon is firing. This markedly improved the firing rate of the Assault Rifle, and so now, tightened up the bullet spread in both both normal and zoomed fire modes so that the Assault Rifle noticeably more accurate than the pistol when not aiming and MUCH more accurate obviously than the pistol when aiming. Because hey, Assault RIFLES were developed specifically to have the rapid fire of a sub-machine gun while retaining much of the accuracy of full-size battle rifles, so an Assault Rifle in a weapon mod needs to be noticeably accurate at range besides having a high rate of fire.

Still juking a bit with the tweaks that turns the primary fire mode of the shotgun/riot gun into a slam-fire mode.

[Lippeth]

I really like what you've done, but I want to keep them as is for several reasons. I give A_GunFlash an extra tic because there are two sprites used in the flash states, one small one, and a bigger one that happens when the bullets come out, so having an extra tic before it fires gives it more of a pop. I kept the assault rifle a bit slow because I don't want it to compete with the chaingun in usefulness. I really like the pistol but I'm torn between yours and mine. I'm typically pretty hard on mice due to a case of Tourette's syndrome, so anytime I can reduce the number of clicks on a mouse, the longer my third Cyborg R.A.T. 7 will live, but I don't mind you releasing your own version or patch to make it fire once per click. You have inspired me to experiment with a 3 round burst beretta, and now I don't know if I want to have it replace the pistol's primary fire after picking up a backpack, or make it a super rare drop at slot 9.

---

Code: Select all

ACTOR MachinePistol : Weapon
{
  Weapon.SelectionOrder 1900
  Weapon.AmmoType "Clip"
  Weapon.AmmoUse 1
  Weapon.AmmoGive 16
  Weapon.AmmoType2 "10mm"
  Weapon.AmmoUse2 1
  Weapon.SlotNumber 2
  Decal "none"
  AttackSound "none"
  Obituary "%o was shot to death by %k's machine pistol"
  Tag "Machine Pistol"
  Weapon.Kickback 60
  +WEAPON.WIMPY_WEAPON
  +WEAPON.NOALERT
  +WEAPON.AMMO_CHECKBOTH
  +WEAPON.ALT_AMMO_OPTIONAL
  +WEAPON.NOAUTOFIRE
  Inventory.Pickupmessage "Picked up a 10mm Auto!"
  States
  {
  Ready:
    BRTT B 0 A_JumpIfInventory("10mm",0,2)
    BRTT B 0 A_JumpIfInventory("Clip",1,2)
    BRTT B 1 A_WeaponReady //(WRF_NOSECONDARY)
    Loop
	BRTT B 1 A_WeaponReady(WRF_ALLOWRELOAD)
	Loop
	
  Select:
    BRTT B 1 A_Raise
    Loop
	
	  Deselect:
    BRTT B 1 A_Lower
    Loop
	
  Fire:
    TNT1 A 0 A_JumpIfInventory("10mm",1,1)
  Goto Reload
    TNT1 A 0 A_TakeInventory("10mm",1,TIF_NOTAKEINFINITE) 
	BRTT B 0 A_GunFlash
	TNT1 A 0 A_SetPitch (pitch+0.2)
	TNT1 A 0 A_PlaySound("weapons/beretta/altfire")
	BRTT B 1 Bright A_FireBullets(4, 4, -1, 8, "BulletPuff2", 0)
	BRTT C 1
	TNT1 A 0 A_PlaySound("weapons/beretta/altfire")
	TNT1 A 0 A_TakeInventory("10mm",1,TIF_NOTAKEINFINITE) 
	BRTT B 1 Bright A_FireBullets(4, 4, -1, 8, "BulletPuff2", 0)
	BRTT C 1
	TNT1 A 0 A_PlaySound("weapons/beretta/altfire")
	TNT1 A 0 A_TakeInventory("10mm",1,TIF_NOTAKEINFINITE) 
	BRTT B 1 Bright A_FireBullets(4, 4, -1, 8, "BulletPuff2", 0)
	BRTT C 1
	TNT1 A 0 A_SetPitch (pitch-0.2)
	BRTT C 2 A_AlertMonsters
	TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,8,0)
	TNT1 A 0 A_FireCustomMissile("9mmCasingSpawner",0,0,8,0)
	BRTT EED 1 
    //BRTT B 1 A_ReFire
    Goto Ready
	
  AltFire:
    TNT1 A 0
	Goto Kick
	
  Kick:
    TNT1 A 0 A_PlaySound("weapons/foot/swing")
    GKCK ABC 2
	BOOT D 2
	//TNT1 A 0 A_Recoil (-4)
	TNT1 A 0 A_TakeInventory("10mm",-1)
	TNT1 A 0 A_FireCustomMissile("PistolKick",0,0,0,0)
	TNT1 A 0 A_CustomPunch ((1+random(1,2)), 0 , 0 , "FootPuff",96)
	KICK E 1 A_Punch
	KICK F 1
	KICK G 2
	KICK E 1
	BOOT D 2
	GKCK CCBBA 1
	BRTT B 2
	Goto Ready
	
	
  Flash:
    BRTF A 1 Bright A_Light2
	TNT1 A 1
	BRTF A 1 Bright A_Light2
	TNT1 A 1
    BRTF B 1 Bright A_Light1
    Goto LightDone
	
  Reload:
    BRTT B 4 A_PlaySound("weapons/Handgun/slide")
	BRTT C 2
	
  ReloadShow:
    TNT1 A 0 A_JumpIfInventory ("10mm",1,"ReloadShow2")
	BRLD ABCDE 2
	BRLD F 6
	BRLD G 2
	Goto ReloadChamberCheck
	
  ReloadShow2:
	CHLD ABCDE 2
	CHLD F 6
	CHLD G 2
	Goto ReloadChamberCheck
	
  ReloadChamberCheck:
    TNT1 A 0 A_JumpIfInventory ("10mm",1,"ReloadLoop2")
    Goto ReloadLoop
	
  ReloadLoop:
    TNT1 A 0 A_GiveInventory("10mm")
    TNT1 A 0 A_TakeInventory("Clip",1,TIF_NOTAKEINFINITE)
    TNT1 A 0 A_JumpIfInventory("10mm",15,"ReloadEnd")
    TNT1 A 0 A_JumpIfInventory("Clip",1,"ReloadLoop")
      Goto ReloadEnd
	  
   ReloadLoop2:
    TNT1 A 0 A_GiveInventory("10mm")
    TNT1 A 0 A_TakeInventory("Clip",1,TIF_NOTAKEINFINITE)
    TNT1 A 0 A_JumpIfInventory("10mm",15,"ReloadEnd2")
    TNT1 A 0 A_JumpIfInventory("Clip",1,"ReloadLoop2")
     Goto ReloadEnd2
	  
  ReloadEnd:
	BRLD HHHIIJJKKKLL 1
	TNT1 A 0 A_PlaySound("weapons/beretta/snap")
	BRLD M 4
	BRLD N 3
	BRLD OPQ 2
  Goto Ready
  
  ReloadEnd2:
	CHLD HHHIIJJKKKLL 1
	BRLD M 4
	BRLD N 3
	BRLD OPQ 2
  Goto Ready
  }
}

ACTOR 10mm : Ammo
{
   +IGNORESKILL
   Inventory.MaxAmount 15
   Ammo.BackpackMaxAmount 15
}

I'm also still interested in this 'slam-fire' shotgun.

[Patriot1776]

Fair enough on keeping the pistol and assault rifle a little slower firing.

Now to the modded primary fire code for the riotgun that is now effectively a 'slam-firing' mode:

---

Code: Select all

   Fire:
      TNT1 A 0 A_JumpIfInventory("ShotgunReloading",1,"ReloadEnd")
      TNT1 A 0 A_JumpIfInventory("LoadedShell",1,1)
      Goto Reload
	  TNT1 AAAA 0
	  TNT1 A 0 A_JumpIfInventory("ZoomIn",1,"AimedFire")
      TNT1 A 0 A_TakeInventory("LoadedShell",1,TIF_NOTAKEINFINITE)
      BOOM A 0 A_AlertMonsters
	  BOOM Z 1
      TNT1 A 0 A_PlaySound("weapons/trenchgun/fire", CHAN_AUTO)
      TNT1 A 0 A_GunFlash
      BOOM Z 1 A_FireBullets(6,6,8,5,"BulletPuff",0)
      //TNT1 A 0 A_Recoil(0.6)
      BOOM Z 1 Offset (0,33)
	  TNT1 A 0 A_SetPitch(pitch+0.8)
	  BOOM Z 1 Offset (0,34)
	  TNT1 A 0 A_SetPitch(pitch-0.8)
	  BOOM KJ 1 Offset (0,32)
	  TNT1 AAAA 0 A_FireCustomMissile("GunSmokeSpawner",0,0,0,0)
	  TNT1 A 0 A_FireCustomMissile("SmokeSpawner",0,0,0,0)
      BOOM Z 4 //4 tics here instead of 8
      BOOM LI 1 //2 tics here total instead of 4
	  TNT1 A 0 A_FireCustomMissile("GunSmokeSpawner",0,0,8,0)
      BOOM I 2 Offset(0,34) A_FireCustomMissile("ShotgunCasingSpawner",0,0,8,-20)
	  BOOM I 1 Offset(0,36)
	  BOOM I 1 Offset(0,34)
      BOOM A 3 Offset(0,32)
      BOOM A 1 A_ReFire
	  BOOM A 1 A_WeaponReady(1)
      Goto Ready

The primary of the riotgun like this, when you hold the fire button, you are shooting it very much as seen in this video here: http://www.youtube.com/watch?v=sLk9xBoyJA8 This allows, if you've not found the double barrel yet, to 'grind down' larger baddies with the riotgun that normally you would be going right for the double barrel for, for when you don't have the double barrel or better yet or don't have the ammo for the minigun or better, but plenty of shells. However, the double barrel is still a tad faster, and with the riotgun you still gotta run and hide to reload or switch weapons after you've fired all 9 shots from it, while the double barrel still doesn't suffer from that.

[FlynnTaggart777]

Aw dang it, I don't mean to bump this year-old thread. But I have to ask the author for permission to release a modification of his modification.

What's in my modification you may ask?

Well, I replaced the ugly plasma rifle in the mod with the original plasma rifle from the Brutal19Weapons/Beautiful DOOM weapons for Brutal DOOM mod.

Also, I changed the rifle sound effect with my custom pulse rifle sound effect which I made in Audacity by combining the pulse rifle sound fx from Aliens TC/Aliens Trilogy mod for DOOM.

Another thing, is that I made the pistol left handed (the right-handed kind of bothered me). I also added the sound effect from Army of Darkness TC pistol.

I am going to replace the Chainsaw with the original Chainsaw today except instead of yellow body it's red. I haven't exactly gotten the resources for it yet and I've posted a thread in resources requesting a red bodied original Chainsaw that is centered.

Do not worry everybody. I will give credit where credit is due. Namely, I have included a WOSCredits text file that gives credits to Lippeth, Beautiful DOOM for Brutal DOOM wad makers, Aliens TC, PSX DOOM TC, and Army of Darkness TC for sound fx and sprites.

The Plasma Rifle and BFG9000 are coming from Beautiful DOOM for Brutal DOOM wad.

The sound FX come from Aliens TC, PSX DOOM TC, and Army of Darkness TC respectively. I haven't finished my modification to your mod yet, but when I do... I will probably send it to somebody who's willing to upload it. Why you ask? Because I don't know how to upload it.

Though one thing I'd like to add, but I'm not sure how. Is there a way to get the vanilla shotgun into this? I kind of liked the vanilla shotgun and super shotgun but I don't know how to implement them. I have SLADE 3 and I'd like to know. Thanks.

If you want me to release my modification of your mod let me know. If not, then tell me now. I am asking for permission and also I've given credits where credit is due... so umm... yeah. Great mod by the way!

[Ed the Bat]

You could (and should) have just sent him a PM.

[FlynnTaggart777]

Oh, sorry. I probably should have just sent him a PM. Should I just copy and paste my post as a PM to him and delete my post?

[wildweasel]

It's a little late to delete your post now, since someone's already replied to it. I'll elect to just leave this here.

[Lippeth]

But I have to ask the author for permission to release a modification of his modification

I'm flattered that you like the mod well enough to use it as a base for your own work, but after reading what you intend to change it sounds like you want to revert it back into vanilla doom which seems a bit counterintuitive. That being said, you have permission to release a mod of WOS or use any resources from it as long as you credit the original authors. By the way, I changed the color of Doom's chainsaw and posted it in your thread. I hope it helps.