Lizard Squad: A cartoony ZDoom mod - Version 5.2b release!

[lizardcommando]

I'm surprised with how much I liked this mod, nice work there!

Y'know, there's something to be said about reimagining the brutal action in Doom as conducted by a bunch of very serious-sounding cute little lizard guys.

Anyway, bug report: rocket launcher's cut off in widescreen.

I did not have widescreen support in mind when I started making this mod. That's why the sprites for the rocket launcher are cut off.

[SamVision]

See if you can make that scope on the RPG useful.

[lizardcommando]

@cq75 I just found a bug in your coding for the revolver. If you reload with an empty clip after picking up some new ammo, it will go jump to the bullet ejecting animation for a split second then jump back to the bullet loading animation.

[lizardcommando]

Here's a comparison between the original textures and my texture pack:




Yes, I know the ring symbol on my flag is longer than the one in the original. I'm going to tweak that a bit later.

[Princess Viscra Maelstrom]

I noticed that the light at the top of the bookcase is gone in your texture pack, and thus, the books on the top shelf are brightened by a nonexistent light.

Other than that, it looks pretty damn good. It looks exactly like the original Doom textures, except with the same cartoony quality as your sprites. However, I have to say, the marble flat looks... well, the quality of the flat is completely lost. It doesn't look anything like the original anymore.

[lizardcommando]

I never got around to fixing the bookcase texture, lol... I just went ahead and fixed that right now. As for the marble floor, I purposely kept it flat-looking to give it a simplistic look. I could go back and add a bit more details to it though if anyone else voices their opinion on it

[Sodaholic]

I think you should add the lines in the marble texture back, just subtle so it fits in with the cartoony stuff.

[cq75]

@cq75 I just found a bug in your coding for the revolver. If you reload with an empty clip after picking up some new ammo, it will go jump to the bullet ejecting animation for a split second then jump back to the bullet loading animation.

Yeah, that's a bug I caught last night

I went through the firing sequence to make sure this one wouldn't mess up. This one should work. I also added more comments to make it easier to figure out if you're interested.

---

Code: Select all • Expand view

