Making custom weapons deplete ammo and make bullet hole decals

[genospizza]

EDIT: After using the solution in the replies, I was still having the decal issue. I've solved it now, so here's the fix for future Googlers:
Create a file in the root of your mod called "decaldef.txt". In there you can add a definition that looks like this:

Code: Select all

generator TestWeapon BulletChip

Replace "TestWeapon" with the name of your weapon class name. "BulletChip" is the default bullet hole texture, but if you unpack gzdoom.pk3 you can view the whole list of decals and choose a different one.

ORIGINAL POST:

Hi there. I've been learning ZScript for a bit, and this is the first problem I've come across that I couldn't solve by looking in the docs or tutorials.

I'm trying to define a custom weapon that inherits from the Pistol class and mimics it precisely, so I can modify it. But I think I may be putting it in the player's inventory the wrong way. When I run the script below, the gun that I get doesn't deplete ammo when I fire it. It also doesn't make bullet hole decals or smoke particles. It does still damage enemies.

The TestWeapon definition:

---

Code: Select all

class TestWeapon: Pistol {
  Default {
    Weapon.SelectionOrder 1900;
    Weapon.AmmoUse 1;
    Weapon.AmmoGive 20;
    Weapon.AmmoType "Clip";
    Obituary "$OB_MPPISTOL";
    +WEAPON.WIMPY_WEAPON
    Inventory.Pickupmessage "$PICKUP_PISTOL_DROPPED";
    Tag "$TAG_PISTOL";
  }
  States {
    Ready:
      PISG A 1 A_WeaponReady;
      Loop;
    Deselect:
      PISG A 1 A_Lower;
      Loop;
    Select:
      PISG A 1 A_Raise;
      Loop;
    Fire:
      PISG A 4;
      PISG B 6 A_FirePistol;
      PISG C 4;
      PISG B 5 A_ReFire;
      Goto Ready;
    Flash:
      PISF A 3 Bright A_Light1;
      Goto LightDone;
    Spawn:
      PIST A -1;
      Stop;
  }
}

The way I'm giving it to the player (ItemTestHandler is registered in mapinfo.txt):

---

Code: Select all

class ItemTestHandler: EventHandler {
  override void WorldThingSpawned(WorldEvent e) {
    If(e.thing is "PlayerPawn" && !e.thing.FindInventory("ItemTest")) {
      e.thing.GiveInventory("ItemTest", 1);
    }
  }
}

class ItemTest: Inventory {
  override void DoEffect() {
    super.DoEffect();
    if(owner) {
      ClearInventory();
      owner.GiveInventory("TestWeapon", 1);
    }
  }
}

Other things I've noticed: even if I change the owner.GiveInventory line to give the player "Pistol" instead of "TestWeapon", it causes the weapon to not deplete ammo. I'm guessing this is just entirely the wrong way to give a player a weapon. Any idea what's causing the ammo depletion and bullet decal problems?

[Jarewill]

It should deplete ammo, however every tic the player is given another copy that gives them 20 more bullets from the ItemTest item.
Why not just give the player the weapon directly in the event handler instead?
Or you could create a new player class as well.

[genospizza]

Yeah, I just realized I was woefully misusing that inventory class. I adapted that from a similar example, but I think that was removing and not adding a weapon. The ammo immediately maxing out should have tipped me off. Thanks for the help!

[genospizza]

I was still having the bullet decal issue, but I solved it now. Edited the OP with the solution.

[wildweasel]

Another thing you can do, regarding decals, is assign them directly from the weapon, without needing a Decaldef file:

Code: Select all

Decal "BulletChip";

Just throw that into the Default block on your new weapon actor.