Issues With Global Arrays and DrawNumber

[22alpha22]

I've created a range finder that works by calculating the distance between the player and a bulletpuff, then displaying the distance on the HUD via SBARINFO and a global array. The problem is that the number on the HUD always comes out as "0" and I'm not sure why.

The bulletpuff:

---

Code: Select all

Actor AlphaRangeFinderPuff : BulletPuff
{
	VSpeed 0
	Radius 1
	Height 2
	AttackSound "Null"
	RenderStyle None
	Alpha 0.0
	DamageType "Null"
	+NOTRIGGER
	+NOTIMEFREEZE
	+DONTSPLASH
	+NODAMAGETHRUST
	+BLOODLESSIMPACT
	+PAINLESS
	+PUFFONACTORS
	+PUFFGETSOWNER
	+NODECAL
	+NOTONAUTOMAP
	-RANDOMIZE
	-ALLOWPARTICLES
	States
	{
	Spawn:
		Goto Death
	Melee:
		Goto Death
	Crash:
		Goto Death
	Death:
		TNT1 A 0
		TNT1 A 1 ACS_NamedExecute("Range_Finder",0,0,0,0)
		TNT1 A 1
		Stop
	}
}

The ACS:

---

Code: Select all

Global Int 1:RangeFinder[];

Script "Range_Finder" (void) {
RangeFinder[PlayerNumber()] = PlayerRangeFinder(GetActorProperty(0,APROP_TARGETTID));
}

Function Int PlayerRangeFinder (Int PlayerTID)
{
	Int Length;
	Int Y = GetActorY(0) - GetActorY(PlayerTID) >> 16;
	Int X = GetActorX(0) - GetActorX(PlayerTID) >> 16;
	Int Z = GetActorZ(0) - GetActorZ(PlayerTID) >> 16;
	
	Int Angle = VectorAngle(X,Y);
	If (((Angle + 0.125) % 0.5) > 0.25) Length = FixedDiv(Y,Sin(Angle));
	Else Length = FixedDiv(X,Cos(Angle));
	
	Angle = VectorAngle(Length,Z);
	If(((Angle + 0.125) % 0.5) > 0.25) Length = FixedDiv(Z,Sin(Angle));
	Else Length = FixedDiv(Length,Cos(Angle));
	
	Return Length;
}

The SBARINFO:

---

Code: Select all

...
IsSelected "AlphaAUGPara"
	{
		DrawNumber 3, AlphaFont1, NovaLogicGreen, Ammo1, Alignment(Right), FillZeros, 52 + Center, -18;
		DrawNumber 2, AlphaFont1, NovaLogicGreen, Ammo2, Alignment(Right), FillZeros, -68 + Center, -18;
		InInventory "AlphaScopeToken", 1
		{
			DrawImage "SCOPE1A", -256, 0 + Center, Center;
			DrawImage "SCOPE1B", -256, 0 + Center, Center;
			DrawImage "SCOPE1C", -256, 0 + Center, Center;
			DrawString AlphaFont1, NovaLogicYellow, "1.5x", -304, 80 + Center, 0, Alignment(Center);
			DrawNumber 4, AlphaFont1, NovaLogicGreen, GlobalArray(1), Alignment(Right), -208, 80 + Center;
		}
	}
...

As you can see, the range value between the player and the puff should be displayed on the HUD whenever the player activates the scope on the weapon, but for some reason the value always comes out "0". In order to be sure the distance values were being calculated correctly, I added the following line to "Range_Finder" script.

Code: Select all

PrintBold(d:PlayerRangeFinder(GetActorProperty(0,APROP_TARGETTID)));

The result was the range to the puff was displayed with expected values in the center of the screen and logged to the console, therefore ruling out any miscalculations in the range finder function. To make matters more interesting, I have an older, more complex range finder script that was called directly from the weapon, rather than a puff, which does display the correct values on the HUD.

The older ACS:

---

Code: Select all

Script "Range_Finder" (void) { 
Int TempTID = UniqueTID(0,0);
Int OldTID = PickActor(0,GetActorAngle(0),GetActorPitch(0),9999.0,0,MF_SHOOTABLE,ML_BLOCKEVERYTHING|ML_BLOCKHITSCAN,PICKAF_RETURNTID);

PickActor(0,GetActorAngle(0),GetActorPitch(0),9999.0,TempTID,MF_SHOOTABLE,ML_BLOCKEVERYTHING|ML_BLOCKHITSCAN,PICKAF_FORCETID);
	If (PickActor(0,GetActorAngle(0),GetActorPitch(0),9999.0,0,MF_SHOOTABLE,ML_BLOCKEVERYTHING|ML_BLOCKHITSCAN,PICKAF_RETURNTID) > 0)
	{
		RangeFinder[PlayerNumber()] = PlayerRangeFinder(TempTID);
	}
	Else
	{
		RangeFinder[PlayerNumber()] = 0;
	}	
Thing_ChangeTID(TempTID,OldTID);
}

The reason I abandoned the old script, which did work correctly, was simply because it only worked when aiming at shootable things and wouldn't provide range values for stuff like level geometry. The new script should provide range values on just about everything, but for whatever reason it just wont work at all.

[Blue Shadow]

I believe the problem is here:

Code: Select all

Script "Range_Finder" (void) {
RangeFinder[PlayerNumber()] = PlayerRangeFinder(GetActorProperty(0,APROP_TARGETTID));
} 

Since the script is called by a non-player (the puff, in this case), PlayerNumber() will return -1.

[22alpha22]

Since the script is called by a non-player (the puff, in this case), PlayerNumber() will return -1.

Thank you so much! I can't believe I overlooked that, I must have been really tired when I wrote that script. Anyway, I've given the puff a TID which is offset from the player's TID and modified the script to make the player the activator. Now it works perfectly.

Code: Select all

Script "Range_Finder" (void) {
Int PuffTID = ActivatorTID();

SetActivatorToTarget(PuffTID);
RangeFinder[PlayerNumber()] = PlayerRangeFinder(PuffTID);
}