ACTOR Revolver : Weapon 14501
{
   +NOAUTOFIRE
   +AMMO_OPTIONAL
   +NOEXTREMEDEATH
   +WEAPON.CHEATNOTWEAPON
      Obituary "%o was capped by %k's trusty ol' Revolver."
        Inventory.Pickupmessage "You got the Revolver!"
   AttackSound "cowboylizard/revolver"
   Inventory.PickupSound "weapons/magnumclose"
   inventory.icon "STWEAP20"
   Weapon.AmmoType1 "REVOLVERCLIP"
   Weapon.AmmoType2 ".45BULLETS"
   Weapon.AmmoUse 1
   Weapon.SelectionOrder 600
   States
   {
   Spawn:
      REVO A -1
      LOOP
   Ready:
      REVG A 1 A_WeaponReady
     REVG A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      Loop
   Deselect:
      REVG A 1 A_Lower
      Loop
   Select:
      REVG A 1 A_Raise
      Goto Select
   Fire:
      REVG A 0 A_JumpIfInventory("RevolverClip", 1, 1)
      Goto DryFire
      REVG A 1 BRIGHT A_GunFlash
      REVG A 0 A_PlayWeaponSound("cowboylizard/revolver")
      REVG A 3 A_FireCustomMissile("PlayerPistolShot",0,1,0,0)
      REVG B 5
      REVG C 3
      REVG D 2
    
      REVG A 3 A_GiveInventory("SpentBullet",1)
    
     REVG A 0 A_JumpIfInventory("RevolverClip",1,"RevCock") // I noticed he cocks the weapon even if there aren't any bullets in the gun. Fixed!
     goto Ready
    
   RevCock:
      REVG E 3
      REVG F 3
      REVG G 3
      REVG H 3 A_PlaySound("cowboylizard/revcock")
      REVG I 3
      REVG A 1
      Goto Ready
    
    
   DryFire:
      REVG A 1 A_Playsound("weapons/click")
     goto Reload
    
    
    // the Reload state is invoked by a dry fire, or when the player hits the "reload" button.
   // since this state can be invoked also by hitting the reload key, you need to check if the gun is full first.
   
    // Reload first checks if there are any spent bullets in the chamber, if there is, it jumps to emptyspentbullets
   
    // if there aren't any spent bullets, AND if the player has ammo to load, it jumps to loadbullets
         // this would happen if the player ran out of ammo, dumped the spent bullets, and found ammo later.
         
    // if the player doesn't have any spent bullets, and doesn't have any ammo to load, reload just goes straight back to ready.
    
   Reload:       
   REVR A 0 A_JumpIfInventory("RevolverClip",6,"Ready") // no point in reloading if the gun is full!
   REVR A 0 A_JumpIfInventory("Spentbullet",1,"EmptySpentBullets") // if there is at least one spent bullet in the chambers, go to EmptySpentbullets
   
   
   REVR A 0 A_JumpIfInventory(".45BULLETS",1,"LoadBullets") // if you have any ammo, load it
   
   // if you don't have any bullets, and there are no spent bullets in the chamber, go to ready.
    
     goto Ready
    
    
   EmptySpentBullets: // intro sequence for emptying spent bullets
      REVR AB 3
      REVR C 4
      REVR DEF 3
   
   DropBullet: // loop for emptying bullets. One iteration per empty bullet.
      
      REVR H 2 A_PlaySound("weapons/magnumload2")
      REVR H 0 A_FireCustomMissile("MagnumShellcasing",random(-2,2),0,1,-5)
      REVR G 3
      
      REVR G 0 A_TakeInventory("SpentBullet",1)
      REVR G 0 A_JumpIfInventory("SpentBullet",1,"DropBullet") // [75] - if there is at least one spent bullet in the chamber, repeat.

      // end of the emptying spent bullets loop, below is the out sequence.
      REVR FEDCA 3
      REVR A 0 A_JumpIfInventory(".45BULLETS",1,"LoadBullets") //[75] - if there is at least one .45 bullet to put in the chamber, load it
      goto Ready // if not, go to ready.
      
   LoadBullets: // loop for loading bullets, one iteration per loaded bullet.
      REVR I 2
        REVR J 3 A_PlaySound("weapons/magnumload2")
        REVR J 0 A_GiveInventory("REVOLVERCLIP",1)
      REVR J 0 A_TakeInventory(".45BULLETS",1)
      REVR J 0 A_JumpIfInventory("REVOLVERCLIP",6, "MagazineLoaded") // if the gun is now full, go to Magazine loaded
      REVR J 0 A_JumpIfInventory(".45BULLETS",1,"LoadBullets") // the gun is not full, if you have bullets, repeat the loop
      goto MagazineLoaded //the gun is not full, you've run out of bullets, cock the weapon and move on.
      
    MagazineLoaded: // the animation where he cocks the revolver after it's loaded.
      REVG E 3
      REVG F 3
      REVG G 3
      REVG H 3 A_PlaySound("cowboylizard/revcock")
      REVG I 3
      REVG A 1
      Goto Ready
    
    
   AltFire: // Quickdraw
      REVG A 0 A_JumpIfInventory("RevolverClip",1,1)
      Goto DryFire // both fire and altfire go to dryfire if there's no ammo in the clip.
      REVG A 1 BRIGHT A_GunFlash
      REVG A 0 A_PlayWeaponSound("cowboylizard/revolver")
      REVG A 3 A_FireCustomMissile("PlayerPistolShot",0,1,0,0)
      REVG A 0 BRIGHT A_TakeInventory("RevolverClip",1)
    
      REVG B 5 A_GiveInventory("SpentBullet",1)
    
      QKDR AB 1
      QKDR C 1 A_PlaySound("cowboylizard/revcock")
      QKDR D 1
      REVG A 1 A_Refire
      Goto Ready
   Flash:
      REVF A 2 BRIGHT A_Light1
      REVF A 0 BRIGHT A_Light0
      stop
  }
}


