Custom properties resetting bug? (Zscript) [Resolved]

[Numnzel]

Hello everyone.

I'm having a really strange bug right now.

I'm creating a new weapon that inherits from an abstract weapon class I did.
The abstract class has a custom property, let's call it X, and a Log function in it's Tick() function for debugging.

The bug is, that if I change the X value by using <self.X> in the new weapon, the Log function shows me the var value changes and resets to the default value in a loop, here's a self-explanatory image:

---

So, IF I move the Log function into the Tick() of the new weapon class instead of the abstract, the reading is cohesive, shows that same variable has changed and does not reset / keeps the new value correctly.

And no, I'm not touching this variable from another place, I already checked that.

What is happening here?

I'm using gzdoom 4.5.0.

[_mental_]

It's impossible to debug a screenshot. Post actual code please.

[Numnzel]

Here goes the code as short as possible:

Abstract class:

---

Code: Select all

class evadoomweapon : weapon abstract {
	
	int mirrorxx;
	property pmirrorx: mirrorxx;

	default {
		
		evadoomweapon.pmirrorx 10;
	}

	override void Tick () {

		super.Tick();

		A_LogInt(self.mirrorxx); // SHOWS VALUE LOOPING AND CHANGING (?)
	}
}

class eva01weapon : evadoomweapon abstract {
	
	default {
		
		//inventory.RestrictedTo "eva01";
	}
}

Actual weapon:

---

Code: Select all

class Eva01Fists : eva01weapon {
	
	default {
		
		weapon.ammouse 0;
		weapon.ammotype "";
		weapon.ammogive 0;
		weapon.slotnumber 1;
		
		+WEAPON.AMMO_OPTIONAL;
		+WEAPON.MELEEWEAPON;
	}

	void mirroring () {
		
		A_Log("CHANGE VALUE TO 999");
		self.mirrorxx = 999;
	}

	override void Tick () {

		super.Tick();

		//A_LogInt(self.mirrorxx); // SHOWS VALUE CONSTANTLY (CORRECTLY CHANGED)
	}
	
	states {
		ready:
			E1FI A 0 A_WeaponReady();
			E1FI A 1;
			loop;
		select:
			E1FI A 1 A_Raise(32);
			loop;
		deselect:
			E1FI A 1 A_Lower(32);
			loop;
		fire:
			E1FI A 10 {
				invoker.mirroring();
			}
			goto ready;
	}
}

[Player701]

I'm unable to reproduce this with your code. The diagnostic messages are probably coming from different instances of the weapon. To be sure, print the value of Level.maptime in addition to the value of mirrorxx, like this:

Code: Select all

Console.Printf("%d, time = %d", mirrorxx, Level.maptime);

If you get more than one message with the same maptime value, it means they are not coming from the same instance. But if that's not the case, it's probably something else in your mod causing the issue.

[Numnzel]

I'm unable to reproduce this with your code. The diagnostic messages are probably coming from different instances of the weapon. To be sure, print the value of Level.maptime in addition to the value of mirrorxx, like this:

Code: Select all

Console.Printf("%d, time = %d", mirrorxx, Level.maptime);

If you get more than one message with the same maptime value, it means they are not coming from the same instance. But if that's not the case, it's probably something else in your mod causing the issue.

That function helped me vastly, didn't know it. I traced the actors doing this:

Code: Select all

Console.Printf("%d, time = %d, actor = %s", mirrorxx, Level.maptime, self.getClassName());

And saw that, of course, the placed weapons in the map were also generating their values.

As always, nothing new below the sky.

I marked the post as resolved. Thank you.