ProjectileKickback?

[whirledtsar]

Anybody have experience using this actor property? I just cant get it to have any effect. Tried putting it on the weapon, tried putting it on the projectile fired by said weapon, tried setting it to an extreme value (20000), nothing makes the projectile actually push enemies back. Using GZDoom 4.1.

[Void Weaver]

In regular cases this property doesn't work only if damage of source projectile\puff is 0 OR its impact target have 0 momentum (if externally stopped for ex.). It also stacks with natural damage thrusting.
Looks that all works correctly:

Code: Select all

Actor PushPistol : Pistol replaces Pistol
{
Weapon.SelectionOrder 1900
Weapon.SlotNumber 2
Weapon.SlotPriority 1
States
{
Fire:
PISG A 4
PISG B 6 A_FireBullets(5.6,0,1,0,"BulletPuff",FBF_USEAMMO|FBF_NORANDOM|FBF_NORANDOMPUFFZ,8192,"PistolBall",0)
PISG B 0 A_PlaySound("weapons/pistol",0)
PISG B 0 A_GunFlash
PISG C 4
PISG B 5 A_ReFire
Goto Ready
}
}

Actor PistolBall : DoomImpBall
{
//Damage 1 //Will work
Damage(1)
//Damage(0) //Wouldn't work
+HITTRACER
ProjectileKickBack 10000
States
{
Death:
//TNT1 A 0 A_GiveInventory("Stoper",1,AAPTR_TRACER) //BUT! If its imact target (projectile's TRACER in this case) will get this item, then property wouldn't work too!
Goto Super::Death
}
}

Actor Stoper : CustomInventory
{
+INVENTORY.ALWAYSPICKUP
Inventory.MaxAmount 0
States
{
Pickup:
TNT1 A 0 A_Stop
Stop
}
}

[whirledtsar]

In regular cases this property doesn't work only if damage of source projectile\puff is 0 OR its impact target have 0 momentum (if externally stopped for ex.). It also stacks with natural damage thrusting.
Looks that all works correctly:

So youre saying it only works if the damage isnt zero and the projectile doesnt stop things on impact? Because my projectile does damage and doesn't stop things, and projectilekickback still does absolutely nothing. Setting Weapon.Kickback on the weapon that fires it also does nothing.

[Void Weaver]

AFAIK, that is. Mainly restrictions of this property are source's zero damage and possibility to stop movenent on impact.

That's odd. Do you have tried the my example? Is it doesn't work too? Because I tested it on 3.7.0 and 4.1.3 and it works as intended.

[Blue Shadow]

Because my projectile does damage and doesn't stop things, and projectilekickback still does absolutely nothing. Setting Weapon.Kickback on the weapon that fires it also does nothing.

Could you upload something that demonstrates the problem so someone can figure out what's wrong?

[whirledtsar]

Could you upload something that demonstrates the problem so someone can figure out what's wrong?

Sure. Its not really MY weapon btw, I was trying to alter a weapon from the Serpent Arsenal mod for Hexen.

---

https://mega.nz/#!8WB2zYKQ!Tj4fWFHS6XAu ... vDHVQ3OTqs

Code: Select all

