Weapon sprint animation state/script?

[body_cleaner666]

Good day, everyone. I'm a newbie in this modding, and at one day I got an idea to add to all my guns sprint animation when player holds shift button (and when moving), but I have no clue how to realize this feature. How I can do this? And if possible, will it work only for Decorate type?

[body_cleaner666]

Uh, excuse me, somebody here? I just really need some help here, please!

[Caligari87]

Do not bump or double-post. If someone is able and willing to help you, they will.

It may help to post an example of your existing weapon code.

[Alfred Don]

Good day, everyone. I'm a newbie in this modding, and at one day I got an idea to add to all my guns sprint animation when player holds shift button (and when moving), but I have no clue how to realize this feature. How I can do this? And if possible, will it work only for Decorate type?

You could check the player's momentum with the decorate variables and jump to another state.

[Jarewill]

You can also use GetPlayerInput for this:
A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED,"SprintState")

[body_cleaner666]

You can also use GetPlayerInput for this:
A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED,"SprintState")

Thank you, but how I can make when player not moves (but still can hold shift button), animation/different gun position won't animate?

And for everyone, thank you for remarks and sorry for double-post.. and if something wrong will go, I'll post my weapon code here.

[openroadracer]

Thank you, but how I can make when player not moves (but still can hold shift button), animation/different gun position won't animate?

And for everyone, thank you for remarks and sorry for double-post.. and if something wrong will go, I'll post my weapon code here.

I have no coding knowledge whatsoever, but I'd say that you'd need to run two checks, one after the other. Put the input check first; then, if it comes back "true", go to the velocity check; if it comes back with a high enough speed, it changes the animation state of the weapon.

[body_cleaner666]

Thank you, but how I can make when player not moves (but still can hold shift button), animation/different gun position won't animate?

And for everyone, thank you for remarks and sorry for double-post.. and if something wrong will go, I'll post my weapon code here.

I have no coding knowledge whatsoever, but I'd say that you'd need to run two checks, one after the other. Put the input check first; then, if it comes back "true", go to the velocity check; if it comes back with a high enough speed, it changes the animation state of the weapon.

Got the idea with states, but don't know how to make the second speed state check for playing animation...

[Jarewill]

You can access the player's velocity with velx and vely expressions.
Untested example:
A_JumpIf(velx>=10||vely>=10,"SprintState")
Since velx and vely are absolute and not relative, you have to check both of them with an OR operator. ( || )

You could also add another key check to see if the player is also holding forward, for example:
A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED && GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_FORWARD, "SprintState")

It all depends on how you want it to work.

[body_cleaner666]

You can access the player's velocity with velx and vely expressions.
Untested example:
A_JumpIf(velx>=10||vely>=10,"SprintState")
Since velx and vely are absolute and not relative, you have to check both of them with an OR operator. ( || )

You could also add another key check to see if the player is also holding forward, for example:
A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED && GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_FORWARD, "SprintState")

It all depends on how you want it to work.

Thank you very much, the first variant is fine for me, just what I needed.

(after some minutes of testing) A yes, the first variant is somewhere bugged because sometimes player still has ready state.. Tried second, works fine, but how to add also BT_BACK correctly? I tried to add it, but didn't worked.

[ramon.dexter]

I tried to add it, but didn't worked.

Show what you tried doing.

[openroadracer]

Thank you very much, the first variant is fine for me, just what I needed.

(after some minutes of testing) A yes, the first variant is somewhere bugged because sometimes player still has ready state.. Tried second, works fine, but how to add also BT_BACK correctly? I tried to add it, but didn't worked.

Just upload your mod file to some other file hosting website and link to it here, please. It'd help all of us.

[Jarewill]

Tried second, works fine, but how to add also BT_BACK correctly? I tried to add it, but didn't worked.

How exactly did you try to do it?

The simplest way would be to put another A_JumpIf that just differs with BT_BACK instead of BT_FORWARD.
However you can also do this to check if either of the keys was pressed:
GetPlayerInput(MODINPUT_BUTTONS,-1)&(BT_FORWARD|BT_BACK)
And you can add any other key there as long as you separate them with a binary OR operator. ( | )

[body_cleaner666]

Tried second, works fine, but how to add also BT_BACK correctly? I tried to add it, but didn't worked.

How exactly did you try to do it?

The simplest way would be to put another A_JumpIf that just differs with BT_BACK instead of BT_FORWARD.
However you can also do this to check if either of the keys was pressed:
GetPlayerInput(MODINPUT_BUTTONS,-1)&(BT_FORWARD|BT_BACK)
And you can add any other key there as long as you separate them with a binary OR operator. ( | )

Ah, there is it. Thank you, now works finally as I wished. And here's codes (full of my gun and sprint only state) yet somewhere it's a bit gross.

Sprint:

---

