CallACS with result on SwitchableDecoration

[Officer D]

I'm trying to have a switchable actor's Active state, do a ACS player inventory check with result.
I'm guessing the player is not being set as activator, hence why its returning 1. I tried SetActivator(0, AAPTR_PLAYER1); instead of SetActivatorToTarget(0); but the problem remained. Any ideas on what is going on here?

Decorate:

Code: Select all • Expand view

actor LootBox : SwitchableDecoration
{
  health 150
  radius 16
  height 28
  scale 0.5
  Activation THINGSPEC_Activate
  +USESPECIAL
  +CANNOTPUSH
  +SHOOTABLE
  +NOBLOOD
  States
  {
  Spawn:
   *irrelevant code*
   loop
  Active:
   VOXB A 1 A_JumpIf(CallACS("KeyCheck",0,0,0) == 0,"OpenBox")
   VOXB A 0 A_JumpIf(CallACS("KeyCheck",0,0,0) == 1,"NoKey")
   Stop
  NoKey:
   VOXB A 1 A_SpawnItem("Lootbox")
   VOXB A 1 A_Print("Key Required",3,"BIGFONT")
   Stop
  OpenBox:
   VOXB A 1 A_SpawnItem("LootboxOpen")
   TNT1 A 0 A_PlaySound("chest/open", 0, 1.0, FALSE, 1.3)
   Stop
  Death:
   *irrelevant code*
    stop
  }
}


ACS:

Code: Select all • Expand view

Script "KeyCheck" (void)
{
   SetActivatorToTarget(0);
   Delay(1);
   if(CheckInventory("ModdedBlueCard") || CheckInventory("ModdedRedCard")
    || CheckInventory("ModdedYellowCard") || CheckInventory("ModdedRedSkull")
     || CheckInventory("ModdedBlueSkull") || CheckInventory("ModdedYellowSkull"))
      {
         SetResultValue(0);
         terminate;
      }
      else
      {
         SetResultValue(1);
         terminate;
      }
}

[Mikk-]

You can use THINGSPEC_ThingTargets on on the Activation properties - that should hopefully solve your issue. You can use multiple THINGSPEC_* flags by using the | separator.

https://zdoom.org/wiki/Actor_properties#Activation

[Officer D]

The result value is still 1 it would seem. The pint message "Key Required" just keeps on showing.

Code: Select all • Expand view

Activation THINGSPEC_Activate | THINGSPEC_ThingTargets


Didn't change much unfortunately.

[Mikk-]

Hm.. with some testing I managed to get it to work by removing the delay from the ACS script.

[Officer D]

Wtf! That indeed fixed the problem. Although it makes no sense at all. Thank you for your help!

[Simon Bollerbeck]

[quote="Officer D"]Although it makes no sense at all.[/quote]
Read this: https://zdoom.org/wiki/SetResultValue

[Gez]

Yes, this is because the DECORATE code wants a result in the same tic it runs the script, it will not wait for the script if there is a delay. By default, the return value is 1, to show that the script was successfully launched. So what happens is that the DECORATE code starts the script, the ACS code hits a delay and so returns the value 1 because it knows it needs to send a return value ASAP, the DECORATE code runs with the result of that return, on the next tic the ACS code runs the rest of the script and sets a return value but it's too late by then.