ACTOR FWeapSpear : FighterWeapon replaces FWeaponPiece3
{
  Weapon.SelectionOrder 1000
  +WEAPON.AXEBLOOD
  +WEAPON.AMMO_OPTIONAL
  +WEAPON.MELEEWEAPON
  Weapon.AmmoUse1 5
  Weapon.SlotNumber 2
  Weapon.AmmoGive1 25
  Weapon.YAdjust -12
  Weapon.AmmoType1 "Mana1"
  Weapon.Kickback 10000
  ProjectileKickback 10000
  Inventory.PickupMessage "$TXT_WEAPON_F5"
  Tag "$TAG_FWEAPSPEAR"

  States
  {
  Spawn:
    JSPR Z -1 Bright
    Stop
  Select:
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "SelectGlow")
    JSPR A 1 A_Raise
    Loop
  Deselect:
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "DeselectGlow")
    JSPR A 1 A_Lower
    Loop
  Ready:
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "ReadyGlow")
    JSPR A 1 A_WeaponReady
    Loop
  Fire:
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "FireGlow")
    JSPR E 4 
    JSPR F 4 
    JSPR G 3
	JSPR H 2 A_PlayWeaponSound("FighterHammerMiss")
    JSPR I 2  A_FireCustomMissile("FSpearFX1",0,false,8,16)
    JSPR JKLM 2 
    TNT1 A 16
	JSPR A 3 Offset(0,92)
	JSPR A 3 Offset(0,72)
	JSPR A 3 Offset(0,52)
    Goto Ready
  SelectGlow:
    JSPR B 1 Bright A_Raise
    Goto Select
  DeselectGlow:
    JSPR B 1 Bright A_Lower
    Goto Deselect
  ReadyGlow:
    JSPR BCDC 5 Bright A_WeaponReady
	JSPR B 0 A_JumpIfInventory("Mana1", 3, "ReadyGlow")
    Goto Ready
  FireGlow:
    JSPR N 4 
    JSPR O 4 
    JSPR P 3 
	JSPR Q 2 A_PlayWeaponSound("FighterHammerMiss")
    JSPR I 2  A_FireCustomMissile("FSpearFX2",0,true,8,16)
    JSPR JKLM 2 
    TNT1 A 16
	JSPR A 0 A_JumpIfInventory("Mana1", 3, 4)
	JSPR A 3 Offset(0,92)
	JSPR A 3 Offset(0,72)
	JSPR A 3 Offset(0,52)
    Goto Ready
	JSPR A 3 Offset(0,92)
	JSPR D 3 Offset(0,72)
	JSPR C 3 Offset(0,52)
    Goto Ready
  }
}

ACTOR FSpearFX1
{
  Speed 50
  Radius 6
  Height 6
  Damage 10
  Projectile
  ProjectileKickback 10000
  DeathSound "weapons/spearhit"
  Obituary "$OB_MPFWEAPSPEAR"
  States
  {
  Spawn:
    JSPR R 1 A_SpawnItemEx("FSpearFX3",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    Loop
  Death:
    TNT1 A 2
    Stop
  }
}


ACTOR FSpearFX2
{
  Speed 90
  Radius 4
  Height 6
  Damage 35
  Projectile
  ProjectileKickback 10000
  DeathSound "weapons/spearhit"
  Obituary "$OB_MPFWEAPSPEAR"
  States
  {
  Spawn:
    JSPR S 1 Bright A_SpawnItemEx("FSpearFX4",0,0,0,0,0,0,0,SXF_NOCHECKPOSITION)
    Loop
  Death:
    TNT1 AAAAAAAAA 0 A_SpawnItemEx("FSpearFX5",0,0,2,frandom(-4,4),frandom(-4,4),random(-2,6),0,SXF_NOCHECKPOSITION)
    Stop
  }
}

[Void Weaver]

Your ProjectileKickback works absolutelly correct, but for some reason ProjectileKickback property doesn't work in Hexen game. o_0
Probably that's a bug.

[Blue Shadow]

All Hexen player classes have the [wiki=Actor_flags#NODAMAGETHRUST]NODAMAGETHRUST[/wiki] flag set. That's why damage kickback is completely ignored in that case.

[Void Weaver]

Wow, thank you for explanation!

So easiest solution is to turn off this flag when the weapon selected and turn it back when de-selected.

Code: Select all

  Select:
    JSPR A 0 A_ChangeFlag("NODAMAGETHRUST",0)
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "SelectGlow")
    JSPR A 1 A_Raise
    Goto Select+2
  SelectGlow:
    JSPR B 1 Bright A_Raise
    Loop
  Deselect:
    JSPR A 0 A_ChangeFlag("NODAMAGETHRUST",1)
    JSPR A 0 A_JumpIfInventory("Mana1", 3, "DeselectGlow")
    JSPR A 1 A_Lower
    Goto Deselect+2
  DeselectGlow:
    JSPR B 1 Bright A_Lower
    Loop

[whirledtsar]

Thanks for the help guys, now I can get it working properly.

[Protozoare]

I was wondering, is there a way to reverse projectile kickback, and make the hit monsters be knocked towards the player?