Prevent "underwater actors" from moving out of the water?

[Tormentor667]

Another nooby-question I guess: I am using Sharks in BoA that can fly but should not be able to leave the 3d water sectors. How can I prevent them to do this? Or are there any other flags for "swimming in water sectors"?

[Hellser]

Hm. There are checks to see if an actor is underwater, but not "keep an actor IN the water" -- could be a feature request?

[Nash]

I'm interested in this too. Would appreciate it if someone posted a bare-bones example. I see MaxEd achieved this in his Powerslave mod but the WAD is too large-scope for me to quickly inspect (yeah I'm impatient LOL).

[Zanieon]

in ACS:

Code: Select all • Expand view

Script "WaterLevelCheck" (Void)
{
   While (TRUE)
   {
      if ( GetActorProperty (0, APROP_Waterlevel) < 3 && GetUserVariable(0, "user_isswimming")==1 )
         SetActorState(0, "Swim.Cancel");
      else if ( GetActorProperty (0, APROP_Waterlevel) == 3 && GetUserVariable(0, "user_isswimming")==0 )
         SetActorState(0, "Swim.Allow");
      Delay(1);
   }
}

in DECORATE:

Code: Select all • Expand view

ACTOR Somerandomshitthatswims
{
   var int user_isswimming;

   States:
   {
   Swim.Cancel:
      TNT1 A 0 A_ChangeFlag("FLOAT",0)
      TNT1 A 0 A_ChangeFlag("NOGRAVITY",0)
      TNT1 A 0 A_SetUserVar("user_isswimming",0)
      Goto See
   Swim.Allow:
      TNT1 A 0 A_ChangeFlag("FLOAT",1)
      TNT1 A 0 A_ChangeFlag("NOGRAVITY",1)
      TNT1 A 0 A_SetUserVar("user_isswimming",1)
      Goto See
   }
}

I didn't tested, write this right now, but the idea is something like this.

[Ozymandias81]

There is also a much more easy way to fix sharks without using acs. Just give me ten mins and I'll post here.

[Ozymandias81]

Here you are: add MaxStepHeight 1 to properties. I wasn't on my PC for a while

[EDIT]: I see you've add a missile state inside shark, now I know exactly why you needed it...
Nevermind above stuff.

[Ozymandias81]

I'm interested in this too. Would appreciate it if someone posted a bare-bones example. I see MaxEd achieved this in his Powerslave mod but the WAD is too large-scope for me to quickly inspect (yeah I'm impatient LOL).

That's the MaxED piranha code, it has some actors inheritances here and there, but everyhting is here.

---

Code: Select all • Expand view