EDIT - I made the reload faster for the combat shotgun and added an A_Refire to both the combat and sawn off shotguns. Let me know what you think, it feels a little smoother, but I noticed you turned off autofire on most of your weapons, so you might not like this change.

---

Code: Select all • Expand view

ACTOR CombatShotgun : Weapon replaces Shotgun
{
   +AMMO_OPTIONAL
   //+NOAUTOFIRE
   +NOALERT
   +NOEXTREMEDEATH
   inventory.icon "STWEAP5"
      Obituary "%o's was murdered by %k's Combat Shotgun."
      Inventory.Pickupmessage "You got the Combat Shotgun!"
   Weapon.AmmoType "SHOTGUNCLIP"
   Weapon.AmmoType2 "SHOTGUNSHELLS"
   Weapon.AmmoGive1 4
   Weapon.AmmoGive2 4
   Weapon.AmmoUse 1
   Weapon.SelectionOrder 280
   States
   {
   Spawn:
      SHOT A -1
      LOOP
   Ready:
      SHTG A 1 A_WeaponReady
      SHTG A 0 A_JumpIfInventory("IsReloading",1,"Reload")
      Loop
      SHTG A 1
      Goto Fire+12
   Deselect:
      SHTG A 1 A_Lower
      Loop
   Select:
      SHTG A 1 A_Raise
      Loop
   Fire:
      SHTG A 0 A_JumpIfNoAmmo("DryFire")
      SHTG A 0 A_AlertMonsters
      SHTG A 1 BRIGHT A_GunFlash
      SHTG A 0 A_PlayWeaponSound("weapons/shotgun")
      SHTG A 7 A_FireBullets(6,7.1,12,5,"BULLETHIT",1)
      SHTG B 4
      SHTG C 5
      SHTG D 5
      TNT1 A 0 A_FireCustomMissile("ShotgunShellcasing2Spawn",0,0,-20,-7)
      SHTG C 5
      SHTG B 4     
      SHTG A 8
     SHTG A 0 A_Refire
      Goto Ready
   DryFire:
      SHTG A 1 A_Playsound("weapons/click")
      Goto Reload
   Reload:
      SHTR A 0 A_JumpIfInventory("SHOTGUNCLIP",0,"Ready")
      SHTR A 0 A_JumpIfInventory("SHOTGUNSHELLS",1,1)
      Goto Ready
      SHTG A 3
   LoadMagazine:
      SHTG B 1
      SHTR A 1
      SHTR B 1 A_PlaySound("weapons/shotgunload")
      SHTR A 0 A_GiveInventory("SHOTGUNCLIP",1)
      SHTR A 0 A_TakeInventory("SHOTGUNSHELLS",1)   
      SHTR C 2
      SHTR D 3
      SHTG B 2
      SHTR A 0 A_JumpIfInventory("IsReloading",1,1)
      Goto CockGun
      SHTR A 0 A_JumpIfInventory("SHOTGUNSHELLS",1,1)
      Goto CockGun
      SHTR A 0 A_JumpIfInventory("SHOTGUNCLIP",0,1)
      Goto LoadMagazine
   CockGun:
      SHTG C 3 A_Playsound("weapons/sgcock")
      SHTG D 3
      SHTG C 3
      SHTG B 3     
      SHTG A 0       
      Goto Ready
   AltFire:
      SHTM A 1 A_PlayWeaponSound("melee/shotgunswing")
      SHTM B 2
      SHTM C 2 A_CUSTOMPUNCH(6.5,0,1,"ShotgunMeleePuff")
      SHTM D 2
      NULL A 15
      SHTM E 3
      Goto Ready
   Flash:
      SHTF A 4 BRIGHT A_Light1
      SHTF B 3 BRIGHT A_Light2
      SHTF B 0 BRIGHT A_Light0     
      stop

  }

}


