[Resource] Stone Golem Boss

Cutmanmike · Post by **Cutmanmike** » Sun Apr 20, 2008 4:37 pm

Here's a HUGE boss monster I've been working on for the past couple of days. I can't say I have a wad to put him in yet so if anyone can find a place for him, groovy!

Download: http://www.cutstuff.net/pub/doomwads/golembattle.zip

Video preview (for the extra lazy): http://uk.youtube.com/watch?v=UV4ZIxDP3RE

He's very large, and requires quite a bit of room. His attacks are slowly stomping around causing earthquakes, and summoning rocks to throw at you. He can summon two rocks at his side which he will proceed to launch at you or summon a round rock in front of him that he will slam and cause it to roll at you at a destructive force and speed.

The trick to surviving is to destroy the rocks he summons. Included is a test map to fight him in (and some badass Brawl music). If you plan to adopt him for your own wad, please note the following:

The Stone Golem likes:
* Fighting on flat land. Some of his attacks don't work right if you're higher than him or have obstacles blocking his rocks.
* Being a end level boss, or a rare hard enemy.
* Fighting at moderate range, but doesn't mind being in the distance.
* Having a clear shot at his targets (as little obstructions as possible)
* The latest version of zdoom!

The Stone Golem doesn't like:
* Ceilings lower than 780 units.
* Being boxed in with his target, as his stomps will kill them quickly.
* Having other minions in his way, because he'll slaughter them all by accident (unless they have the "Rock" resistance)
* Being in crowds of other Stone Golems, although does not mind fighting with a partner for those "epic" battles.
* Appearing in Joke wads, small projects or just arenas showing him off (apart from the one included with golembattle.zip)
* People who don't credit the authors!

Enjoy

Post by **Gez** » Sun Apr 20, 2008 4:47 pm

Speaking of crediting the authors, where do his sprites come from?

Slasher · Post by **Slasher** » Sun Apr 20, 2008 4:50 pm

Probably one of the only M&M creatures that needs no scaling and still makes sense in Doom. I like it.

I'm using that very same creature for a project of my own, however it'll be a bit different, but I'm not saying anything here.

Downloading now, I wanna check this out. Are you going to use this in a project? Perhaps Ghoul's Forest will become Golem's Quarry or something?

Cutmanmike · Post by **Cutmanmike** » Sun Apr 20, 2008 5:01 pm

Gez wrote:Speaking of crediting the authors, where do his sprites come from?

Might and Magic resources, courtesy of Bouncy (He's mentioned in the DECORATE file, don't worry!)

Perhaps Ghoul's Forest will become Golem's Quarry or something?

Haha very funny

I did imagine him in a valley of some kind though, slowly making his way to you from a distance. And no anyone can use this as long as they plan to use him for something serious.

Shadelight · Post by **Shadelight** » Sun Apr 20, 2008 6:09 pm

Resource huh? Could save me the trouble of trying to decorate a stone golem myself for the first level of my Hexen mod. XP

Nightmare Doom · Post by **Nightmare Doom** » Sun Apr 20, 2008 6:16 pm

Whats with the white screen that blinds you when the Golem hits you with a rock and never fades away? is this a bug? edit: I tried this normal ZDoom and it never happened, so is this a GZDoom bug?

chronoteeth · Post by **chronoteeth** » Sun Apr 20, 2008 9:07 pm

He dies too easily, personally.

DBThanatos · Post by **DBThanatos** » Mon Apr 21, 2008 12:16 am

This looks seriously awesome, my only complaint is this:

I hate the extremely slow walking / death animation. I understand is supossed to be slow, but that's just too extreme. If that is sped up, it looks way better. Much more fluid

However, all the attacks looks obsene (in a good way

)

Cutmanmike · Post by **Cutmanmike** » Mon Apr 21, 2008 2:53 am

Whats with the white screen that blinds you when the Golem hits you with a rock and never fades away? is this a bug? edit: I tried this normal ZDoom and it never happened, so is this a GZDoom bug?

