Implementing ammo regeneration that is always active in zsc

[anud]

Hello I'm making a mod that changes most of the weapon to also use a common resource "TimeMana", and I haven't figured out how where the regen code should be.

After I implemented the custom ammo

Code: Select all

class TimeMana : Ammo {
    default {
        Inventory.PickupMessage "Picked up 10 time mana"; // "Picked up a clip."
        Inventory.Amount 10;
        Inventory.MaxAmount 100;
        Inventory.Icon "CLIPA0";
    }
}

My initial try was to augment the tick function inside the DoomPlayer extension

Code: Select all

class SorcDoom : DoomPlayer {

    Default {
        Player.DisplayName "SorcDoom" ;
        Player.StartItem "IceLance" ;
        Player.WeaponSlot 1, "IceLance" ;
        
        Player.StartItem "SorcSpark" ;
        Player.WeaponSlot 2, "SorcSpark" ;
        Player.StartItem "Clip", 50 ;
        Player.StartItem "TimeMana", 1 ;
        // Player.WeaponSlot 1, "Pistol" ;
    }

    override void Tick()
    {
        Super.Tick(); // Note this could be after as well, as long as it's called *somewhere* unconditionally in the main Tick block.
        A_GiveInventory("TimeMana", 1);
    }
}

But after the initial tick it doesn't update anymore (ingame the TimeMana inventory value is bumped up to 2)

Another solution was to have a TimeManaGenerator item that while being held it would increment time mana

Code: Select all

class TimeManaGenerator : CustomInventory {
    default {
        Inventory.PickupMessage "$GOTCLIP"; // "Picked up a clip."
        Inventory.Amount 1;
        Inventory.MaxAmount 1;
        Inventory.Icon "CLIPA0";
    }

    States {
        Held: 
            TNT1 A 1 {
                A_Print("Hello");
                A_GiveInventory("TimeMana", 1);
            }
            Loop;
        
    }
}

but the held state doesn't trigger.

Any ideas on what needs to be done?

[Enjay]

Accidental duplicate of this thread that was made while not logged in has been moved to the garbage bin at OPs request.

[Virathas]

You can give an itemthat uses the DoEffect() to grant mana. As a simple example:

Code: Select all

class ManaGiver : Inventory
{
Default
{
Inventory.Amount 1;
Inventory.MaxAmount 1;
}
override void DoEffect()
{
Super.DoEffect();
Owner.GiveInventory("TimeMana");
}
}

This of course does not handle things like "do not regenerate if dead" and regenerates 1 every tic (35/second).

I think the Tick() function didn't work for player, since player uses PlayerThink() in that place (and overriding it seems to be dangerous, at least with multiplayer compatibility in mind). Someone can probably correct me about this though.

[Jarewill]

I think the Tick() function didn't work for player, since player uses PlayerThink() in that place (and overriding it seems to be dangerous, at least with multiplayer compatibility in mind). Someone can probably correct me about this though.

Actually, the Tick override still works for the PlayerPawn actor, as I was using that method in most my mods.
However I do not know why the OP's code didn't work.

[anud]

Thanks for the responses. In the end I used the PlayerThink() override approach because that seems to work.
Reading about multiplayer compatibility what are things that should i keep in mind?

this is the function implementation

Code: Select all

 override void PlayerThink()
    {
        Super.PlayerThink();
        timePass = timePass + 1;
        if(timePass % 35 == 0) {
            A_GiveInventory("TimeMana", 1);
        }
        if(timePass > 700) {
            timePass = 1;
        }
    }

[Player701]

There shouldn't be any multiplayer issues. Note that you can use GetAge() instead of a custom variable that you increment every tick. The Tick() override should work as well, it worked in my tests for sure. If the code works if you override PlayerThink but not Tick, it could be a bug in your GZDoom version, so you should update to the latest version unless you haven't already done that.