Dual wielding pistol

r3v3n93 · Post by **r3v3n93** » Tue Jun 29, 2021 6:26 pm

Have you ever played call of duty? Then you probably experienced Dual-wielded pistol from it. Its system is special because you can shoot both pistols rapidly by clicking both mouse buttons rapidly. I'm currently making a dual-wielding pistol with an overlay to implement the cod system. But there's a problem. It won't fire rapidly. Although [wiki]A_WeaponReady[/wiki] exists on both fire states, it won't cancel the current shooting sequence, but the sequence keep goes on until the animation done. An interesting thing is that A_WeaponReady doesn't cancel fire state and goes to altfire state, but it works when it goes to fire state from canceled fire state(or altfire from altfire).
Sorry for the bad English ability.

Code: Select all

CTOR KellyPistol : DoomWeapon replaces pistol
{
  Weapon.SelectionOrder 1900
  Weapon.AmmoUse 1
  Weapon.AmmoGive 20
  Weapon.AmmoType "Clip"
  Weapon.SlotNumber 2
  Obituary "You've been killed with Kelly's Pistols"
  +WEAPON.WIMPY_WEAPON
  Inventory.Pickupmessage "You picked up Kelly's Pistols"
  Tag "Kellys_Pistols"
  +NOAUTOFIRE
  States
  {
  Ready:
    PPPR A 0 A_Overlay(2, "RightReady")
    PPPL A 1 A_WeaponReady
    Loop
  RightReady:
    PPPR A 1
	Loop
  RightSelect:
    PPPR A 1 A_Raise
    Stop
  Deselect:
    PPPL A 1 A_Lower
    Loop
  Select:
    PPPR A 0 A_Overlay(2, "RightSelect")
    PPPL A 1 A_Raise
    Loop
  Fire:
    PPPL A 2
	PPPL B 1 
	{
	     A_FireBullets (1, 0, 5, 50, "BulletPuff");
         A_PlaySound("weapons/pap", CHAN_WEAPON);
         A_GunFlash;
    }
	PPPL CD 1 	
	PPPL DB 2 A_WeaponReady
	PPPL A 2 
    Goto Ready
  Altfire:
   PPPL A 11 A_Overlay(2, "RightFire")
   Goto Ready
  RightFire:
    PPPR A 2
	PPPR B 1 
	{
	     A_FireBullets (1, 0, 5, 50, "BulletPuff");
         A_PlaySound("weapons/pap", CHAN_WEAPON);
         A_GunFlash("Flash2");
    }
	PPPR CD 1 
	PPPR DB 2 A_WeaponReady
	PPPR A 2 
	Goto RightReady
  Flash:
    PPFL A 1 Bright A_Light1
    Goto LightDone
    PPFL A 1 Bright A_Light1
    Goto LightDone
  Flash2:
    PPFR A 1 Bright A_Light1
    Goto LightDone
    PPFR A 1 Bright A_Light1
    Goto LightDone
  }
}

The code isn't actually finished yet.

Post by **Jarewill** » Wed Jun 30, 2021 1:41 am

A weapon can only be in one state on one overlay, meaning that both Fire and Altfire cannot both operate at the same time.
Making an akimbo weapon is more complex and requires 2 overlays running at the same time and getting the player input.
This is an example I did a while ago:

Spoiler:

Code: Select all

Actor AkimboPistol : Weapon
{
    Weapon.SelectionOrder 1900
    Weapon.AmmoUse 1
    Weapon.AmmoGive 20
    Weapon.AmmoType "Clip"
    Weapon.SlotNumber 2
    Inventory.Pickupmessage "Picked up a second pistol"
    Tag "Akimbo"
    States
    {
    Spawn:
        PIST A -1
        Stop
    Select:
        TNT1 A 0 {A_Overlay(2,"LeftGun"); A_Overlay(3,"RightGun");}
        TNT1 A 0 {A_OverlayOffset(2,-40,0); A_OverlayOffset(3,-40,0);}
        TNT1 A 0 A_OverlayFlags(3,PSPF_FLIP|PSPF_MIRROR,1)
        TNT1 A 1 A_Raise
        Wait
    Deselect:
        TNT1 A 1 A_Lower
        Wait
    Ready:
        TNT1 A 1 A_WeaponReady(WRF_NOFIRE)
        Loop
    LeftGun:
        PISG A 1
        PISG A 1 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_ATTACK,"Fire")
        Wait
    RightGun:
        PISG A 1
        PISG A 1 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_ALTATTACK,"Altfire")
        Wait
    Fire:
        TNT1 A 0 A_JumpIfInventory("Clip",1,1)
        Goto LeftGun
        PISG A 2
        PISG B 2 {A_FireBullets(5.6,0,1,5); A_StartSound("weapons/pistol",CHAN_WEAPON); A_Overlay(1002,"LeftFlash");}
        PISG C 2
        Goto LeftGun
    AltFire:
        TNT1 A 0 A_JumpIfInventory("Clip",1,1)
        Goto RightGun
        PISG A 2
        PISG B 2 {A_FireBullets(5.6,0,1,5); A_StartSound("weapons/pistol",CHAN_5); A_Overlay(1003,"RightFlash");}
        PISG C 2
        Goto RightGun
    LeftFlash:
        PISF A 2 Bright {A_Light1; A_OverlayOffset(1002,-40,0);}
        Goto LightDone
    RightFlash:
        PISF A 2 Bright {A_Light1; A_OverlayOffset(1003,-40,0); A_OverlayFlags(1003,PSPF_FLIP|PSPF_MIRROR,1);}
        Goto LightDone
    }
}