actor ExPiranha : ExEnemy 1913
{
   //$Category Monsters
   //$Title Angry Piranha

   Radius 16
   Height 48
   XScale 0.6
   YScale 0.55
   Speed 4
   Health 32 //2 machete hits
   MeleeRange 42
   PainChance 196
   Accuracy 50

   SeeSound "piranha/see"

   +FLOAT
   +NOGRAVITY
   
   States
   {
      Spawn:
         PRNM A 0 NoDelay A_SetScale(ScaleX + frandom(-0.1, 0.15), ScaleY + frandom(-0.1, 0.1))
         goto Idle
      
      Idle:
         PRNM A 5 ThrustThing(angle*256/360 + 64, 2, 0, 0)
         PRNM B 2 A_LookEx(0, 0, 0, 256, 360)
         PRNM C 5 ThrustThing(angle*256/360 + 192, 2, 0, 0)
         PRNM B 2 A_LookEx(0, 0, 0, 256, 360)
         loop   
   
      See:
         PRNM A 0 ThrustThing(angle*256/360 + 64 , 2, 0, 0)
         PRNM AAAAABB 1 A_Chase
         NULL A 0 ThrustThing(angle*256/360 + 192 , 2, 0, 0)
         PRNM CCCCC 1 A_Chase
         NULL A 0 A_JumpIf(waterlevel != 3, "PushDown")
         loop
         
      Wander:
         PRNM A 5 ThrustThing(angle*256/360 + 64, 2, 0, 0)
         PRNM B 2 A_Wander
         PRNM C 5 ThrustThing(angle*256/360 + 192, 2, 0, 0)
         PRNM B 2 A_Wander
         NULL A 0 A_Jump(64, "StopWandering")
         loop
         
      StopWandering:
         NULL A 0 A_ChangeFlag("FRIGHTENED", 0)
         goto Idle   

      PushDown:
         NULL A 0 A_ChangeVelocity(velx, vely, -10)
         goto See

      Melee:
         NULL A 0 A_FaceTarget
         NULL A 0 A_JumpIf(CallACS("ExGetPlayerZ") > z, "UpperAttack")
         NULL A 0 A_Jump(128, "Melee2")
         PRA1 AB 6 A_CustomMeleeAttack(3)
         NULL A 0 A_PlaySound("piranha/attack", CHAN_AUTO | CHAN_UI, 0.75)
         goto See
         
      Melee2:
         PRA2 A 6
         PRA2 B 5 A_CustomMeleeAttack(3)
         NULL A 0 A_PlaySound("piranha/attack", CHAN_AUTO | CHAN_UI, 0.75)
         goto See
         
      Pain:
         NULL A 0 A_ChangeFlag("FRIGHTENED", 1)
         goto Wander
         
      UpperAttack:
         PRAU A 6
         PRAU B 5 A_CustomMeleeAttack(3)
         NULL A 0 A_PlaySound("piranha/attack", CHAN_AUTO | CHAN_UI, 0.75)
         goto See
         
      Death:
         NULL A 0 A_Jump(30, "XDeath") //because it's kinda hard to cause XDeath with machete :)
         NULL A 0 A_Jump(64, "Death2")
         PIRD A 8 A_NoBlocking
         NULL A 0 A_PlaySound("piranha/death", CHAN_AUTO | CHAN_UI, 1.0)
         NULL A 0 A_CheckFloor("DeathOnFloor")
         NULL A 0 A_SpawnItemEx("ExPiranhaCorpse")
         stop
         
      DeathOnFloor:
         PIRD BBBBCCCCDDDDEEEEFFFF 2 A_SpawnItemEx("ExUnderwaterBloodBubble", Random(-16, 16), Random(-16, 16), Random(16, 32))
         goto Lay
         
      Lay:
         PIRD F 250
         NULL A 0 A_CheckSight("Vanish")
         loop

      Death2:
         PIRX A 8 A_NoBlocking
         NULL A 0 A_PlaySound("piranha/death", CHAN_AUTO | CHAN_UI, 1.0)
         NULL A 0 A_CheckFloor("Death2OnFloor")
         NULL A 0 A_SpawnItemEx("ExPiranhaCorpse2")
         stop

      Death2OnFloor:
         PRD2 BBBBCCCCDDDD 2 A_SpawnItemEx("ExUnderwaterBloodBubble", Random(-16, 16), Random(-16, 16), Random(16, 32))
         goto Lay2
         
      Lay2:
         PRD2 D 250
         NULL A 0 A_CheckSight("Vanish")
         loop

      XDeath:
         PIRX A 6 A_NoBlocking
         NULL A 0 A_PlaySound("piranha/death", CHAN_AUTO | CHAN_UI, 1.0)
         PIRX B 6
         NULL AAAAAAAAAAAAA 0 A_SpawnItemEx("ExUnderwaterBloodBubble", Random(-24, 24), Random(-24, 24), Random(0, 32), 0, 0, 32)
         NULL A 0 A_SpawnItemEx("ExPiranhaGore1", 0, 0, 16, velx + Random(-2, 2), vely + Random(-2, 2), Random(1, 3), Random(0, 256), 0, 0)
         NULL A 0 A_SpawnItemEx("ExPiranhaGore2", 0, 0, 16, velx + Random(-2, 2), vely + Random(-2, 2), Random(1, 3), Random(0, 256), 0, 0)
         NULL A 0 A_SpawnItemEx("ExPiranhaGore3", 0, 0, 16, velx + Random(-2, 2), vely + Random(-2, 2), Random(1, 3), Random(0, 256), 0, 0)
         PIRX C 6
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloud", 0, 0, 16)
         PIRX DE 6
         stop
         
      Vanish:
         NULL A 0
         stop
   }
}

//GORE
actor ExPiranhaGore1 : ExAbstractGoreChunk
{
   Gravity 30
   //DeathSound "gore/splat"

   States
   {
      Spawn:
         PGOR ABCD 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         goto Fly
         
      Fly:
         PGOR A 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         loop
         
      Death:
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", 0, 0, 16)
         goto Lay

      Lay:
         PGOR A 250
         NULL A 0 A_CheckSight("Vanish")
         loop
   }
}

actor ExPiranhaGore2 : ExAbstractGoreChunk
{
   Gravity 20
   //DeathSound "gore/splat"

   States
   {
      Spawn:
         PGOR FGHI 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         goto Fly
         
      Fly:
         PGOR F 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         loop
         
      Death:
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", 0, 0, 16)
         goto Lay

      Lay:
         PGOR F 250
         NULL A 0 A_CheckSight("Vanish")
         loop
   }
}

actor ExPiranhaGore3 : ExAbstractGoreChunk
{
   Gravity 25
   //DeathSound "gore/splat"

   States
   {
      Spawn:
         PGOR KLMN 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         goto Fly
         
      Fly:
         PGOR K 8 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", Random(-2, 2), Random(-2, 2), Random(-2, 2))
         loop
         
      Death:
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloudSmall", 0, 0, 16)
         goto Lay

      Lay:
         PGOR K 250
         NULL A 0 A_CheckSight("Vanish")
         loop
   }
}

actor ExPiranhaCorpse : ExAbstractGoreChunk
{
   Gravity 20.0
   Mass 500

   States
   {
      Spawn:
         PIRD BBBBBBCCCCCC 1 A_SpawnItemEx("ExUnderwaterBloodBubble", Random(-16, 16), Random(-16, 16), Random(16, 32))
         loop
         
      Death:
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloud", 0, 0, 16)
         PIRD DEF 8
         goto Lay

      Lay:
         PIRD F 250
         NULL A 0 A_CheckSight("Vanish")
         loop
   }
}

