[SOLVED][ZSCRIPT] Monster Stuck With Custom Chase Function

[Kan3x]

Hello guys.

I was trying to have a custom "chasing" function for a monster.
What I wanted to achieve is a monster moving away from its target when it's too close, but with specific escaping routes and the possibility to attack like it was in a normal chasing (this is why I completely put aside the easy way of just using the FRIGHTENED flag and call it a day).
I got the "avoid the target" and "avoid obstacles" done, working pretty well too, but then I tested the creature with normal steps... and it broke.

Basically, what happens is that the monster doesn't get block by the step like an actual obstacle, but he won't move forward anymore and won't climb the step, but only if the total height of the steps to climb exceeds the standard Doom monster limit of 24... even though the monster MaxStepHeight is 32... I even tried raising it up to 64, but this behavior didn't change.
Not to mention that if the monster target gets closer, sometimes the monster will climb up the steps...

To me even weirder, is when the monster tries to go downstairs instead, because in this case it will recognize the "stepping down" as an obstacle and just avoid it like a wall etc.

This is the code I'm using:

---

Code: Select all

state A_DistantChase(double maxRange, double minRange, StateLabel meleeState, StateLabel standState, StateLabel altMissile) {
		if(target) {
			if(Default.bDROPOFF && !bDROPOFF) {
				bDROPOFF = true;
			}
			if(Distance3D(target) >= maxRange || !CheckLOF(CLOFF_SKIPOBSTACLES)) {
				A_Chase();
			}
			else if(Distance3D(target) >= minRange) {
				return FindState(standState);
			}
			else {
				if(bDROPOFF) {
					bDROPOFF = false;
				}
				double lMul = sqrt(2);
				if(angle % 90 == 0) {
					lMul = 1.0;
				}
				Vector2 vecF = Vec2Angle(Speed*lMul, angle);
				Vector2 vecL = Vec2Angle(Speed*sqrt(2)/lMul, angle + 45);
				Vector2 vecR = Vec2Angle(Speed*sqrt(2)/lMul, angle - 45);
				bool obsCheckF = CheckMove(vecF, PCM_DROPOFF);
				bool obsCheckL = CheckMove(vecL, PCM_DROPOFF);
				bool obsCheckR = CheckMove(vecR, PCM_DROPOFF);
				int turnAng = 0;
				int maxTAng = 135;
				double dAng = deltaangle(angle, AngleTo(target));
				if(!obsCheckF) {
					A_Log("OH SHIT A WALL");
					if(obsCheckL || obsCheckR) {
						if(dAng >= 0) {
							if(obsCheckR) {
								A_Log("TURN RIGHT");
								turnAng = 45;
							}
							else {
								A_Log("OH SHIT RIGHT WALL");
								turnAng = -45;
								A_Log("TURN LEFT THEN");
							}
						}
						else {
							if(obsCheckL) {
								A_Log("TURN LEFT");
								turnAng = -45;
							}
							else {
								A_Log("OH SHIT LEFT WALL");
								turnAng = 45;
								A_Log("TURN RIGHT THEN");
							}
						}
					}
					else {
						A_Log("SHIT I'M STUCK!");
						if(dAng < 0) {
							for(int al = -45; al >= -180; al -= 45) {
								A_LogInt(al);
								obsCheckF = CheckMove(Vec2Angle(Speed * 4, angle-al), PCM_DROPOFF);
								if(obsCheckF) {
									turnAng = al;
									A_Log("WHATEVER GO LEFT");
									break;
								}
							}
						}
						else {
							for(int ar = 45; ar <= 180; ar += 45) {
								obsCheckF = CheckMove(Vec2Angle(Speed * 4, angle-ar), PCM_DROPOFF);
								A_LogInt(ar);
								if(obsCheckF) {
									turnAng = ar;
									A_Log("WHATEVER GO RIGHT");
									break;
								}
							}
						}
					}
				}
				else {
					A_Log("NO WALL ON SIGHT");
					if(!obsCheckL || !obsCheckR) {
						maxTAng = 45;
					}
					if(abs(dAng) < maxTAng) {
						if(dAng < 0) {
							if(obsCheckL) turnAng = -45;
							else {
								if(obsCheckR) turnAng = 45;
								else turnAng = -45;
							}
						}
						else {
							if(obsCheckR) turnAng = 45;
							else {
								if(obsCheckL) turnAng = -45;
								else turnAng = 45;
							}
						}
					}
				}
				movedir = ((angle - turnAng) / 45) % 8;
				if(movedir > 7) movedir -= 8;
				else if(movedir < 0) movedir += 8;
				A_SetAngle(movedir*45);
				//A_Chase(meleeState, altMissile, CHF_NORANDOMTURN);
				//TryMove(vecF, 2);
				TryWalk();
			}
		}
		return null;
	}

