Custom Episode and Skill Menu

[22alpha22]

For my project I have different episodes that need different skills depending on which episode is chosen. In addition, I would like to add additional skills than can be unlocked for an episode after it has been completed, NewGame+ style. The new skills would only be accessible from the skill menu once the chosen episode had been completed once.

I thought this would all be fairly trivial to implement with MENUDEF and a few global CVars to track episode progress but it seems that the functionality of both the episode and skill menus are hardcoded. After some research, it seems the episode and skill menu functionality isn't even exposed to ZScript. As such, I've spent more hours than I care to admit, trying to learn ZScript menus and replace the episode and skill menus entirely. I mostly failed but rather than giving up, I've come up with a hacky workaround for my issues. Rather than create a new skill menu from scratch, I've repurposed the existing menu and did my best to disable the undesired existing functionality.

First I wanted different skill choices depending on the episode chosen but I couldn't find access to any variable that held the selected episode. The SetMenu param variable is set to the chosen episode during the episode menu but where it is stored upon moving to the skill menu, I have no idea. I worked around this by creating a new CVar and overriding the MenuEvent and setting the new episode CVar to the chosen episode. Seems somewhat hacky but at least the skill menu will be able access the CVar and retrieve what episode was chosen.

Even with being able to retrieve the chosen episode in the skill menu, it was going to be very tricky to implement different skill choices because of the hardcoded skill selection functionality. I came up with a even more hacky workaround; I removed the rendering of all skill options by override the Drawer function and added all possible skill options as static text via MENUDEF. I aligned the static text skills with where the skill options would normally be so that I wouldn't have to mess with the cursor's location. I used the drawer function to filter the static skills by episode, and override MenuEvent to override the normal skill selection and instead start new game with whatever skill is chosen filtered by episode.

All together it is a hacky solution but it does work, still I'm sure there must be a better way to do this, surely? I haven't even implemented my NewGame+ skills yet, but it shouldn't be to hard to tack them on to this system if I don't find a better solution. Does anyone have any experience with this? Is this the best I can do or is there a cleaner way to implement this?

MENUDEF:

---

Code: Select all

//////////////////////////////////////////////
///////////////////Menu Def///////////////////
//////////////////////////////////////////////

///////////////////Episode Selection//////////

ListMenu "EpisodeMenu"
{
	NetgameMessage "$NEWGAME"
	Position 48, 63
	StaticPatch 54, 38, "M_EPISOD", 0 , "$MNU_EPISODE"
	LineSpacing 16
	Class "EpisodeMenu"
}

///////////////////Skill Selection////////////

ListMenu "SkillMenu"
{
	StaticPatch 96, 9, "M_NEWG", 0, "$MNU_NEWGAME"
	LineSpacing 16
	StaticPatch 54, 33, "M_SKILL", 0, "$MNU_CHOOSESKILL"
	Position 48, 58
	Class "SkillMenu"
	StaticText 48, 58, "Very Easy"
	StaticText 48, 76, "Easy"
	StaticText 48, 94, "Normal"
	StaticText 48, 112, "Heroic"
	StaticText 48, 130, "Legendary"
	StaticText 48, 148, "Epic"
	StaticText 48, 166, "Nightmare!"               //NewGame+ Skills
	StaticText 48, 184, "Ultra-Nightmare!"       //Not yet implemented
	StaticPatch 48, 58, "M_JKILL", 0, "$SKILL_BABY"                //Alternate episode skills
	StaticPatch 48, 76, "M_ROUGH", 0, "$SKILL_EASY"             //Only available in the 'vanilla' episodes
	StaticPatch 48, 94, "M_HURT", 0, "$SKILL_NORMAL"
	StaticPatch 48, 112, "M_ULTRA", 0, "$SKILL_HARD"
	StaticPatch 48, 130, "M_NMARE", 0, "$SKILL_NIGHTMARE"
}

ZScript:

---

Code: Select all

//////////////////////////////////////////////
///////////////////Menu///////////////////////
//////////////////////////////////////////////

///////////////////Episode Menu///////////////

Class EpisodeMenu : ListMenu
{
	Override Bool MenuEvent(Int MKey, Bool FromController)
	{
		Switch (MKey)
		{
			Default:
			{
				Return Super.MenuEvent(MKey,FromController);
			}
			Case MKEY_Enter:
			{
				If (MDesc.MSelectedItem >= 0)
				{
					MenuSound("Menu/Advance");
				}

				If (MDesc.MSelectedItem == 1) //|| MDesc.MSelectedItem == 2)  Additional episodes can easily be added here
				{
					CVar.FindCVar('Episode').SetInt(MDesc.MSelectedItem - 1);
					MDesc.MItems[MDesc.mSelectedItem].Activate();
					//Close();
					//Menu.SetMenu("SkillMenu",MDesc.MSelectedItem - 1);
				}
				Else
				{
					CVar.FindCVar('Episode').SetInt(-1);
					MDesc.MItems[MDesc.mSelectedItem].Activate();
				}

				Return True;
			}
		}
	}
}

///////////////////Skill Menu/////////////////