actor Handcannon : Weapon replaces SuperShotgun
{
  radius 20
  height 16
  attacksound "weapons/sshotf"
  inventory.pickupmessage "You got the Handcannon!"
  obituary "%o was blasted by %k's Handcannon."
  Inventory.PickupSound "weapons/sshotc"
  inventory.icon "STWEAP6"
  weapon.selectionorder 250
  weapon.kickback 100
  weapon.ammotype "SSGMag"
  weapon.ammotype2 "SHOTGUNSHELLS"
  weapon.ammouse 1
  weapon.ammouse2 0
  Weapon.AmmoGive2 8
  weapon.ammogive1 2
 +AMMO_OPTIONAL
 +NOAUTOFIRE
  states
  {
  Ready:
    SHT2 A 1 A_WeaponReady
    SHT2 A 0 A_JumpIfInventory("IsReloading",1,"Reload")
    loop
  Deselect:
    SHT2 A 1 A_Lower
    loop
  Select:
    SHT2 A 1 A_Raise
    loop
  Fire:
    TNT1 A 0  A_JumpIfInventory("SSGMag",1,1)
    Goto Reload  //originally went to Dryfire?
    SHT2 A 3
    SHT2 A 0 A_GunFlash
    SHT2 A 4 A_FireBullets (10.2,5.1,10,5,"BULLETHIT")
    SHT2 P 2
    SHT2 B 2
    TNT1 A 0 A_Refire
    Goto Ready
  DryFire:  //Appears to be unused?
    SHT2 A 1 A_Playsound("weapons/click")
    Goto Reload
  AltFire:
    SHT2 A 0 A_JumpIfInventory("SSGMag",2,1)
    Goto FireOnce
    SHT2 A 0 A_TakeInventory("SSGMag",2)
   TNT1 A 0 A_GunFlash
    SHT2 A 4 A_FireBullets (13.2,8.1,20,5,"BULLETHIT")  //why no duration?  Fix
    Goto Reload
  FireOnce:
    TNT1 A 0 A_JumpIfInventory("SSGMag",1,1)
    Goto Reload
    SHT2 A 0 A_FireBullets (13.2,8.1,10,5,"BULLETHIT")
    SHT2 A 4 A_GunFlash
    SHT2 P 2
    SHT2 B 2 A_TakeInventory("SSGMag",2)
    Goto Ready
   Reload:
    TNT1 A 0 A_JumpIfInventory("SHOTGUNSHELLS",1,1)
    Goto Ready
    TNT1 A 0 A_JumpIfInventory("SSGMag",0,"Ready")
    SHT2 AB 4
    SHT2 C 4 A_PlaySound ("weapons/sshoto")
    TNT1 A 0 A_JumpIfInventory("SHOTGUNSHELLS",2,1)
   Goto OneShell
    TNT1 A 0 A_JumpIfInventory("SSGMag",1,1)
   Goto BothShells
  OneShell:
    TNT1 A 0 A_TakeInventory("SHOTGUNSHELLS",1)
   TNT1 A 0 A_FireCustomMissile("ShotgunShellcasingSpawn",0,0,-6,2)
    SHT2 E 5 A_GiveInventory("SSGMag",1)
    Goto MagazineLoaded
  BothShells:
    TNT1 A 0 A_TakeInventory("SHOTGUNSHELLS",2)
   TNT1 A 0 A_FireCustomMissile("ShotgunShellcasingSpawn",0,0,-6,2)
   TNT1 A 0 A_FireCustomMissile("ShotgunShellcasingSpawn",0,0,-8,2)
    SHT2 E 5 A_GiveInventory("SSGMag",2)
  MagazineLoaded:
    SHT2 E 4
    SHT2 F 4
    SHT2 G 4 A_PlaySound ("weapons/sshotl")
    SHT2 H 4
    SHT2 I 0 A_PlaySound ("weapons/sshotc")
    SHT2 IA 3
    goto Ready
    SHT2 A 1
    Goto Ready
  Flash:
    TNT1 A 0 A_JumpIfInventory("SSGMag",1,4)
    SHT2 N 2 bright A_Light1
    SHT2 O 2 bright A_Light2
    TNT1 A 0 bright A_Light0
    Stop
    TNT1 A 0 A_JumpIfInventory("SSGMag",2,4)
    SHT2 L 2 bright A_Light1
    SHT2 M 2 bright A_Light2
    TNT1 A 0 bright A_Light0
    Stop
    SHT2 J 2 bright A_Light1
    SHT2 K 2 bright A_Light2
    TNT1 A 0 bright A_Light0
    stop
  Spawn:
    SGN2 A -1
    stop
  }
}