Works for me in the latest GZDoom. Try grabbing a newer version?

He dies too easily, personally.

He was stronger but it just made him tedious to fight. I was going to include some stronger weapons to fight him with buuuut I decided to quickly lower his hp.

I hate the extremely slow walking / death animation. I understand is supossed to be slow, but that's just too extreme. If that is sped up, it looks way better. Much more fluid

I prefer him slow, after all it's supposed to be a boss of some sort. I didn't want him dancing around shooting A_CustomMissiles like every other boss out there

Chris Neilson · Post by **Chris Neilson** » Mon Apr 21, 2008 6:25 am

Execution could not continue.

Script error, "DECORATE" line 51:
Expected ')', got ','.

When run gzdoom.exe get error.

Code: Select all

// Stone Golem by CutmanMike. 
// Please pop my name, and Bouncy in the txt file of you wad if used.

actor StoneGolem
{
    Health 5500
    Radius 100
    Height 780
    Speed 5
    PainChance 1
	damagefactor "Rock", 0.0
    Scale 4.0
    MONSTER 
	+NOBLOOD
    +FLOORCLIP
	+NORADIUSDMG
	renderstyle Translucent
	alpha 1.0
    Obituary "%o was crushed by a giant rock golem."
	ActiveSound "golemmove"
	SeeSound "golemsee"
	+BOSS
	mass 9999999
    States
    {
    Spawn:
		EREL B 0
        EREL B 20 A_Look
        Loop
    See:
        EREL BBBBBB 5 
		EREL B 0 A_JumpIfInventory("RocketAmmo", 3, "Attackpick")
		EREL B 0 A_GiveInventory("RocketAmmo",random(1,3))
        EREL CCCCCCDDDDDDEEEEEE 5 A_Chase
		EREL F 0 A_SpawnItem("GiantRockGolemStomp",0,0)
		EREL F 0 Radius_Quake(5, 30, 12, 300, 0)
		EREL FFFFFF 5
		EREL F 0 A_JumpIfInventory("RocketAmmo", 3, "Attackpick")
		EREL B 0 A_GiveInventory("RocketAmmo",random(1,3))
		EREL GGGGGGHHHHHHIIIIII 5 A_Chase
		EREL B 0 A_SpawnItem("GiantRockGolemStomp",0,0)
		EREL B 0 Radius_Quake(5, 30, 12, 300, 0)
		Loop
	Attackpick:
		EREL A 0 A_TakeInventory("RocketAmmo",1000) 
		EREL A 0 A_CheckSight("See")
		EREL A 0 A_Jump(256, "Rocksummon1", "Rocksummon2", "Rollingattack")
		EREL A 1
		Goto See
	Rocksummon1:
		EREL A 0 A_PlaySoundEx("golemattack","Auto",0,2)
		EREL J 0 A_TakeInventory("RocketAmmo",1000) 
		EREL JKL 10 A_FaceTarget
		EREL L 0 Radius_Quake(2, 30, 0, 800, 0)
		EREL L 0 A_CustomMissile("Summoningrock1", 0, -450,0 ,0)
		EREL L 0 A_CustomMissile("Summoningrock2", 0, 450,0 ,0)
		EREL L 0 A_PlaySoundEx("golemsee","Auto",0,2)
	Goto Rocktimer
	Rocksummon2:
		EREL A 0 A_PlaySoundEx("golemattack","Auto",0,2)
		EREL J 0 A_TakeInventory("RocketAmmo",1000) 
		EREL JKL 10 A_FaceTarget
		EREL L 0 Radius_Quake(2, 30, 0, 800, 0)
		EREL L 0 A_CustomMissile("Summoningrock2", 0, -430,0 ,0)
		EREL L 0 A_CustomMissile("Summoningrock1", 0, 430,0 ,0)
		EREL L 0 A_PlaySoundEx("golemsee","Auto",0,2)
	Goto Rocktimer
	Rocktimer:
		EREL L 2 A_GiveInventory("RocketAmmo",1)
		EREL L 0 A_FaceTarget
		EREL L 0 A_JumpIfInventory("RocketAmmo", 600, "Rockfinish")
		Loop
	Rockfinish:
		EREL LKJ 10 A_TakeInventory("RocketAmmo",1000) 
		Goto See
	Rollingattack:
		EREL A 0 A_FaceTarget
		EREL A 60 A_SpawnItem("Summoningrollingrock", 250)
		EREL A 0 A_PlaySoundEx("golemattack","Auto",0,2)
		EREL JKL 8
		EREL M 13 A_SpawnItem("Launchcheck", 250,356)
		EREL N 10 A_TakeInventory("RocketAmmo",1000) 
		EREL OP 10
		Goto See
    Death:
		EREL Z 0 A_Fall
        EREL Q 20 A_PlaySoundEx("golemdie","Auto",0,2)
		EREL QQQQQQQQQQQQQQQQQQ 3 A_SpawnItem("Golemdeathspawnfx", random(-100,250), random(256,700))
		EREL RRRRRRRRRRRRRRRRRR 3 A_SpawnItem("Golemdeathspawnfx", random(-100,250), random(256,700))
		EREL WWWWWWWWWWWWWWWWWW 2 A_SpawnItem("Golemdeathspawnfx", random(-100,250), random(256,500))
		ERED A 0 Radius_Quake(6, 100, 12, 300, 0)
		ERED A 0 A_PlaySoundEx("golemland","Auto",0,2)
		EREL XXXXXXXXXXXXXXXXXX 1 A_SpawnItem("Golemdeathspawnfx2", random(-200,200), 0)
		EREL YYYYYYYYYYYYYYYYYY 1 
		ERED A 0 Radius_Quake(6, 100, 12, 300, 0)
		ERED A 0 A_PlaySoundEx("golemland","Auto",0,2)
		EREL ZZZZZZZZZZZZ 1 A_SpawnItem("Golemdeathspawnfx2", random(-200,200), 0)
		ERED AAAAAAAAAAAA 1 A_SpawnItem("Golemdeathspawnfx2", random(-200,200), 0)
		ERED AAAAAAAAAAAAAAA 3 A_SpawnItem("Golemdeathspawnfx2", random(-200,200), 0)
		ERED A 500
		Goto Fading
	Fading:
		ERED A 0 ACS_Execute(999,0) //Remove this line if using on another level
		ERED A 8 A_FadeOut(0.1)
        Loop
    }
}