I tried different moving functions, but nothing really change except with TryMove, but I'm getting some jittering results for some reason.

I wonder if there's some hardcoded stuff within CheckMove(), because I'm clueless about this behavior.

This is the monster class:

---

Code: Select all

Class WarrensBase : Actor
{
	int steps;
	Default
	{
		//$Category Monsters
		MaxStepHeight 64;
		BloodColor "Dark Red";
		Monster;
		+FORCEXYBILLBOARD
		+JUMPDOWN
		+FLOORCLIP
		+DROPOFF
	}
}

Class TheUnclean : WarrensBase
{  
	Default
	{
		Health 1200;
		Radius 48;
		Height 64;
		Mass 2000;
		Speed 8;
		PainChance 96;
		PainChance "Acid", 4;
		PainChance "Silver", 16;
		PainChance "Fire", 16;
		DamageFactor "Poison", 0.0;
		DamageFactor "Disease", 0.25;
		DamageFactor "Acid", 0.25;
		DamageFactor "Silver", 0.5;
		DamageFactor "Bludge", 1.25;
		DamageFactor "Pierce", 0.75;
		+BOSS
		+LOOKALLAROUND
		SeeSound "unclean/sight";
		PainSound "unclean/pain";
		DeathSound "unclean/death";
		ActiveSound "unclean/active";
		HitObituary "%o was smuthered by The Unclean.";
		Species "Resistant";
		Tag "The Unclean";
	}
	States
	{
	Spawn:
	Idle:
		TOAD AABB 3 {
			//A_Wander();
			A_LookEx(fov: 180);
		}
		Loop;
	See:
		TOAD AABBCCDDEEFF 2 A_DistantChase(1000, 900, null, "Stand", null);
		Loop;
		[...]

I'd like to know if what I'm trying to do is possible without having to rewrite the zdoom chasing functions, otherwise I'll just surrender and use the FRIGHTENED flag T_T

[Kan3x]

Interesting enough, I guess, if I replace CheckMove() with TryMove() it "almost" works, but the guy is having a lot of jittering while moving D:
Any help on this? I'm totally stuck T_T like the monster...

[7Soul]

I coded my own chase function too and the way I fixed the TryMove jitteriness was to use variables to track the direction and distance the monster wants to move, then use those values to move the monster in its Tick() function. So for example if the monster wants to move 8 units and its animation frame lasts 4 frames, it'll move 2 unit per tick 4 times, so it moves as smoothly as possible

This is a function that calculates the distance from the current position to the position the enemy wants to get to (nextPos) and sets the variables. You call this instead of TryMove
animSpeed is the length of the walk animation, you pass that value when you call it. This makes so the monster's position changes faster or slower depending on the animation speed

Code: Select all

void SetWalkSteps(vector2 nextPos, int animSpeed){
	vector2 a = (nextPos - pos.xy);
	double dist = floor(Sqrt( (a.x * a.x) + (a.y * a.y)) + 0.1) ;

	walkDirection = Angle;
	walkDist = abs(dist / animSpeed);
	walkSteps = animSpeed;
}

Enemy variables:

Code: Select all

int walkDirection;
int walkSteps;
double walkDist;

And this goes into Tick():

Code: Select all

if (walkDist > 0 && walkSteps > 0) 
	TryMove(pos.xy + AngleToVector(walkDirection, walkDist), 1);
walkSteps = max(walkSteps - 1, 0);

Hope this helps

[Kan3x]

I coded my own chase function too and the way I fixed the TryMove jitteriness was to use variables to track the direction and distance the monster wants to move, then use those values to move the monster in its Tick() function. So for example if the monster wants to move 8 units and its animation frame lasts 4 frames, it'll move 2 unit per tick 4 times, so it moves as smoothly as possible

This is a function that calculates the distance from the current position to the position the enemy wants to get to (nextPos) and sets the variables. You call this instead of TryMove
animSpeed is the length of the walk animation, you pass that value when you call it. This makes so the monster's position changes faster or slower depending on the animation speed

Code: Select all

void SetWalkSteps(vector2 nextPos, int animSpeed){
	vector2 a = (nextPos - pos.xy);
	double dist = floor(Sqrt( (a.x * a.x) + (a.y * a.y)) + 0.1) ;

	walkDirection = Angle;
	walkDist = abs(dist / animSpeed);
	walkSteps = animSpeed;
}

Enemy variables:

Code: Select all

int walkDirection;
int walkSteps;
double walkDist;

And this goes into Tick():

Code: Select all

if (walkDist > 0 && walkSteps > 0) 
	TryMove(pos.xy + AngleToVector(walkDirection, walkDist), 1);
walkSteps = max(walkSteps - 1, 0);

Hope this helps

Thanks for the help!
This is quite an interesting route and it actually solved the "step up" issue! (I still can't understand the "magic" behind it, why do I need to take this detour?)
Although it cannot get rid of the "step down" one D: Because that's caused directly by the CheckMove() (or TryMove()) checks for obstacles that will always detect a "step down" bigger than the common 24 units as a wall, no matter the MaxStepHeight the monster has.

[Kan3x]

Ok, I finally found a solution to apparently every glitch that I had.
The major issue, which was the monster not being able to go upstairs, despite the MaxStepHeight property value being big, and downstairs has been solved by the use of the MaxDropOffHeight property
(which still doesn't really makes too much sense for the step up to me, I clearly understand the step down, of course, but to go up I should only need the Step height, or am I missing something?)

For the rest being a bit buggy, now I made some tweaks here and there and the function works just wonderfully fine:

---

Code: Select all

state A_DistantChase(double maxRange, double minRange, StateLabel meleeState, StateLabel standState, StateLabel altMissile, StateLabel idleState) {
		if(target && target.Health > 0) {
			if(Distance3D(target) >= maxRange || !CheckLOF(CLOFF_SKIPOBSTACLES)) {
				A_Chase();
			}
			else if(Distance3D(target) >= minRange) {
				return FindState(standState);
			}
			else {
				Vector2 vecF = Vec2Angle(Speed, angle);
				bool obsCheckF = CheckMove(vecF, PCM_DROPOFF);
				bool obsCheckL;
				bool obsCheckR;
				bool stuck;
				int turnAng = 0;
				int maxTAng = 135;
				double dAng = deltaangle(angle, AngleTo(target));
				if(!obsCheckF) { //can't move forward
					A_Log("OH SHIT A WALL");
					maxTAng = 90;
					obsCheckL = CheckMove(Vec2Angle(Speed, angle + 90), PCM_DROPOFF);
					obsCheckR = CheckMove(Vec2Angle(Speed, angle - 90), PCM_DROPOFF);
					if(obsCheckL || obsCheckR) { //can go left or right
						if(dAng >= 0) { //target to the left
							if(obsCheckR) { //can go right
								A_Log("TURN RIGHT");
								turnAng = -45;
							}
							else { //can't go right
								A_Log("OH SHIT RIGHT WALL");
								turnAng = 45;
								A_Log("TURN LEFT THEN");
							}
						}
						else { //target to the right
							if(obsCheckL) { //can go left
								A_Log("TURN LEFT");
								turnAng = 45;
							}
							else { //can't go left
								A_Log("OH SHIT LEFT WALL");
								turnAng = -45;
								A_Log("TURN RIGHT THEN");
							}
						}
					}
					else { //can't go left nor right
						A_Log("SHIT I'M STUCK!");
						for(int t = 45; t <= 180; t += 45) {
							if(dAng >= 0) { //target to the left
								obsCheckF = CheckMove(Vec2Angle(Speed, angle - t), PCM_DROPOFF);
								if(obsCheckF) {
									turnAng = -t; //go right
									break;
								}
								else if(t > 180) { //no way out
									stuck = true;
								}
							}
							else { //target to the right
								obsCheckF = CheckMove(Vec2Angle(Speed, angle + t), PCM_DROPOFF);
								if(obsCheckF) {
									turnAng = t; //go left
									break;
								}
								else if(t > 180) {  //no way out
									stuck = true;
								}
							}
						}
					}
				}
				else {
					A_Log("NO WALL ON SIGHT");
					bool right = true;
					bool left = true;
					bool back = true;
					for(int w = 90; w <= 270; w += 90) {
						obsCheckF = CheckMove(Vec2Angle(Radius, angle + w), PCM_DROPOFF);
						if(!obsCheckF) { //can't go left or right
							maxTAng = 45;
							if(w < 180) left = false;
							else if(w == 180) back = false;
							else right = false;
						}
					}
					if(!right && !left && !back) { turnAng = 0; A_Log("CAN ONLY GO FORWARD"); }//can't go right, nor left, nor back
					else if(abs(dAng) < maxTAng) { //target inside maximum turning angle
						if(dAng < 0) { //target to the right
							if(left) turnAng = 45; //go left
							else {
								if(right) turnAng = -45; //go right
								else turnAng = 90; //go back
							}
						}
						else { //target to the left
							if(right) turnAng = -45; //go right
							else {
								if(left) turnAng = 45; //go left
								else turnAng = -90; //go back
							}
						}
					}
				}
				if(!stuck) {
					movedir = ((angle + turnAng) / 45) % 8;
					if(movedir > 7) movedir -= 8;
					else if(movedir < 0) movedir += 8;
					A_SetAngle(movedir*45);
					A_Chase(meleeState, altMissile, CHF_NORANDOMTURN);
				}
				else {
					A_FaceTarget();
				}
			}
		}
		else {
			return FindState(idleState);
		}
		return null;
	}

I'll leave it here for anyone that wants to use it