Ready:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 0 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED && GetPlayerInput(MODINPUT_BUTTONS,-1)&(BT_FORWARD|BT_BACK), "SprintState")
TGUI A 0 A_SetCrosshair(23)
TGUI A 1 A_WeaponReady(WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
Loop

SprintState:
TGUI A 0 A_OverlayRotate(1, 20)
TGUW A 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW B 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW C 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW D 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW E 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW F 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW G 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW H 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
Goto Ready

Gun:

---

ACTOR TGNAmmo : Ammo
{
inventory.MaxAmount 34
Inventory.Icon "CLIPA0"
+IGNORESKILL
}

ACTOR TMPSMG: Weapon 20005 {
//$Category "Guns"
Decal "BulletChip"
Inventory.Icon "TGICA0"
Inventory.AltHUDIcon "TOSHA0"
Weapon.UpSound "weapon/gundraw"
Weapon.SelectionOrder 65
Weapon.AmmoUse 1
Weapon.AmmoGive 0
Weapon.AmmoType "TGNAmmo"
Weapon.AmmoUse2 0
Weapon.AmmoGive2 34
Weapon.AmmoType2 "9mmRound"
Weapon.BobStyle "Alpha"
Weapon.BobSpeed 2
Weapon.BobRangeX 2
Weapon.BobRangeY 2
Weapon.WeaponScaleX 1.4
Weapon.WeaponScaleY 1.4
+Weapon.Ammo_Optional
Scale 0.8

Inventory.PickupSound "weapon/weaponpickup"
Inventory.PickupMessage "$GotBobbyGun"

States {
Spawn:
TOMG A -1
Stop

Select:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 1 A_Raise
Loop

Deselect:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 1 A_Lower
Loop

Ready:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 0 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_SPEED && GetPlayerInput(MODINPUT_BUTTONS,-1)&(BT_FORWARD|BT_BACK), "SprintState")
TGUI A 0 A_SetCrosshair(23)
TGUI A 1 A_WeaponReady(WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
Loop

SprintState:
TGUI A 0 A_OverlayRotate(1, 20)
TGUW A 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW B 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW C 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW D 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW E 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW F 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW G 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
TGUW H 2 A_WeaponReady(WRF_NOFIRE|WRF_ALLOWRELOAD|WRF_ALLOWUSER1)
Goto Ready

Fire:
TGUI A 0 A_OverlayRotate(1, 0)
TGUS A 0 A_JumpIfNoAmmo("NoAmmo")
TGUS A 1 A_PlaySound("weapon/bobbyshot",CHAN_WEAPON, 0.65)
TGUS A 1 A_FireBullets(1.4,1.4,-1,random(5,7), "BulletPuff",FBF_USEAMMO|FBF_NORANDOM,8192,none,45)
TGUS B 0 A_FireCustomMissile("GunSleeveSpawner",0,0,0)
TGUS A 0 A_GunFlash
TGUS A 0 A_SetPitch(pitch-0.35)
TGUS B 1
TGUS B 0 A_SetPitch(pitch+0.35)
TGUI A 1
Goto Ready

User1:
TGUI A 0 A_OverlayRotate(1, 0)
TGUM A 3
TGUM B 3
TGUM C 2
TGUM D 2 A_PlaySound("weapongunwhip",CHAN_WEAPON,0.6)
TGUM E 2
TGUM F 2 A_CustomPunch(22,TRUE,0,"MeleePuff",72,0,0,"ArmorBonus","weapon/whiphit")
TGUM G 1
TGUM H 1
TGUM I 1
TGUM J 2
TGUM K 2
TGUM B 3
TGUM A 2
Goto Ready

Flash:
TNT1 A 1 Bright A_Light1
TNT1 A 2 Bright A_Light2
TNT1 A 0 A_Light0
Stop

Hold:
TGUI A 0 A_CheckReload
TGUI A 0 A_ReFire
Goto Ready

NoAmmo:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 0 A_PlaySound("weapon/outofammo", CHAN_WEAPON, 0.75)
TGUI A 15 A_WeaponReady(WRF_NOFIRE)
Goto Ready

Reload:
TGUI A 0 A_OverlayRotate(1, 0)
TGUI A 0 A_WeaponReady
TGUI A 0 A_JumpIfInventory("TGNAmmo",34,"Ready")

TGUI A 0 A_JumpIfInventory("9mmRound",1,2)
goto noammo
TGUR A 3 A_WeaponReady(WRF_NOFIRE)
TGUR B 3 A_WeaponReady(WRF_NOFIRE)
TGUR C 0 A_PlaySound("weapon/bobbyclipout",CHAN_WEAPON, 0.8)
TGUR C 2 A_WeaponReady(WRF_NOFIRE)
TGUR D 2 A_WeaponReady(WRF_NOFIRE)
TGUR E 2 A_WeaponReady(WRF_NOFIRE)
TGUR F 2 A_WeaponReady(WRF_NOFIRE)
TGUR G 22 A_WeaponReady(WRF_NOFIRE)
TGUR H 2 A_WeaponReady(WRF_NOFIRE)
TGUR I 2 A_WeaponReady(WRF_NOFIRE)
TGUR J 2 A_WeaponReady(WRF_NOFIRE)
TGUR K 2 A_WeaponReady(WRF_NOFIRE)
TGUR L 0 A_PlaySound("weapon/bobbyclipin",CHAN_WEAPON, 0.8)
TGUR L 4 A_WeaponReady(WRF_NOFIRE)
TGUR M 3 A_WeaponReady(WRF_NOFIRE)
TGUR N 3 A_WeaponReady(WRF_NOFIRE)
TGUR O 0 A_PlaySound("weapon/bobbyslide",CHAN_WEAPON, 0.8)
TGUR O 3 A_WeaponReady(WRF_NOFIRE)
TGUR P 4 A_WeaponReady(WRF_NOFIRE)
TGUR Q 3 A_WeaponReady(WRF_NOFIRE)
TGUR R 3 A_WeaponReady(WRF_NOFIRE)
TGUI A 2 A_WeaponReady(WRF_NOFIRE)
Goto insert

insert:
TGUI A 0 A_JumpIfInventory("TGNAmmo",34,"Ready")
TGUI A 0 A_JumpIfInventory("9mmRound",1,2)
goto ready
TGUI A 0
TGUI A 0 A_GiveInventory("TGNAmmo",1)
TGUI A 0 A_TakeInventory("9mmRound",1)
TGUI A 0 A_JumpIfInventory("TGNAmmo",0,"Ready")
Goto insert
}

}