actor Golemdeathspawnfx
{
- SOLID
+NOBLOCKMAP
+LOOKALLAROUND
States
{
Spawn:
TNT1 AAAAA 1 A_Look
See:
TNT1 A 0 A_PlaySoundEx("rockexplode","Auto",0,2)
TNT1 A 1 A_CustomMissile("rollingrocktrail", 0, random(-200,200), 0, 2,0)
Stop
}
}

actor Golemdeathspawnfx2
{
- SOLID
+NOBLOCKMAP
States
{
Spawn:
TNT1 AAAAA 1 A_Look
See:
TNT1 A 1 A_CustomMissile("GiantRockGolemStomp", 0,random(-200,200), 0, 2,0)
Stop
}
}
actor Launchcheck
{
damagetype "Launch"
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_Explode(10, 300, 0)
Stop
}
}

actor Summoningrock1
{
Obituary "%o was crushed by a giant rock golem."
+NOGRAVITY
Speed 0
+LOOKALLAROUND
Scale 1.5
+SHOOTABLE
Health 70
+NOBLOOD
Height 110
Radius 50
mass 999999
States
{
Spawn:
RCKF A 0
RCKF AAAA 1 A_Look
Stop
See:
ROLR A 0 A_PlaySoundEx("rockspawn","Auto",0,2)
RCKF AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Smokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
RCKF AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
RCKF A 80 ThrustThingZ(0, 28, 0, 1)
RCKF A 10 A_Stop
RCKF A 0 A_FaceTarget
RCKF A 0 A_CustomMissile("bigrockprojectile",0,0,0)
Stop
Death:
TNT1 A 1 A_Explode(50,500,1)
TNT1 A 0 A_Playsound("rockexplode")
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAaAAA 0 A_CustomMissile("minirockeffect", 0, 0, random(0,360), 2, random(10,90))
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect2", 0, 0, random(0,360), 2, random(0,90))
Stop
}
}

