Implementing a combo system

[cinnagoat_]

I need some assistance on how I should go about writing a codebase that essentially functions like Hotline Miami's combos.

Whenever you get a kill, I want it to display HUD images depending on how many kills you get, and disappear whenever you haven't killed anything in a period of time. What would be the best way to format it? I tried to find other WADs so I could reference and learn the code, but to no avail.

[Dan_The_Noob]

maybe look into buffs/debuffs
use enemy sprites or a counter as the display etc etc.

[cinnagoat_]

I was moreso wanting something built into the HUD system.

[Dan_The_Noob]

yeah, usually buff/debuff mods show something on the screen. you could easily use a timed buff in the same way as a combo counter.

[Jarewill]

I've made an ACS script like this:

---

Code: Select all

#library "SCORE"
#include "zcommon.acs"

int combokills; //Amount of kills
int combotimer; //Timer before combo ends

Script "ComboSystem" ENTER
{
    str combomessage;
    While(true)
    {
        If(combokills>0)
        {
            If(combokills==1){combomessage="1 kill!";} //Kill messages
            Else If(combokills==2){combomessage="2 kills!";}
            Else If(combokills==3){combomessage="3 kills!";}
            Else If(combokills==4){combomessage="4 kills!";}
            Else If(combokills==5){combomessage="5 kills!";}
            Else If(combokills==6){combomessage="6 kills!";}
            Else If(combokills==7){combomessage="7 kills!";}
            Else If(combokills==8){combomessage="8 kills!";}
            Else If(combokills==9){combomessage="9 kills!";}
            Else If(combokills>=10){combomessage="Overkill!";}
            SetFont("BIGFONT");
            HudMessage(s:combomessage; HUDMSG_PLAIN, 100, 0, 0.5, 0.2, 0);
            int time = Ceil(FixedDiv(combotimer<<16,35.0));
            SetFont("SMALLFONT");
            HudMessage(f:time; HUDMSG_PLAIN, 101, 0, 0.5, 0.22, 0);
            If(combotimer<=0){combokills=0;} //When timer runs out, combo ends
            Else{combotimer--;}
        }
        Else
        {
            HudMessage(s:" "; HUDMSG_PLAIN, 100, 0, 0.5, 0.2, 0);
            HudMessage(s:" "; HUDMSG_PLAIN, 101, 0, 0.5, 0.2, 0);
        }
        Delay(1);
    }
}

Script "ComboGet" (void)
{
    combokills++; //Add to the counter
    combotimer=175; //5 seconds
} 

Then this in ZScript:

Code: Select all

version "3.3"

Class ComboEventHandler : EventHandler
{
    Override void WorldThingDied(WorldEvent e)
    {
        If(e.Thing.bIsMonster&&e.Thing.target is "PlayerPawn")
        {
            e.Thing.ACS_NamedExecute("ComboGet",0,0,0,0);
        }
    }
}

And this in MAPINFO:

Code: Select all

GameInfo
{
    AddEventHandlers = "ComboEventHandler"
} 

However, it has no way of detecting what killed the monster, so if another monster kills it, it will add to the combo.

Edit: Figured out a way to detect who killed the monster using ZScript.

[cinnagoat_]

I implemented and tested the code and it doesn't seem to count if you get a multi-kill. Is there anything that can make it possibly detect multiple kills in one go? Like a rocket killing a group of zombiemen.

[Jarewill]

My bad.
In the ZScript file replace:

Code: Select all

e.Thing.ACS_NamedExecute("ComboGet",0,0,0,0);

With:

Code: Select all

e.Thing.ACS_NamedExecuteAlways("ComboGet",0,0,0,0);

[cinnagoat_]

Thanks a bunch, yo! I'll make sure to credit you when I complete my mod. I'm not very well versed in ACS/ZScript unless it has to do with mapping, so this is extremely useful.

[LossForWords]

Tweaked the ACS a bit to display combo numbers past 10.

Code: Select all

#library "SCORE"
#include "zcommon.acs"

int combokills; //Amount of kills
int combotimer; //Timer before combo ends

Script "ComboSystem" ENTER
{
    str combomessage;
    While(true)
    {
        If(combokills>0)
        {
            SetFont("BIGFONT");
            HudMessage(s:"\cf",i:combokills,s:"x"; HUDMSG_PLAIN, 100, 0, 0.5, 0.2, 0);
            int time = Ceil(FixedDiv(combotimer<<16,35.0));
            SetFont("SMALLFONT");
            HudMessage(f:time; HUDMSG_PLAIN, 101, 0, 0.5, 0.22, 0);
            If(combotimer<=0){combokills=0;} //When timer runs out, combo ends
            Else{combotimer--;}
        }
        Else
        {
            HudMessage(s:" "; HUDMSG_PLAIN, 100, 0, 0.5, 0.2, 0);
            HudMessage(s:" "; HUDMSG_PLAIN, 101, 0, 0.5, 0.2, 0);
        }
        Delay(1);
    }
}

Script "ComboGet" (void)
{
    combokills++; //Add to the counter
    combotimer=175; //5 seconds
}