Help with DECORATE?

[Warhawk]

I'm trying to combine 2 types weapons into one using A_GiveInventory. Without the inventory, it'll fire a projectile. When Alt-fire is pressed, the weapon will "check" the inventory and will "give" inventory: "Expander Mode" meaning the weapon has changed to a hit-scanner. Then when Alt-fire is pressed again, it'll "check" and "take" the inventory and it'll return to projectile attack. But I'm stuck and cofused at the Alt-Fire state when it "gives","takes", and "checks" inventory. Help please? Thanks.

---

ACTOR Shrinker/ExpanderGun : Weapon
{
Inventory.PickupMessage "You got the Shrinker/Expander!"
Weapon.AmmoType1 "ShrinkerAmmo"
Weapon.AmmoType2 "ExpanderAmmo"
Weapon.AmmoGive1 10
Weapon.AmmoGive2 20
Weapon.AmmoUse1 0
Weapon.AmmoUse2 0
States
{
Spawn:
SHEX A -1
Stop
Ready:
SHRG A 0 A_JumpIfInventory("ExpanderMode",1,2)
SHRG ABCD 5 Bright A_WeaponReady
Goto Ready+3
EXPG ABCD 5 Bright A_WeaponReady
Goto Ready+3
Deselect:
SHRG A 0 A_JumpIfInventory("ExpanderMode",1,2)
SHRG R 1 A_Lower
Loop
EXPG A 1 A_Lower
Loop
Select:
SHRG A 0 A_JumpIfInventory("ExpanderMode",1,2)
SHRG R 1 A_Raise
Loop
EXPG A 1 A_Raise
Loop
Fire:
SHRG E 0 A_JumpIfInventory("ExpanderMode",1,6)
SHRG E 0 A_GunFlash
SHRG E 0 A_PlaySound ("shrinker/shoot")
SHRG E 7 A_FireCustomMissile("ShrinkerAttack" 0, 0, 0, 0)
SHRG E 0 A_TakeInventory("ShrinkerAmmo",1)
SHRG F 8
SHRG G 7
SHRG H
Goto Ready
EXPG E 0 A_GunFlash
EXPG E 0 A_TakeInventory("ExpanderAmmo",1)
EXPG E 1 A_FireBullets(2.6, 2.6, 1, 17, "ExpanderPuff")
EXPG F 1 A_ReFire
EXPG G 1
EXPG H 1
Goto Ready
AltFire:
SHRG A 0 A_JumpIfInventory("ExpanderMode",1,1)
SHRG A 1
SHRG A 0 A_TakeInventory("ExpanderMode")
SHRG A 1
SHRG A 0 A_GiveInventory("ExpanderMode",1)
Goto Ready
Flash:
SHRF A 0 A_JumpIfInventory("ExpanderMode",1,3)
SHRF A 1 Bright
SHRF B 1 Bright
Stop
EXPF A 1 Bright
EXPF B 1 Bright
Stop
}
}

ACTOR ExpanderMode : Inventory
{
Inventory.Amount 1
Inventory.MaxAmount 1
}

[Blue Shadow]

Try this...

Code: Select all

  AltFire:
    SHRG A 0 A_JumpIfInventory("ExpanderMode", 1, 2)
    SHRG A 1 A_GiveInventory("ExpanderMode", 1)
    Goto Ready
    SHRG A 1 A_TakeInventory("ExpanderMode", 1)
    Goto Ready

[Matt]

Code: Select all

  AltFire:
    SHRG A 0 A_JumpIfInventory("ExpanderMode", 1, "RemoveExpanderModeFlag")
    SHRG A 0 A_GiveInventory("ExpanderMode", 1)
    SHRG A 0 A_Refire
    Goto Ready
  RemoveExpanderModeFlag:
    SHRG A 0 A_TakeInventory("ExpanderMode", 1)
    SHRG A 0 A_Refire
    Goto Ready
  AltHold:
    SHRG A 1 A_WeaponReady(WRF_NOFIRE)
    SHRG A 0 A_Refire
    Goto Ready

That way you won't have to perfectly time your altfire press to get the result you want.