actor Summoningrock2 : Summoningrock1
{
States
{
See:
ROLR A 0 A_PlaySoundEx("rockspawn","Auto",0,2)
RCKF AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Smokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
RCKF AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
RCKF A 80 ThrustThingZ(0, 28, 0, 1)
RCKF A 30 A_Stop
RCKF A 0 A_FaceTarget
RCKF A 0 A_CustomMissile("bigrockprojectile",0,0,0)
Stop
}
}

actor Summoningrollingrock
{
Obituary "%o was crushed by a giant rock golem."
mass 999999
+NOGRAVITY
Speed 0
+LOOKALLAROUND
Scale 1.5
+SHOOTABLE
Health 120
+NOBLOOD
Height 50
Radius 60
painchance 0
painchance "Launch", 255
States
{
Spawn:
ROLR A 0
ROLR AAAA 1 A_Look
Stop
See:
ROLR A 0 A_PlaySoundEx("rockspawn","Auto",0,2)
ROLR AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Smokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
ROLR AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect", random(0,10), 0, random(0,360), 2, random(10,90))
ROLR A 70 ThrustThingZ(0, 28, 0, 1)
ROLR A 0 A_FaceTarget
ROLR A 100 A_Stop
Goto Death
Death:
TNT1 A 1 A_Explode(50,500,1)
TNT1 A 0 A_Playsound("rockexplode")
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAaAAA 0 A_CustomMissile("minirockeffect", 0, 0, random(0,360), 2, random(10,90))
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect2", 0, 0, random(0,360), 2, random(0,90))
Stop
Pain.Launch:
ROLR A 0 A_PlaySoundEx("rockexplode","Auto",0,2)
ROLR A 5 ThrustThingZ(0, 200, 1, 1)
ROLR A 0 A_CustomMissile("rollingrockprojectile",0,0,0,2,0)
Stop
}
}

actor GiantRockGolemStomp
{
- SOLID
+NOCLIP
+NOBLOCKMAP
States
{
Spawn:
TNT1 A 1
TNT1 A 0 A_PlaySoundEx("golemstomp","Auto",0,2)
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Smokeeffect", random(0,10), 0, random(0,360), 2, random(-2,20))
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect", random(0,10), 0, random(0,360), 2, random(-2,20))
Stop
}
}

actor Smokeeffect
{
renderstyle translucent
speed 18
+DONTSPLASH
alpha 0.8
radius 4
height 4
+DOOMBOUNCE
damage 0
+RIPPER
+NOBLOOD
States
{
Spawn:
SMOK ABCDEFGHIJKLMNOPQ 2
Stop
}
}

actor Minismokeeffect : Smokeeffect
{
speed 24
Scale 0.5
alpha 0.5
}

actor Minismokeeffect2 : Minismokeeffect
{
Scale 0.9
speed 20
}

actor bigrockprojectile
{
damagetype "Rock"
Height 100
Radius 80
Damage 20
PROJECTILE
- NOBLOCKMAP
+SHOOTABLE
Health 30
+NOBLOOD
Speed 45
Scale 1.5
States
{
Spawn:
RCKF ABCDEFGHIJKLMNOPQRSTUVWXYZ 3
RCK2 ABCDEFGHIJK 3
loop
Death:
TNT1 A 1 A_Explode(50,500,1)
TNT1 A 0 A_Playsound("rockexplode")
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAaAAA 0 A_CustomMissile("minirockeffect", 0, 0, random(0,360), 2, random(10,90))
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect2", 0, 0, random(0,360), 2, random(0,90))
Stop
}
}

