[WIP] Unheil - A Wolfenstein inspired conversion

[Lippeth]

If you took the time to fix my errors, I would be indebted to you.

I'll still continue to work on making the weapons function better, but I'd rather continue with mapping, which has been halted due to weapon reload problems.

[Tapwave]

Real is brown-
But it looks very atmospheric, nice job!

[Ed the Bat]

I'd be happy to help shore up these weapons. Now, the question is, what style to go for. There are a few different schools of how reloading systems should work.

You can have the reload take ammo out of the main pool (eg., I have 100 bullets and an empy magazine for my MP40, I reload it, then I have 30 in the MP40 and 70 bullets in my ammo pool), which may be ideal if you have several different weapons with a common ammo.

Or, you can have the ammo pool include the count in the weapon magazine (I have 100 bullets, I reload, and I have 30 in my mag but my ammo pool still says 100 and will count down as I shoot), which I use a lot in my own projects, but I'd personally only recommend it if every weapon had separate ammo types.

There might be other methods, but I'm kinda drawing a blank right now. Anyway, I'll work based on whatever your favored method is, since different approaches would need to be written differently.

[Lippeth]

Personally, I don't mind using the same ammo for pistols, chainguns, and rifles because it makes it way easier to map not worrying if I have enough of EVERY ammo type lying around, so I like your first method. I've actually tried doing the MP40 like that, and while it will take 30 bullets and leave the main ammo pool at 70, if I only have 85 bullets, it will load 30 into the gun, but only leave me with 50 bullets in the main pool, losing five bullets in the process. Furthermore, if I am out of ammo, I can still load 30 bullets into the gun. It's been a real mess.

Basically this is my ideal result: Pistol, MP40, Kar98k and minigun should all use "clip" ammo

MP40 and Kar98k should reload how you first described, as well as switch to the next best weapon in inventory when out of ammo

Shotgun (or Trenchgun as labeled in the pk3 file) should be interruptible after loading two shells when pressing fire, but instead of going directly to the fire state, I'd like it to jump to the reload end animation and then fire. The reason for this is that realistically, if you load a shell into an empty shotgun and fire, nothing happens. You need to cock the gun first to set the shell behind the firing pin. I know this is a game and real-world rules only apply half the time, but I'm particularly adamant about a shotgun that cocks before firing if interrupting the reload state.

The shotgun should also switch to the next best weapon when empty. I hate dry-fire states, but if that's the only way, then I'll live.

If you actually decide to help fix even just one of the guns, I'll be eternally grateful and not ever hesitate to help you with whatever I can in the future!

[Ed the Bat]

Give these a try, and see how well they suit your tastes.

---

Code: Select all