Class SkillMenu : ListMenu
{
	Override Void Drawer(Void)
	{
		If (Self == GetCurrentMenu() && BackbuttonAlpha > 0 && M_Show_backbutton >= 0 && M_Use_Mouse)
		{
			Let Tex = TexMan.CheckForTexture(Gameinfo.MBackButton,TexMan.Type_MiscPatch);

			If (Tex.IsValid())
			{
				Vector2 V = TexMan.GetScaledSize(Tex);
				Int W = Int(V.X + 0.5) * CleanXFac;
				Int H = Int(V.Y + 0.5) * CleanYFac;
				Int X = (!(M_Show_backbutton & 1)) ? 0 : Screen.GetWidth() - W;
				Int Y = (!(M_Show_backbutton & 2)) ? 0 : Screen.GetHeight() - H;

				If (MBackbuttonSelected && (MMouseCapture || M_Use_Mouse == 1))
				{
					Screen.DrawTexture(Tex,True,X,Y,DTA_CleanNoMove,True,DTA_ColorOverlay,Color(40,255,255,255),DTA_NOOFFSET,True);
				}
				Else
				{
					Screen.DrawTexture(Tex,True,X,Y,DTA_CleanNoMove,True,DTA_Alpha,BackbuttonAlpha,DTA_NOOFFSET,True);
				}
			}
		}

		If (MDesc.MItems.Size() >= 2)
		{
			MDesc.MItems[0].Draw(False,MDesc);
			MDesc.MItems[1].Draw(False,MDesc);
		}

		Int Episode = CVar.FindCVar('Episode').GetInt();

		If (Episode != -1)  //If the episode isn't a 'vanilla' episode, draw the new skills instead
		{
			MDesc.MItems[2].Draw(False,MDesc);
			MDesc.MItems[3].Draw(False,MDesc);
			MDesc.MItems[4].Draw(False,MDesc);
			MDesc.MItems[5].Draw(False,MDesc);
			MDesc.MItems[6].Draw(False,MDesc);
			MDesc.MItems[7].Draw(False,MDesc);

		}
		Else  //Draw the 'vanilla' skills
		{
			MDesc.MItems[10].Draw(False,MDesc);
			MDesc.MItems[11].Draw(False,MDesc);
			MDesc.MItems[12].Draw(False,MDesc);
			MDesc.MItems[13].Draw(False,MDesc);
			MDesc.MItems[14].Draw(False,MDesc);
		}

		If (MDesc.MSelectedItem >= 15 && MDesc.MSelectedItem < MDesc.MItems.Size())
		{
			If (!MenuDelegate.DrawSelector(MDesc))
			{
				MDesc.MItems[MDesc.MSelectedItem].DrawSelector(MDesc.MSelectOfsX,MDesc.MSelectOfsY,MDesc.MSelector,MDesc);
			}
		}
	}

	Override Bool MenuEvent (Int MKey, Bool FromController)
	{
		Int OldSelect = MDesc.MSelectedItem;
		Int StartedAt = Max(0,MDesc.MSelectedItem);
		Int Episode = CVar.FindCVar('Episode').GetInt();
		Int Skill;

		Switch (MKey)
		{
			Case MKEY_Up:
			{
				If (Episode != -1)  //Use the new skill list, currently includes 6 skills
				{
					Do
					{
						If (--MDesc.MSelectedItem < 0)
						{
							MDesc.MSelectedItem = MDesc.MItems.Size() - 1;
						}
					}

					While (!MDesc.MItems[MDesc.MSelectedItem].Selectable() && MDesc.MSelectedItem != StartedAt);

					If (MDesc.MSelectedItem == StartedAt)
					{
						MDesc.MSelectedItem = OldSelect;
					}
				}
				Else  //Use the vanilla skill list, only 5 skills
				{
					Do
					{
						If (--MDesc.MSelectedItem < 0)
						{
							MDesc.MSelectedItem = MDesc.MItems.Size() - 2;
						}
					}

					While (!MDesc.MItems[MDesc.MSelectedItem].Selectable() && MDesc.MSelectedItem != StartedAt);

					If (MDesc.MSelectedItem == StartedAt)
					{
						MDesc.MSelectedItem = OldSelect;
					}
				}

				MenuSound("Menu/Cursor");

				Return True;
			}
			Case MKEY_Down:
			{
				If (Episode != -1)
				{
					Do
					{
						If (++MDesc.MSelectedItem >= MDesc.MItems.Size())
						{
							MDesc.MSelectedItem = 0;
						}
					}

					While (!MDesc.MItems[MDesc.MSelectedItem].Selectable() && MDesc.MSelectedItem != StartedAt);

					If (MDesc.MSelectedItem == StartedAt)
					{
						MDesc.MSelectedItem = OldSelect;
					}
				}
				Else
				{
					Do
					{
						If (++MDesc.MSelectedItem >= MDesc.MItems.Size() - 1)
						{
							MDesc.MSelectedItem = 0;
						}
					}

					While (!MDesc.MItems[MDesc.MSelectedItem].Selectable() && MDesc.MSelectedItem != StartedAt);

					If (MDesc.MSelectedItem == StartedAt)
					{
						MDesc.MSelectedItem = OldSelect;
					}
				}

				MenuSound("Menu/Cursor");

				Return True;
			}
			Case MKEY_Enter:
			{
				If (Episode != -1)  //If not a 'vanilla' episode
				{
					Skill = MDesc.MSelectedItem - 15; //All possible skills are available because we listed them manually in MENUDEF, therefore we need to compensate for that to ensure the correct skill is actually chosen
				}
				Else  //Vanilla episode
				{
					Skill = MDesc.MSelectedItem - 7;  //Again, compensating because of all the skills being available, ensure the correct skill is chosen for the episode
				}

				If (MDesc.MSelectedItem >= 0)
				{
					MenuSound("Menu/Advance");
					Close();
					SetMenu("Startgame",Skill);  //Start a new game and set the skill manually
				}

				Return True;
			}
			Default:
			{
				Return Super.MenuEvent(MKey,FromController);
			}
		}
	}
}

[Sir Robin]

I'm not sure how to do it in the menus, but have you considered creating a 3d episode / skill selection map? Then you could easily do it how ever you wanted

[Dan_The_Noob]

for NG+, you might be better off just offering the option at the end of the episode and have it jump back to MAP01 or whatever the start of episode is...else maybe consider making a hub map to jump to after episodes.