actor minirockeffect
{
Scale 0.2
Speed 12
Height 4
Radius 4
PROJECTILE
- NOGRAVITY
Damage 0
States
{
Spawn:
RCKF ABCDEFGHIJKLMNOPQRSTUVWXYZ 1
RCK2 ABCDEFGHIJK 1
Goto Death
Death:
TNT1 A 1 A_SpawnItem("Minismokeffect2")
Stop
}
}

actor rollingrockprojectile
{
damagetype "Rock"
Radius 50
Damage 50
Obituary "%o was crushed by a giant rock golem."
Height 50
PROJECTILE
Speed 70
Scale 1.5
+RIPPER
+FLOORHUGGER
States
{
Spawn:
ROLR A 0 
ROLR ABCDEFGHIJKLMNOPQRSTUVWXYZ 1 A_SpawnItem("rollingrocktrail",-9)
ROL2 ABCDEF 1 A_SpawnItem("rollingrocktrail",-10)
loop
Death:
TNT1 A 1 A_Explode(50,500,1)
TNT1 A 0 A_Playsound("rockexplode")
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAaAAA 0 A_CustomMissile("minirockeffect", 0, 0, random(0,360), 2, random(10,90))
TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("Minismokeeffect2", 0, 0, random(0,360), 2, random(0,90))
Stop
}
}

actor rollingrocktrail
{
-SOLID
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_PlaySound("rollingrock")
TNT1 AAAA 0 A_CustomMissile("Smokeeffect",0,0,random(-180,180), 2, random(25,90))
TNT1 AAAAAAAAAAAA 0 A_CustomMissile("minirockeffect", 0, 0, random(-180,180), 2, random(10,90))
TNT1 AAAAAA 0 A_CustomMissile("Minismokeeffect2", 0, 0, random(-180,180), 2, random(0,90))
TNT1 A 1 A_Explode(18, 600,1)
Stop
}
}

Script error, "DECORATE" line 51:
Expected ')', got ','.

all "EREL A 0 A_PlaySoundEx("<sound>","Auto",0,2)" worng place.

Chris Neilson · Post by **Chris Neilson** » Mon Apr 21, 2008 6:41 am

Too big pic

Execution could not continue.

Script error, "DECORATE" line 217:
SC_GetNumber: Bad numeric constant "Launch".

bad number size pic.
PLEASE remove the size number all pic!

Pic1

Pic2

no more size number!

Cutmanmike · Post by **Cutmanmike** » Mon Apr 21, 2008 6:50 am

Try the latest version of GZDoom: http://grafzahl.drdteam.org/gzdoom/GZDo ... 1-1-02.zip

Chris Neilson · Post by **Chris Neilson** » Mon Apr 21, 2008 7:12 am

thank. its working

Nightmare Doom · Post by **Nightmare Doom** » Mon Apr 21, 2008 8:30 am

Cutmanmike wrote:
Whats with the white screen that blinds you when the Golem hits you with a rock and never fades away? is this a bug? edit: I tried this normal ZDoom and it never happened, so is this a GZDoom bug?
Works for me in the latest GZDoom. Try grabbing a newer version?

I got the new version (the one you linked) but that white screen still pops out randomly during the fight for no reason.

Cutmanmike · Post by **Cutmanmike** » Mon Apr 21, 2008 8:36 am

Very odd indeed. PM Graf, see if he can give you an explanation.

ZDoom

[Resource] Stone Golem Boss

[Resource] Stone Golem Boss

Re: Stone Golem Boss

Re: Stone Golem Boss

Re: Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Re: [Resource] Stone Golem Boss

Login • Register