ACTOR MP40 : Weapon replaces Chainsaw
{
	Inventory.PickupMessage "Picked up an MP40"
	Inventory.PickupSound "weapon/mp40"
	Obituary "%o was gunned down by %k's MP40."
	Weapon.SelectionOrder 750
	Weapon.AmmoType "Clip"
	Weapon.AmmoUse 1
	Weapon.AmmoGive 30
	Weapon.AmmoType2 "MP40Ammo"
	Weapon.AmmoUse2 1
	Weapon.SlotNumber 4
	AttackSound "None"
	Decal "BulletChip"
	+WEAPON.NOALERT
	+WEAPON.AMMO_CHECKBOTH
	States
	{
	Spawn:
		MPIC A -1
		Stop
	Ready:
		MPGN D 2 A_PlayWeaponSound("weapons/MP40/cock")
		MPGN E 1
		MP4C A 2
		MP4C B 3
		MP4C CD 2
		MP4C E 3
		MPGN E 3
		MPGN DG 2
		Goto ReallyReady
	ReallyReady:
		TNT1 A 0 A_JumpIfInventory("MP40Ammo",0,2)	//Mag is full? Disable reloading
		TNT1 A 0 A_JumpIfInventory("Clip",1,2)		//Got bullets to load? Allow it
		MPGN C 1 A_WeaponReady
		Loop
		MPGN C 1 A_WeaponReady(WRF_ALLOWRELOAD)
		Loop
	Select:
		MPGN F 1 A_Raise
		Loop
	Deselect:
		MPGN F 1 A_Lower
		Loop
	Fire:
		TNT1 A 0 A_JumpIfInventory("MP40Ammo",1,1)
		Goto Reload
		TNT1 A 0 A_TakeInventory("MP40Ammo",1,TIF_NOTAKEINFINITE)
		MPGN C 1 A_AlertMonsters
		MPGN A 2 A_GunFlash
		MPGN B 0 A_SetPitch(pitch+0.3)
		MPGN B 0 A_PlaySound("weapons/MP40/fire")
		MPGN B 2 A_FireBullets(6,4,1,7.5,"BulletPuff",0)
		MPGN C 1 Offset(0,36) A_SetPitch(pitch-0.3)
		TNT1 A 0 A_ReFire
		MPGN F 4 A_WeaponReady
		Goto ReallyReady
	Flash:
		MP4F A 1 BRIGHT A_Light2
		MP4F B 1 BRIGHT A_Light2
		TNT1 A 1 A_Light1
		Stop
	Reload:
		MPGN DE 3
		TNT1 A 0 A_PlayWeaponSound("weapons/MP40/reload")
		MP4R ABCDE 2
		MP4R FFFFF 2
		MP4R EDCBA 3
	ReloadLoop:
		TNT1 A 0 A_GiveInventory("MP40Ammo")
		TNT1 A 0 A_TakeInventory("Clip",1,TIF_NOTAKEINFINITE)
		TNT1 A 0 A_JumpIfInventory("MP40Ammo",0,"ReloadEnd")
		TNT1 A 0 A_JumpIfInventory("Clip",1,"ReloadLoop")
		Goto ReloadEnd
	ReloadEnd:
		TNT1 A 0 A_PlayWeaponSound("weapons/MP40/cock")
		MP4C A 2
		MP4C B 3
		MP4C CD 2
		MP4C E 3
		MPGN E 3
		MPGN D 2
		MPGN G 2
		Goto ReallyReady
	}
}

ACTOR MP40Ammo : Ammo
{
	+IGNORESKILL
	Inventory.MaxAmount 30
}

---

Code: Select all