actor ExPiranhaCorpse2 : ExAbstractGoreChunk
{
   Gravity 20.0
   Mass 500

   States
   {
      Spawn:
         PRD2 BBBBBBCCCCCC 1 A_SpawnItemEx("ExUnderwaterBloodBubble", Random(-16, 16), Random(-16, 16), Random(16, 32))
         loop
         
      Death:
         NULL A 0 A_SpawnItemEx("ExUnderwaterBloodCloud", 0, 0, 16)
         goto Lay

      Lay:
         PRD2 D 250
         NULL A 0 A_CheckSight("Vanish")
         loop
   }
}

and its ExGetPlayerZ acs code

Code: Select all • Expand view

script "ExGetPlayerZ" (void)
{
   SetResultValue(GetActorZ(playerID) >> 16);
}

[Zanieon]

The problem there Ozymandias81, the delay to check if the actor is under water is too long and causes a bit of "jumping" out of the water, this behavior is the intention on this mainly because a piranha really behaves as this unlike a shark that stays underwater more often, reducing the check delay on the state would solve the problem but this will go make piles of extra lines in the decorate which isn't necessary if there is a script is running on background to do the job it.

Well decision is up to Torm on what code use, both solves the problem i think (as i said above, i didn't tested mine)

[Ozymandias81]

The problem there Ozymandias81, the delay to check if the actor is under water is too long and causes a bit of "jumping" out of the water, this behavior is the intention on this mainly because a piranha really behaves as this unlike a shark that stays underwater more often, reducing the check delay on the state would solve the problem but this will go make piles of extra lines in the decorate which isn't necessary if there is a script is running on background to do the job it.

Well decision is up to Torm on what code use, both solves the problem i think (as i said above, i didn't tested mine)

I'm OK with you Rev, I tried some odd stuff to see if running continuosly thingthrust while underwater could help, but didn't work unless we have only melee states in it (I mean the shark).
The fact is that I have a piranha inside Gore that works exactly like shark one, except that it doesn't have any missiles states that will prevent it to go out of water.
BTW I'll try now your code and if it works I'll ask to Torm to implement on sharks.
Thankx anyway Rev (I'm gonna give a look to your big boss and see if I'm skilled enough to to make/change its not-so-doomish palette into a baron one).

[Ozymandias81]

While I wasn't capable to implement Rev's code, I've done a silly trick that worked a bit.
Here's the shark code, the trick can be found inside "missile" state:

---

Code: Select all • Expand view

ACTOR Shark 8000
{
//$Category Monsters (Wolf3D)
//$Title Shark
//$Color 4
obituary "%o was shredded by a shark."
health 100
mass 120
speed 10
Radius 30
Height 30
seesound "shark/sight"
deathsound "shark/death"
activesound "shark/active"
MONSTER
+FLOORCLIP
+NOGRAVITY
+DROPPED
+FLOAT
States
   {
   Spawn:
   SHRK BC 10 A_Look
   loop
   See:
   SHRK ABCB 4 A_GiveInventory("Chase_Water",1)
   loop
   Missile:
   SHRK A 0 A_Jumpifcloser(224, 2)
   Goto See
   SHRK A 4 A_FaceTarget
   SHRK A 10 A_SkullAttack(1.5)
   SHRK A 4 A_Gravity
   Goto Missile+2
   Melee:
   SHRK A 10 A_FaceTarget
   SHRK F 8 A_CustomMeleeAttack (random (1, 5) *5, "Chomp", "Swipe")
   SHRK A 10
   goto See
   Death:
   SHRK A 0
   SHRK A 0 A_Scream
   SHRK AAAAAAAA 0 A_CustomMissile("Gibs1",random(20,40),0,random(0,360),2,random(-100,100))
   stop
   }
}

 Actor Chase_Water : CustomInventory
{
Inventory.MaxAmount 0
+Inventory.AutoActivate
States
{
Spawn:
TNT1 A 1
Fail
Use:
TNT1 A 0 A_jumpif(waterlevel < 3, "Waterlimit")
TNT1 A 0 A_Chase
Stop
Waterlimit:
TNT1 A 0 ThrustThingZ(0, 4, 1, 1)
TNT1 A 0 A_Chase
Stop
}
}

Inspired to maulerdemon attack, the shark can't fly out the water sector, it just "jumps" sometimes like a swimming player.

@Torm
If it works, may I add this stuff?

[Nash]

TBH (and no offense) this is all really hacky shit and it really should be just be an engine-side flag like +CANTLEAVEWATER or something like that. :S

[Zanieon]

Hellser wins the match then, lol

[Ozymandias81]

@nash
Exactly the same I had in my mind while losing time with it

@revilution
Definately

[Tormentor667]

TBH (and no offense) this is all really hacky shit and it really should be just be an engine-side flag like +CANTLEAVEWATER or something like that. :S

Yep, I am just gonna request that

[Tormentor667]

viewtopic.php?f=15&t=48160&p=823288#p823288
Actually not solvable, so we need to continue hacking around -_-