The weapon firing happens in the overlay states instead of the Ready state, which is only used for switching weapons and such. WRF_NOFIRE will prevent Fire and Altfire from triggering normally.
If LeftGun and RightGun detect the fire or altfire buttons being pressed (BT_ATTACK/BT_ALTATTACK) they will jump to the fire states. A_ReFire will break things in this example.

r3v3n93 · Post by **r3v3n93** » Wed Jun 30, 2021 7:46 pm

Jarewill wrote:A weapon can only be in one state on one overlay, meaning that both Fire and Altfire cannot both operate at the same time.
Making an akimbo weapon is more complex and requires 2 overlays running at the same time and getting the player input.
This is an example I did a while ago:

Spoiler:

Code: Select all

Actor AkimboPistol : Weapon
{
    Weapon.SelectionOrder 1900
    Weapon.AmmoUse 1
    Weapon.AmmoGive 20
    Weapon.AmmoType "Clip"
    Weapon.SlotNumber 2
    Inventory.Pickupmessage "Picked up a second pistol"
    Tag "Akimbo"
    States
    {
    Spawn:
        PIST A -1
        Stop
    Select:
        TNT1 A 0 {A_Overlay(2,"LeftGun"); A_Overlay(3,"RightGun");}
        TNT1 A 0 {A_OverlayOffset(2,-40,0); A_OverlayOffset(3,-40,0);}
        TNT1 A 0 A_OverlayFlags(3,PSPF_FLIP|PSPF_MIRROR,1)
        TNT1 A 1 A_Raise
        Wait
    Deselect:
        TNT1 A 1 A_Lower
        Wait
    Ready:
        TNT1 A 1 A_WeaponReady(WRF_NOFIRE)
        Loop
    LeftGun:
        PISG A 1
        PISG A 1 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_ATTACK,"Fire")
        Wait
    RightGun:
        PISG A 1
        PISG A 1 A_JumpIf(GetPlayerInput(MODINPUT_BUTTONS,-1)&BT_ALTATTACK,"Altfire")
        Wait
    Fire:
        TNT1 A 0 A_JumpIfInventory("Clip",1,1)
        Goto LeftGun
        PISG A 2
        PISG B 2 {A_FireBullets(5.6,0,1,5); A_StartSound("weapons/pistol",CHAN_WEAPON); A_Overlay(1002,"LeftFlash");}
        PISG C 2
        Goto LeftGun
    AltFire:
        TNT1 A 0 A_JumpIfInventory("Clip",1,1)
        Goto RightGun
        PISG A 2
        PISG B 2 {A_FireBullets(5.6,0,1,5); A_StartSound("weapons/pistol",CHAN_5); A_Overlay(1003,"RightFlash");}
        PISG C 2
        Goto RightGun
    LeftFlash:
        PISF A 2 Bright {A_Light1; A_OverlayOffset(1002,-40,0);}
        Goto LightDone
    RightFlash:
        PISF A 2 Bright {A_Light1; A_OverlayOffset(1003,-40,0); A_OverlayFlags(1003,PSPF_FLIP|PSPF_MIRROR,1);}
        Goto LightDone
    }
}

The weapon firing happens in the overlay states instead of the Ready state, which is only used for switching weapons and such. WRF_NOFIRE will prevent Fire and Altfire from triggering normally.
If LeftGun and RightGun detect the fire or altfire buttons being pressed (BT_ATTACK/BT_ALTATTACK) they will jump to the fire states. A_ReFire will break things in this example.

Appreciate it man. That's what I was lookin' for. But I think there's a problem that when I die, overlays don't disappear and still function.

Post by **Jarewill** » Thu Jul 01, 2021 1:01 am

You are right that's something I missed.
Try to add A_JumpIfHealthLower to make it jump to a dummy state:

Spoiler:

This will however make it instantly disappear and I don't know what can be done to prevent that.

r3v3n93 · Post by **r3v3n93** » Thu Jul 01, 2021 3:02 am

That'd be kinda effective, but what I've used was dumb but effective. Which is making both idle akimbo pistols sprites into a single sprite, and replaced it on "Deselect" state and used [wiki]A_ClearOverlays[/wiki].
Anyway, Thanks a lot!

ramon.dexter · Post by **ramon.dexter** » Thu Jul 01, 2021 3:30 am

Jarewill wrote: This will however make it instantly disappear and I don't know what can be done to prevent that.

...which could be easily fixed by putting some actual animation sequence into the "nope" state.

r3v3n93 · Post by **r3v3n93** » Thu Jul 01, 2021 3:34 am

ramon.dexter wrote:
Jarewill wrote: This will however make it instantly disappear and I don't know what can be done to prevent that.
...which could be easily fixed by putting some actual animation sequence into the "nope" state.

I've already tried it but the sprite won't show up. Maybe it's just my mistake

Post by **Jarewill** » Fri Jul 02, 2021 3:04 am

ramon.dexter wrote:...which could be easily fixed by putting some actual animation sequence into the "nope" state.

True, but the animation can desync if the weapons enter the state at different times.
I don't know of a method to make it completely foolproof.

r3v3n93 wrote:That'd be kinda effective, but what I've used was dumb but effective. Which is making both idle akimbo pistols sprites into a single sprite, and replaced it on "Deselect" state and used [wiki]A_ClearOverlays[/wiki].
Anyway, Thanks a lot!

This method actually works the best.

ZDoom

Dual wielding pistol

Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol

Re: Dual wielding pistol