ACTOR Kar98k : Weapon replaces SuperShotgun
{
	Inventory.PickupMessage "Picked up a Mauser Kar98k"
	Inventory.PickupSound "weapon/mp40"
	Obituary "%o was gunned down by %k's Mauser."
	Weapon.SelectionOrder 740
	Weapon.AmmoType "Clip"
	Weapon.AmmoUse 1
	Weapon.AmmoGive 8
	Weapon.AmmoType2 "Rounds"
	//Weapon.AmmoGive2 1
	Weapon.AmmoUse2 1
	Weapon.SlotNumber 3
	AttackSound "None"
	Decal "BulletChip"
	+WEAPON.NOALERT
	+WEAPON.AMMO_CHECKBOTH
	States
	{
	Spawn:
		MAUS A -1
		Stop
	Ready:
		TNT1 A 0 A_PlayWeaponSound("weapons/mauser/cock")
		KAR9 C 2
		KAR9 D 4
		KAR9 E 1
		KAR9 F 6
		KAR9 G 15
		KAR9 F 6
		KAR9 E 1
		KAR9 D 4
		KAR9 C 1
		KAR9 A 5
		Goto ReallyReady
	ReallyReady:
		KAR9 A 0 A_JumpIfInventory("Rounds",0,2)	//Mag is full? Disable reloading
		KAR9 A 0 A_JumpIfInventory("Clip",1,2)		//Got bullets to load? Allow it
		KAR9 A 1 A_WeaponReady
		Loop
		KAR9 A 1 A_WeaponReady(WRF_ALLOWRELOAD)
		Loop
	Select:
		KAR9 D 1 A_Raise
		Loop
	Deselect:
		KAR9 A 1 A_Lower
		Loop
	Fire:
		TNT1 A 0 A_JumpIfInventory("Rounds",1,1)
		Goto Reload
		TNT1 A 0 A_TakeInventory("Rounds",1,TIF_NOTAKEINFINITE)
		KAR9 A 2 A_AlertMonsters
		TNT1 A 0 A_GunFlash
		KAR9 A 0 A_SetPitch (pitch+0.3)
		KAR9 A 0 A_PlaySound ("weapons/mauser/fire")
		KAR9 B 2 A_FireBullets(0, 0, 10, 8, "BulletPuff",0)
		KAR9 A 2 A_SetPitch (pitch-0.3)
		KAR9 A 6
		KAR9 C 1
		KAR9 D 5
		KAR9 E 1
		KAR9 F 5
		KAR9 G 10
		KAR9 F 5
		KAR9 E 1
		KAR9 D 4
		KAR9 C 1
		KAR9 A 3
		KAR9 A 1 A_Refire
		Goto ReallyReady
	Flash:
		KARF ABC 1 BRIGHT A_Light2
		TNT1 A 1 A_Light1
		Stop
	Reload:
		KAR9 C 2 A_PlayWeaponSound("weapons/mauser/open")
		KAR9 D 4
		KAR9 E 1
		KAR9 F 6
		KAR9 G 5
		KARR A 8
		KARR B 3
	ReloadLoop:
		TNT1 A 0 A_GiveInventory("Rounds")
		TNT1 A 0 A_TakeInventory("Clip",1,TIF_NOTAKEINFINITE)
		TNT1 A 0 A_JumpIfInventory("Rounds",0,"ReloadEnd")
		TNT1 A 0 A_JumpIfInventory("Clip",1,"ReloadLoop")
		Goto ReloadEnd
	ReloadEnd:
		KARR C 5 A_PlayWeaponSound("weapons/mauser/insert")
		KARR D 4
		KARR E 6
		KARR FG 5
		KARR H 5 A_PlayWeaponSound("weapons/mauser/shut")
		KARR I 3
		KARR J 2
		KAR9 FE 1
		KAR9 D 4
		KAR9 C 1
		KAR9 A 5
		Goto ReallyReady
	}
}

ACTOR Rounds : Ammo
{
	+IGNORESKILL
	Inventory.MaxAmount 5
}

---

Code: Select all

