Sophisticated Player Dash

[Hornetzero]

Hey everyone,
I was looking for an easy and efficient way to implement a custom move for the player in which he dashes a certain distance forward via a custom action key defined as a CVAR. I'm still new to Zscript and haven't gotten to use it much, but If an example could be provided, it would certainly be easier to do over Decorate or ACS, only because I have some experience with coding in those.

So to elaborate on the type of dash maneuver I want to setup in terms of pseudo code:

1, Upon pressing the dash key, the player activates the PASSTHROUGHACTOR flag, that allows him to pass through enemies like a ghost, until the dash finishes.
2, Defining the distance covered with a fast moving velocity. If the player just taps the dash key, he would move a certain distance forward, and if he holds and releases this key, the distance covered increases.
3, If the player has picked up a Berserker pack, the dash would damage enemies and create a fire trail behind the player.

So whats the best way to set this up?

Thank you
Kagur

[Jarewill]

I did it as a function that gets called every tic and checks if the player is holding a button.
I used the [Run] button instead of a custom bind though.

---

Code: Select all

version "4.4"

Class PlayerDash : DoomPlayer
{
    int maxdash; int cooldash; bool sounddash;
    Override void Tick()
    {
        Super.Tick();
        If(health>0){DoDash();}
    }
    void DoDash()
    {
        If(GetPlayerInput(MODINPUT_BUTTONS)&BT_SPEED && maxdash<18) //If player is holding BT_SPEED, aka [Run]
        {
            If(sounddash){A_StartSound("skeleton/swing"); sounddash=0;} //To play a sound when dashing
            A_ChangeVelocity(20.0,0,0,CVF_RELATIVE|CVF_REPLACE); //Replace third zero with vel.z to make the player subject to gravity
            maxdash++; cooldash=0;
            bTHRUACTORS=1;
            If(FindInventory("PowerStrength")) //Berserk effects
            {
                A_Explode(10,64,XF_NOTMISSILE);
                A_SpawnItemEx("ArchvileFire");
            }
        }
        Else
        {
            If(cooldash>=35) //Cooldown on dash recharge
            {
                If(!sounddash){A_StartSound("misc/i_pkup"); sounddash=1;} //Sound when recharging
                maxdash=0;
            }
            Else{cooldash++; maxdash=18;}
            bTHRUACTORS=0;
        }
    }
} 

[Hornetzero]

Thanks. It works great. The only things off are that the dash maneuver is occasionally blocked by enemies for some unknown reason, and that the velocity reduces when its done while crouching (velocity while jumping, standing and walking is fine and consistent).

[Jarewill]

I don't seem to be able to replicate the issues.
I can dash through monsters fine and the velocity when crouching is the same as when standing.
Was the function modified? Maybe there's something affecting it from the outside?
Could you post your mod?

[Hornetzero]

Sure thing, here is the file.

[Jarewill]

Now that is weird.
Crouching issue doesn't seem to happen with lower velocities, not sure what could be done about that.

As for getting stuck on monsters, I still seem to not encounter that issue.
The only time I got stuck on monsters was when the dash ran out.
It could be fixed by extending the THRUACTORS flag a little bit.
Try this:

---

Code: Select all

Class PlayerDash : DoomPlayer
{
    int maxdash; int cooldash; bool sounddash; int thrudash;
    Override void Tick()
    {
        Super.Tick();
        If(health>0){DoDash();}
        If(thrudash>0){bTHRUACTORS=1; thrudash--;}
        Else{bTHRUACTORS=0;}
    }
    void DoDash()
    {
        If(GetPlayerInput(MODINPUT_BUTTONS)&BT_SPEED && maxdash<18) //If player is holding BT_SPEED, aka [Run]
        {
            If(sounddash){A_StartSound("skeleton/swing"); sounddash=0;} //To play a sound when dashing
            A_ChangeVelocity(100.0,0,0,CVF_RELATIVE|CVF_REPLACE); //Replace third zero with vel.z to make the player subject to gravity
            maxdash++; cooldash=0;
            thrudash=maxdash+10;
            If(FindInventory("PowerStrength")) //Berserk effects
            {
                A_Explode(10,64,XF_NOTMISSILE);
                A_SpawnItemEx("ArchvileFire");
            }
        }
        Else
        {
            If(cooldash>=35) //Cooldown on dash recharge
            {
                If(!sounddash){A_StartSound("misc/i_pkup"); sounddash=1;} //Sound when recharging
                maxdash=0;
            }
            Else{cooldash++; maxdash=18;}
        }
    }
}

[Hornetzero]

It didn't resolve it, but its fine. I'm still quite happy with the results and I thank you very much for this.