[lizardcommando]

Excellent work with the revolver coding. It works great now.

As for the shotgun and handcannon, I'll probably use the coding for the faster reloading. Everything else, I most likely won't use. I wanted to give this mod a bit of a tactical feel to it, so that you don't just rush in guns blazing. I personally feel alot more comfortable having to press the fire button to shoot the shotgun for every shot. I know I was practically inspired by the Metal Slug games for this mod, but I still wanted to put in a splash of realism to it in terms of some of the gameplay mechanics.

[cq75]

I figured you wanted "semi-auto" weapons. It works really well for the pistols and the infantry rifle.

My best attempt to explain why I like the shotgun to have auto fire:

Usually, having to press the button to fire the gun should give you more control over it, but not always.

An example of a good weapon to have no auto fire is your 9mm pistol. The firing state is really short, so you can hammer the button to fire off several shots a second.
It makes sense to turn off auto fire, if you didn't, the gun would be as fast as the .45 MP.

An example of a weapon that would be bad with auto fire off is the Doom standard pistol. Its firing state is long, if that weapon was made without A_Refire, you'd have to time hitting the fire button with when the sprite stopped animating, in order to get as many shots out as possible (I did a lot with the shotgun).

For your shotgun, since there's a reload animation between every shot, you can't really fire at the exact moment you want to, so it doesn't give you more control over the gun.

I felt a lot more comfortable with it as an auto fire weapon, I don't mind loading a patch if you want to turn off auto-fire, though.


EDIT - nice work on the textures so far

EDIT2 - The monsters still infight, is that a bug?

[DoomRater]

An example of a good weapon to have no auto fire is your 9mm pistol. The firing state is really short, so you can hammer the button to fire off several shots a second.
It makes sense to turn off auto fire, if you didn't, the gun would be as fast as the .45 MP.

there are ways to make a weapon fire faster and still have a very slow autofire. I've done it a few times, and it involves +NOAUTOFIRE and careful use of A_WeaponReady() with the proper flags to disallow switching. Actually I did it before those flags existed so I always had glitches where it was possible to put the weapon away really fast.

Oh right, obviously you NEED A_Refire after all the normal lag frames are added, just pad them with A_WeaponReady frames to allow firing faster.

[pieceofpiesoftware]

make the blood splats on the wall be just one color to help with the cartoonie effect.

[lizardcommando]

Alright, well what's the best way to edit them? I export them, but they appear black and white.

[InsanityBringer]

really, you should be able to get away with just making all of the pixels you want red white, and all of the pixels you want transparent black. As far as I'm aware, for decals, the grayscale images like this are treated as alpha channels (white = not transparent, black = completely transparent and all of the colors inbetween are varying amounts).

[cq75]

I changed the bloodsplat color by using the "Bloodcolor" actor property. Whatever you set that to, the color on the wall will match. I'm not sure if you can make it one solid color, but a brighter red might look more cartoony.