Monster attack that shortly freezes player?

[Tormentor667]

Can something like that be done?

[.+:icytux:+.]

Can something like that be done?

give the player a inventory item that executes a script that does SetPlayerProperty on the activator. and give the property PROP_TOTALLYFROZEN, Delay(35*6); or whatever you like then call SetPlayerProperty once more to deactivate it.

[Zhs2]

Perhaps a temporary item that calls a color change on the player's HUD, as well?

[Macil]

Make a new player actor that has a custom pain state which freezes the player. You might have to call an ACS script inside the pain state to do exactly what you want.

[.+:icytux:+.]

Make a new player actor that has a custom pain state which freezes the player. You might have to call an ACS script inside the pain state to do exactly what you want.

sounds like a better solution if you could freeze the player without acs.

[Tormentor667]

I tried it but without any success... anyone able to give me a working example?

[CaptainToenail]

The creeper stun balls from GvH and the Tazer from 007 Goldeneye TC both do this

[Tormentor667]

The GvH scripts are only the as compiled versions and I don't have the 007 TC, links someone?

[XutaWoo]

The GvH scripts are only the as compiled versions

Have you tried looking at the GLOBAL script that's in the main dictionary, not the scripts dictionary?

[Tormentor667]

Yes, now I did but it doesn't seem to work for me... here is what Cutmanmike wrote for the Marine class:

Code: Select all

Pain.Creepstun:
PLAY G 0 A_Pain
PLAY G 18 ACS_ExecuteAlways(986,0)
Goto Spawn

...and the correspdonding script looks like this:

Code: Select all

script 986 (void) // Creeper stun blast effect
{
SetPlayerProperty (0, 1, 0);
fadeto(255, 255, 255, 0.03, 0.0);
Delay(48);
fadeto(255, 255, 255, 0.0, 0.0);
SetPlayerProperty (0, 0, 0);
}

If I put that up exactly the way Cutman did this in my own project, it doesn't work. I get the "fadeto" screen change but I do not get any change in terms of my movement.

[Tormentor667]

Ah.. now I know why, I have this second script running:

Code: Select all

//Stop moving while aiming
script 800 ENTER
{
  int buttons;
  while (TRUE)
  {
    buttons = GetPlayerInput(-1, INPUT_BUTTONS);
    if (buttons & BT_ALTATTACK)
    {
      	GiveInventory("PlayerFreezer", 1);
      	SetPlayerProperty(0,1,PROP_FROZEN);
    }
    else
    {
    	TakeInventory("PlayerFreezer", 99999999);
    	SetPlayerProperty(0,0,PROP_FROZEN);
    }
    delay(1);
  }
}

Now, how to combine both?

[Tormentor667]

Hm... tried it and it seems to be impossible... but what about spawning a dummy sector directly into the player that stops its movement for a while? Has something like that already been tried?

*EDIT*
Hah, that actually works ^^

[Chris]

Try something like this:

Code: Select all

int freezecount;

//Stop moving while aiming
script 800 ENTER
{
  int buttons, lastbuttons;
  while (TRUE)
  {
    lastbuttons = buttons;
    buttons = GetPlayerInput(-1, INPUT_BUTTONS);
    if ((buttons & BT_ALTATTACK) && !(lastbuttons&BT_ALTATTACK))
    {
         GiveInventory("PlayerFreezer", 1);
         SetPlayerProperty(0,1,PROP_FROZEN);
         freezecount++;
    }
    else if(!(buttons & BT_ALTATTACK) && (lastbuttons&BT_ALTATTACK))
    {
       TakeInventory("PlayerFreezer", 99999999);
       freezecount--;
       if(freezecount == 0)
          SetPlayerProperty(0,0,PROP_FROZEN);
    }
    delay(1);
  }
}

script 986 (void) // Creeper stun blast effect
{
   SetPlayerProperty (0, 1, 0);
   freezecount++;
   fadeto(255, 255, 255, 0.03, 0.0);

   Delay(48);

   fadeto(255, 255, 255, 0.0, 0.0);
   freezecount--;
   if(freezecount == 0)
      SetPlayerProperty (0, 0, 0);
}

[Tormentor667]

Look above, I already found a much easier method But thanks though for your help