ACTOR Trenchgun : Weapon replaces Shotgun
{
	Weapon.SelectionOrder 1300
	Weapon.AmmoType "Shell"
	Weapon.AmmoUse 1
	Weapon.AmmoGive 8
	Weapon.AmmoType2 "LoadedShell"
	Weapon.AmmoUse2 1
	Weapon.AmmoGive2 0
	Weapon.SlotNumber 3
	Decal "BulletChip"
	AttackSound "none"
	Inventory.PickupMessage "Picked up a trenchgun"
	Obituary "%o was blasted by %k's trenchgun"
	+WEAPON.NOALERT
	+WEAPON.AMMO_CHECKBOTH
	States
	{
	Ready:
		TNT1 A 0 A_PlayWeaponSound("weapons/trenchgun/cock")
		BOOM EF 4
		BOOM G 3
		BOOM FE 4
		BOOM A 2
		Goto ReallyReady
	ReallyReady:
		BOOM A 0 A_JumpIfInventory("LoadedShell",0,2)	//Mag is full? Disable reloading
		BOOM A 0 A_JumpIfInventory("Shell",1,2)			//Got shells to load? Allow it
		BOOM A 1 A_WeaponReady
		Loop
		BOOM A 1 A_WeaponReady(WRF_ALLOWRELOAD)
		Loop
	Deselect:
		BOOM A 1 A_Lower
		Loop
	Select:
		BOOM A 1 A_Raise
		Loop
	Fire:
		TNT1 A 0 A_JumpIfInventory("LoadedShell",1,1)
		Goto Reload
		TNT1 A 0 A_TakeInventory("LoadedShell",1,TIF_NOTAKEINFINITE)
		BOOM A 3 A_AlertMonsters
		TNT1 A 0 A_PlaySound("weapons/trenchgun/fire")
		TNT1 A 0 A_SetPitch(pitch+0.6)
		TNT1 A 0 A_GunFlash
		BOOM A 1 A_FireBullets(5.5,3,6,8,"BulletPuff",0)
		TNT1 A 0 A_SetPitch(pitch-0.6)
		TNT1 A 0 A_Recoil(0.6)
		BOOM KJK 2
		BOOM A 8
		BOOM LI 1
		BOOM I 3 Offset(0,33)
		BOOM A 2 Offset(0,32)
		BOOM A 1 A_ReFire
		Goto ReallyReady
	Flash:
		BOOF A 2 Bright A_Light1
		BOOF B 1 Bright A_Light2
		Goto LightDone
	//Tap Reload key (or dry-fire the gun) to load a single shell
	//Hold reload to keep reloading until finished or until key is released
	Reload:
		TNT1 A 0 A_PlayWeaponSound("weapons/trenchgun/load")
		TNT1 A 0 A_TakeInventory("Shell",1)
		TNT1 A 0 A_GiveInventory("LoadedShell",1)
		BOMR ABC 2
		BOMR DEFG 1
		BOMR H 1 //A_WeaponReady(WRF_NOBOB)
		TNT1 A 0 A_JumpIfInventory("LoadedShell",0,"ReloadEnd")
		TNT1 A 0 A_JumpIfInventory("Shell",1,1)
		Goto ReloadEnd
		CSHT A 0 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH|WRF_ALLOWRELOAD)
	ReloadEnd:
		TNT1 A 0 A_PlayWeaponSound("weapons/trenchgun/cock")
		BOOM EF 5
		BOOM G 4
		BOOM FE 5
		BOOM A 3 A_WeaponReady(WRF_NOFIRE)
		TNT1 A 0 A_ReFire
		Goto ReallyReady
	Spawn:
		SHOT A -1
		Stop
	}
}

ACTOR LoadedShell : Ammo
{
	+IGNORESKILL
	Inventory.MaxAmount 5
}

[Woolie Wool]

While this project shows promise, it is very rough and needs a lot of work. Here are some suggestions to make it better:

* Important thing when designing DECORATE weapons: All of them should handle reloading the same way. So if one weapon has a reloading system with a dual ammo count, like the Mauser or the shotgun, all of them should have that system.
* This project is badly in need of a new status bar with the treasure contributing to a score counter. You could make your own, import one from a Wolfenstein mod, or even use this one: http://www.3drealms.com/rott/images/origin28.gif
* The trench shotgun might as well be removed with the Mauser 98k taking its place, as the Mauser is a weapon the German army actually used. In addition, the Mauser should use its own ammo type rather than use the pistol bullets, and fire one really big bullet instead of four weaker ones (and remember that a real Mauser 98k holds 5 rounds, not 8).
* The MP40 fire rate could be increased (the speed of Doom's chaingun is about right for the MP40) and its damage slightly reduced to make it more accurate and more fun to use.
* Is this supposed to be set during WWII, or after? Are there supposed to be monsters as well as Nazis or are the Revenants just placeholders? If it is supposedly set in WWII, you should get rid of all the modern-looking textures (e.g. TLITE6_4) and replace them with more historically suitable alternatives.

[Ed the Bat]

* Important thing when designing DECORATE weapons: All of them should handle reloading the same way. So if one weapon has a reloading system with a dual ammo count, like the Mauser or the shotgun, all of them should have that system.

I'm inclined to agree. The pistol probably ought to have a reload system like the rest of the guns. You may be able to squeak past this one on the minigun and say it's fed by a continuous belt, but it probably wouldn't hurt to add reloading to this one too.

* This project is badly in need of a new status bar...

I agree, and I especially think the HUD for this project ought to include the in-mag ammo counts for these weapons, to give users a better heads-up of what he's got available.

* Are there supposed to be monsters as well as Nazis or are the Revenants just placeholders?

I was wondering the same thing. Revenants, Imps, and Mancubi seem rather out of place among the Nazis, unless you explicitly wanted to incorporate some type of occult/hell angle into this.

[Lippeth]

Ed the Bat, you just fixed every weapon problem I had, and improved them past my expectations! Thank you a million!

As for why there are Doom monsters in this mod, I explain this in the text file as part of "the story so far". Basically you take the role of Doomguy who stepped through the wrong portal on Phobos ending up in an alternate universe, and at the very end I say, "You also begin to wonder if you were the only one who set foot through that portal..."
If they still just seem out of place, I can look for solutions, and am open to suggestions as to what should take their place.

The HUD....I didn't ever think about that. The fullscreen HUD uses the treasure icons to show how you use each one, but other than that, I agree it needs a revamp.

I'm perfectly okay with the minigun not reloading, as it chews through ammo faster than lightning, so holding down fire too long is met with the 'punishment' of no more ammo, and the pistol is replaced by other weapons pretty quickly. BUT, I can work on reloading animations for weapon consistency.

The Kar98k is made to take the place of the SSG, but if you guys want it to take the place of the shotgun, that's totally fine.

Thanks, everyone for the amazing feedback, and sorry for the unfinished second map. I'll continue with this project and hopefully have at least a beta with several maps by this fall. Anyone and everyone is invited to contribute, and you'll be credited (with consent) as being part of the Unheil team. Unless there's a better name. Then you'll be part of "Whatever this project is called" team.

[Woolie Wool]

Weapons for a TC do not need to take anything's place; the weapon set should be self-contained. Their relation to Doom's weapons is irrelevant.

[Lippeth]

I guess all I mean is that the Mauser is more powerful than the trench gun and takes more time to reload, isn't drop-able by enemies and it literally overrides the SSG in the decorate file. I always considered this a partial conversion anyway, but the more it goes along the more I change. So I think we're both right. Or I'm just confused.

I may increase the rate of fire for the MP40, but I want it to stay consistent with the SS rate of fire, and I don't want the enemies to shoot so fast that the player doesn't have a chance. I will still play with seeing how far I can push it before it gets silly.

EDIT: I increased the rate of fire, and it's more fun like you said, thanks

Also, the download link is updated to the new changes, same file name for now. It's not so much a new version as it is a less broken one.

[Woolie Wool]

The player will have just as much of a chance if you decrease the damage of enemy MP40 shots to compensate for the increased rate of fire.

[Lippeth]

The player will have just as much of a chance if you decrease the damage of enemy MP40 shots to compensate for the increased rate of fire.

Enemy fire damage was already at a 1, but increasing the rate of fire for both player and enemies keeps the challenge consistent by making it easier and more difficult at the same time. I decreased player MP40 damage from 7 to 6, and you can still mow them down in a timely manner before taking too much damage, if at all if you're careful.

You've also got me thinking more about the Doom monsters. I want to either try and replace them with more Nazis, or find a whole new enemy type, or if nothing else reskin the revenants and give them Panzerfausts.

[Lippeth]

So any non SS enemy is now gone. Thanks to Woolie Wool for all the great input. The next step is to add soldiers who carry rifles along side the trench gunners, as well as Panzerfaust soldiers. This will require some tedious sprite work, but will hopefully be worth it. Outright replacing shotgun enemies with riflemen slows down the action too much, and the trench gun is just fun.

UPDATED LINK

[Peter Bark]

Blood & Wolfenstein 3D mix? interesting.

[Mav3rick]

hey like it very nice change

But why i do need to constantly be clicking the reload buttom to add shells to the shotgun :/ it make it hard to move and be doing it many times
And every time i switch weapons they do the cocking animation? all the time i need to make a quick change i get my ass kicked for waiting that animation with the guns.
Oh why a dog need 2 shotgun hits to die?? hell dog?

very good mod keep the good work